Subversion Repositories ngs

Rev

Blame | Last modification | View Log | Download | RSS feed | ?url?

  1.  
  2. ;ФЛЕШЕР ДЛЯ НГС
  3.  
  4. LOW             DB 0            ;БИТЫ 7-0 АДРЕСА
  5. MIDDLE          DB 0            ;БИТЫ 15-8 АДРЕСА
  6. HIGH            DB 0            ;БИТЫ 23-16 АДРЕСА
  7.  
  8. ;УСТАНОВКА АДРЕСА ЗАПИСИ
  9. ;HL-МЛАДШИЕ 16 БИТ АДРЕС
  10. ;A-СТАРШИЕ 8 БИТ АДРЕСА
  11. SET_ADR         LD (LOW),HL
  12.                 LD (HIGH),A
  13.                 RET
  14.  
  15. ;СТИРАНИЕ БЛОКА 64К
  16. ;НА ВХОДЕ:
  17. ;A-НОМЕР БЛОКА ДЛЯ СТИРАНИЯ (0...7)
  18. ERA_BLK         LD B,A
  19.                 XOR A
  20.                 OUT (MPAG),A
  21.                 LD A,0X10
  22.                 OUT (GSCFG0),A
  23.  
  24.                 LD A,0XAA
  25.                 LD (0X0555+0X8000),A    ;555,AA
  26.                 LD A,0X55
  27.                 LD (0X02AA+0X8000),A    ;2AA,55
  28.                 LD A,0X80
  29.                 LD (0X0555+0X8000),A    ;555,80
  30.                 LD A,0XAA
  31.                 LD (0X0555+0X8000),A    ;555,AA
  32.                 LD A,0X55
  33.                 LD (0X02AA+0X8000),A    ;2AA,55
  34.  
  35.                 LD A,B
  36.                 AND 7
  37.                 ADD A,A
  38.                 OUT (MPAG),A
  39.  
  40.                 LD A,0X30
  41.                 LD (0X8000),A           ;BA,30
  42.  
  43. ;50uS pause (@12MHz)
  44.                 LD B,50
  45.                 DJNZ $
  46.  
  47. WCMP            LD A,(0X8000)
  48.                 LD B,A
  49.                 LD A,(0X8000)
  50.                 XOR B
  51.                 AND 0X40
  52.                 JR NZ,WCMP
  53.                 LD A,0X11
  54.                 OUT (GSCFG0),A
  55.                 RET
  56.  
  57. ;ЗАПИСЬ БАЙТА ВО ФЛЕШЬ
  58. WR_BYTE         LD B,A
  59.                 XOR A
  60.                 OUT (MPAG),A
  61.                 LD A,0X10
  62.                 OUT (GSCFG0),A
  63.  
  64.                 LD HL,LOW
  65.                 LD E,(HL)
  66.                 INC HL
  67.                 LD D,(HL)
  68.                 INC HL
  69.                 LD C,(HL)
  70.  
  71.                 LD A,0XAA
  72.                 LD (0X0555+0X8000),A    ;555,AA
  73.                 LD A,0X55
  74.                 LD (0X02AA+0X8000),A    ;2AA,55
  75.                 LD A,0XA0
  76.                 LD (0X0555+0X8000),A    ;555,A0
  77.  
  78.                 LD A,D
  79.                 RLA
  80.                 LD A,C
  81.                 ADC A,A
  82.                 AND 0X0F
  83.                 OUT (MPAG),A
  84.  
  85.                 LD H,D
  86.                 LD L,E
  87.                 SET 7,H
  88.  
  89.                 LD (HL),B
  90.                 INC DE
  91.                 LD A,D
  92.                 OR E
  93.                 JR NZ,$+3
  94.                 INC C
  95.                 LD HL,LOW
  96.                 LD (HL),E
  97.                 INC HL
  98.                 LD (HL),D
  99.                 INC HL
  100.                 LD (HL),C
  101.                 JR WCMP
  102.