Subversion Repositories pentevo

Rev

Rev 761 | Rev 795 | Go to most recent revision | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed

  1.  
  2. ;LAST UPDATE: 01.09.2017 savelij
  3.  
  4. ;последовательность для RST 8
  5. ;старый стек    HL AF BC RF ADR_RET DE  ->
  6. ;-> новый стек  HL(номер паги и порт BF) DE(RAMNROM И DOS7FFD) BC' DE' HL' IX IY AF' ->
  7. ;-> чтение конфига
  8.  
  9. REG_R_CORRECT   EQU 0X0D
  10.  
  11. CODE_NMIRST
  12.                 PHASE 0
  13.  
  14.                 DUPL ADR_SEL_ROM-$,0
  15.                 OUT (C),A                       ;переключение страниц для переходов
  16.                 NOP
  17. FOR_RET         NOP
  18.                 JP RAMSEL1
  19.  
  20. OUT_NMI         OUT (0XBE),A
  21.                 RETN
  22.  
  23.                 DUPL 0X0038-$,0XFF
  24. IM_EI_RET       EI
  25.                 RET
  26.  
  27. VIRT_BITS       DB 0                            ;1 биты 7-4 примонтированные диски,
  28.                                                 ;  биты 3-2 номер реального диска
  29.                                                 ;  биты 1-0 номер виртуального диска
  30.  
  31.                 DUPL 0X0066-$,0XFF
  32.                 NOP
  33.                 NOP
  34. ADR_MAGIC       JP NMI_SERVICE
  35. ADR_NMI_JUMP    EQU $-2
  36.  
  37.                 PHASE $+CPU6
  38. ;считанная конфигурация портов для RST 8
  39. R_BF            DB 0XFF
  40. R_77            DB 0XFF
  41. R_EFF7          DB 0XFF
  42. R_7FFD          DB 0XFF
  43. R_DOS7FFD       DB 0XFF
  44. R_RAMNROM       DB 0XFF
  45. R_1WINA3        DB 0XFF
  46. R_1WINA2        DB 0XFF
  47. R_1WINA1        DB 0XFF
  48. R_1WINA0        DB 0XFF
  49. R_0WINA3        DB 0XFF
  50. R_0WINA2        DB 0XFF
  51. R_0WINA1        DB 0XFF
  52. R_0WINA0        DB 0XFF
  53.  
  54. ;считанная конфигурация портов для NMI
  55. N_BF            DB 0XFF
  56. N_77            DB 0XFF
  57. N_EFF7          DB 0XFF
  58. N_7FFD          DB 0XFF
  59. N_DOS7FFD       DB 0XFF
  60. N_RAMNROM       DB 0XFF
  61. N_1WINA3        DB 0XFF
  62. N_1WINA2        DB 0XFF
  63. N_1WINA1        DB 0XFF
  64. N_1WINA0        DB 0XFF
  65. N_0WINA3        DB 0XFF
  66. N_0WINA2        DB 0XFF
  67. N_0WINA1        DB 0XFF
  68. N_0WINA0        DB 0XFF
  69. N_TEK_PALS      DUPL 0X10,0XFF
  70.  
  71. ;сохраненные регистры при вызове RST 8
  72. RREG_FI         DB 0XFF
  73. RREG_I          DB 0XFF                         ;IF
  74. RREG_FF         DB 0XFF
  75. RREG_AA         DB 0XFF                         ;AF'
  76. RREG_IYL        DB 0XFF
  77. RREG_IYH        DB 0XFF                         ;IY
  78. RREG_IXL        DB 0XFF
  79. RREG_IXH        DB 0XFF                         ;IX
  80. RREG_LL         DB 0XFF
  81. RREG_HH         DB 0XFF                         ;HL'
  82. RREG_EE         DB 0XFF
  83. RREG_DD         DB 0XFF                         ;DE'
  84. RREG_CC         DB 0XFF
  85. RREG_BB         DB 0XFF                         ;BC'
  86. RDOS7FFD        DB 0XFF                         ;биты DOS7FFD перед вызовом
  87. RRAMNROM        DB 0XFF                         ;биты RAMNROM перед вызовом
  88. RPBF_CALL       DB 0XFF                         ;содержимое порта BF перед вызовом
  89. RPAGE_CALL      DB 0XFF                         ;номер страницы откуда пришли
  90. RREG_E          DB 0XFF
  91. RREG_D          DB 0XFF                         ;DE
  92. RADRRET_L       DB 0XFF
  93. RADRRET_H       DB 0XFF                         ;ADR_RET
  94. REI_DI          DB 0XFF
  95. R_R             DB 0XFF                         ;RF
  96. RREG_C          DB 0XFF
  97. RREG_B          DB 0XFF                         ;BC
  98. RREG_F          DB 0XFF
  99. RREG_A          DB 0XFF                         ;AF
  100. RREG_L          DB 0XFF
  101. RREG_H          DB 0XFF                         ;HL
  102. RST8_SAVE_SP    DW 0XFF
  103.  
  104. ;сохраненные регистры при вызове NMI
  105. ;ADR_RET AF' IY IX BC' DE' HL' BC DE RF IF AF HL
  106. NADRRET_L       DB 0XFF                         ;ADR RET
  107. NADRRET_H       DB 0XFF
  108. NREG_FF         DB 0XFF                         ;AF'
  109. NREG_AA         DB 0XFF
  110. NREG_IYL        DB 0XFF                         ;IY
  111. NREG_IYH        DB 0XFF
  112. NREG_IXL        DB 0XFF                         ;IX
  113. NREG_IXH        DB 0XFF
  114. NREG_CC         DB 0XFF                         ;BC'
  115. NREG_BB         DB 0XFF                
  116. NREG_EE         DB 0XFF                         ;DE'
  117. NREG_DD         DB 0XFF
  118. NREG_LL         DB 0XFF                         ;HL'
  119. NREG_HH         DB 0XFF
  120. NREG_C          DB 0XFF                         ;BC
  121. NREG_B          DB 0XFF
  122. NREG_E          DB 0XFF                         ;DE
  123. NREG_D          DB 0XFF
  124. NREG_EI_DI_2    DB 0XFF                         ;RF
  125. NREG_R          DB 0XFF
  126. NREG_EI_DI_1    DB 0XFF                         ;IF
  127. NREG_I          DB 0XFF
  128. NREG_F          DB 0XFF                         ;AF
  129. NREG_A          DB 0XFF
  130. NREG_L          DB 0XFF                         ;HL
  131. NREG_H          DB 0XFF
  132. NMI_SAVE_SP     DW 0XFF                         ;адрес сохранения стека программы прерванной по NMI
  133. NUM_IM          DB 0XFF                         ;режим прерываний: 0-IM 1, 1-IM 2
  134. INT_MODE        DB 0XFF                         ;прерывания 0-запрешены, 1-разрешены
  135. INTERNAL_SP     DW 0XFF                         ;адрес хранения стека при работе сервисов
  136.  
  137. B0_CPU0         DB 0XFF                         ;байт для порта 0 окна 0 мапера
  138. P0_CPU0         DB 0XFF                         ;старший байт адреса порта порта для 0 окна 0 мапера
  139. B0_CPU1         DB 0XFF                         ;байт для порта 1 окна 0 мапера
  140. P0_CPU1         DB 0XFF                         ;старший байт адреса порта порта для 1 окна 0 мапера
  141. B0_CPU2         DB 0XFF                         ;байт для порта 2 окна 0 мапера
  142. P0_CPU2         DB 0XFF                         ;старший байт адреса порта порта для 2 окна 0 мапера
  143. B0_CPU3         DB 0XFF                         ;байт для порта 3 окна 0 мапера
  144. P0_CPU3         DB 0XFF                         ;старший байт адреса порта порта для 3 окна 0 мапера
  145. B1_CPU0         DB 0XFF                         ;байт для порта 0 окна 0 мапера
  146. P1_CPU0         DB 0XFF                         ;старший байт адреса порта порта для 0 окна 0 мапера
  147. B1_CPU1         DB 0XFF                         ;байт для порта 1 окна 0 мапера
  148. P1_CPU1         DB 0XFF                         ;старший байт адреса порта порта для 1 окна 0 мапера
  149. B1_CPU2         DB 0XFF                         ;байт для порта 2 окна 0 мапера
  150. P1_CPU2         DB 0XFF                         ;старший байт адреса порта порта для 2 окна 0 мапера
  151. B1_CPU3         DB 0XFF                         ;байт для порта 3 окна 0 мапера
  152. P1_CPU3         DB 0XFF                         ;старший байт адреса порта порта для 3 окна 0 мапера
  153. B_PORT77        DB 0XFF                         ;байт для вывода в порт ХХ77
  154. P_PORT77        DB 0XFF                         ;старший байт адреса порта ХХ77
  155.  
  156. F_INTEXT_DRV    DB 0XFF                         ;флаги при внешних/внутренних вызовах драйверов
  157.  
  158.                 PHASE $-CPU6
  159.                 DUPL HIGH ($)*0X100+0XFF-$,0XFF
  160.                 DW IM_EI_RET
  161.  
  162.                 DUPL HIGH ($)*0X100+0X80-$,0XFF
  163. STACK_RST
  164.  
  165.                 DUPL (HIGH ($)+1)*0X100-$,0XFF
  166. STACK_NMI
  167.  
  168.                 JP NMI_EXIT_DBG
  169.                 JP NMI_CASH_REM
  170.  
  171. RAMSEL1        
  172.                 LD (RST8_SAVE_SP-CPU6),SP       ;сохранили старый стек
  173.                 LD SP,RREG_E-CPU6
  174.                 PUSH HL                         ;номер страницы откуда пришли и содержимое порта BF
  175.                 PUSH DE                         ;биты RAMNROM+DOS7FFD
  176.                 EXX
  177.                 PUSH BC                         ;BC'
  178.                 PUSH DE                         ;DE'
  179.                 PUSH HL                         ;HL'
  180.                 EXX
  181.                 PUSH IX                         ;IX
  182.                 PUSH IY                         ;IY
  183.                 EX AF,AF'
  184.                 PUSH AF                         ;AF'
  185.                 LD A,I
  186.                 PUSH AF                         ;IF
  187.                 LD HL,OUT_NMI
  188.                 LD (ADR_NMI_JUMP),HL
  189.                 LD A,0XC9
  190.                 LD (FOR_RET),A
  191.                 XOR A
  192.                 LD I,A
  193.                 LD HL,(RST8_SAVE_SP-CPU6)
  194.                 LD DE,RREG_E-CPU6
  195.                 LD BC,RREG_H-RPAGE_CALL
  196.                 LDIR
  197.                 LD HL,R_77-CPU6
  198.                 LD BC,RD_77
  199.                 INIR
  200.                 INI
  201.                 LD HL,(RDOS7FFD-CPU6)
  202.                 LD (R_DOS7FFD-CPU6),HL
  203.                 LD SP,STACK_RST
  204.                 LD A,(R_77-CPU6)
  205.                 AND 7
  206.                 OR 0XA0;8                       ;выключение турбо 14 мгц
  207.                 LD BC,0XFF77
  208.                 OUT (C),A
  209.                 PEC_OFF M_SHADOW_BF
  210.                 LD BC,PENT_CONF
  211.                 LD A,(R_EFF7-CPU6)
  212.                 AND %11101111
  213.                 OUT (C),A                       ;включение турбо 7 мгц
  214.                 PEC_ON M_SHADOW_BF
  215.                 LD A,(R_7FFD-CPU6)
  216.                 AND 0X10
  217.                 LD HL,R_0WINA0-CPU6
  218.                 JR Z,RAMSEL3
  219.                 LD HL,R_1WINA0-CPU6
  220. RAMSEL3         LD A,(RPAGE_CALL-CPU6)
  221.                 LD (HL),A
  222.                 ATMPORT WIN_A3,0X40
  223.                 LD BC,WIN_P6
  224.                 XOR A
  225.                 OUT (C),A
  226.                 LD BC,WIN_A0
  227.                 LD A,ROM_RST83
  228.                 LD HL,CPU6
  229.                 ADD HL,SP
  230.                 LD SP,HL
  231.                 LD HL,CONT_RST8                 ;адрес продолжения обработки RST 8
  232.                 PUSH HL
  233.                 JP ADR_SEL_ROM
  234.  
  235. P4_EXIT_RST8    LD HL,NMI_SERVICE
  236.                 LD (ADR_NMI_JUMP),HL
  237.                 XOR A
  238.                 LD (FOR_RET),A
  239.                 PEC_OFF M_SHADOW_BF
  240.                 LD BC,PENT_CONF
  241.                 LD A,(R_EFF7-CPU6)
  242.                 OUT (C),A
  243.                 PEC_ON M_SHADOW_BF
  244.                 LD C,LOW (WIN_A5)
  245.                 LD A,(R_7FFD-CPU6)
  246.                 AND 0X10
  247.                 LD HL,B0_CPU1-CPU2
  248.                 JR Z,RENS11
  249.                 LD HL,B1_CPU1-CPU2
  250. RENS11          LD A,3
  251. RENS12          EX AF,AF'
  252.                 LD E,(HL)                       ;байт для записи в порт
  253.                 INC HL
  254.                 LD D,(HL)                       ;старший байт адреса порта
  255.                 INC HL
  256.                 LD A,D
  257.                 OR 7
  258.                 LD B,A
  259.                 OUT (C),E
  260.                 EX AF,AF'
  261.                 DEC A
  262.                 JR NZ,RENS12
  263.                 LD HL,RST8_SAVE_SP-(RREG_H-RPAGE_CALL)-CPU6
  264.                 LD DE,(RST8_SAVE_SP-CPU6)
  265.                 LD BC,RREG_H-RPAGE_CALL
  266.                 LDIR
  267.                 LD BC,(B_PORT77-CPU6)
  268.                 LD A,C
  269.                 LD C,0X77
  270.                 OUT (C),A
  271.                 LD SP,RREG_FI-CPU6
  272.                 POP AF
  273.                 LD I,A
  274.                 POP AF
  275.                 EX AF,AF'
  276.                 POP IY
  277.                 POP IX
  278.                 POP HL
  279.                 POP DE
  280.                 POP BC
  281.                 EXX
  282.                 POP DE
  283.                 POP HL
  284.                 LD SP,(RST8_SAVE_SP-CPU6)       ;восстановили стек вызвашей программы
  285.                 LD BC,ADR_RST8END               ;адрес возврата
  286.                 PUSH BC
  287.                 LD C,LOW (WIN_A0)
  288.                 LD A,(R_7FFD-CPU6)
  289.                 AND 0X10
  290.                 LD DE,(B0_CPU0-CPU6)
  291.                 JR Z,RENS13
  292.                 LD DE,(B1_CPU0-CPU6)
  293. RENS13          LD A,D
  294.                 OR 7
  295.                 LD B,A
  296.                 LD A,E                          ;страница ROM куда возвращаться
  297.                 JP ADR_SEL_ROM
  298.  
  299. NMI_SERVICE     LD (NMI_SAVE_SP-CPU6),SP        ;сохранение стека
  300.                 LD SP,NMI_SAVE_SP-CPU6          ;новый стек
  301.                 PUSH HL                         ;сохранили HL
  302.                 PUSH AF                         ;сохранили AF
  303.                 LD A,I
  304.                 PUSH AF                         ;сохранили I, флаги и режим прерываний
  305.                 LD A,R
  306.                 PUSH AF                         ;сохранили R
  307.                 PUSH DE                         ;сохранили DE
  308.                 PUSH BC                         ;сохранили BC
  309.                 EXX
  310.                 PUSH HL                         ;сохранили АЛЬТ HL
  311.                 PUSH DE                         ;сохранили АЛЬТ DE
  312.                 PUSH BC                         ;сохранили АЛЬТ BC
  313.                 PUSH IX                         ;сохранили IX
  314.                 PUSH IY                         ;сохранили IY
  315.                 EX AF,AF'
  316.                 PUSH AF                         ;сохранили альт AF
  317.                 LD A,0X80-REG_R_CORRECT
  318.                 LD HL,NREG_R-CPU6
  319.                 SLA (HL)
  320.                 RLA
  321.                 ADD A,(HL)
  322.                 RRCA
  323.                 LD (HL),A                       ;коррекция регистра R
  324.                 LD HL,(NMI_SAVE_SP-CPU6)
  325.                 LD E,(HL)
  326.                 INC HL
  327.                 LD D,(HL)
  328.                 LD HL,(NREG_F-CPU6)
  329.                 AND A
  330.                 SBC HL,DE
  331.                 JR NZ,NMISERV005
  332.                 LD HL,(NMI_SAVE_SP-CPU6)
  333.                 INC HL
  334.                 INC HL
  335.                 LD (NMI_SAVE_SP-CPU6),HL
  336.                 LD E,(HL)
  337.                 INC HL
  338.                 LD D,(HL)
  339. NMISERV005      PUSH DE
  340.                 LD SP,STACK_NMI
  341.                 LD HL,OUT_NMI
  342.                 LD (ADR_NMI_JUMP),HL
  343.                 LD A,0XC9
  344.                 LD (FOR_RET),A                  ;RET для переключения страниц ROM/RAM
  345.                 LD HL,N_BF-CPU6                 ;адрес сохранения прочитанных регистров конфигурации
  346.                 IN A,(PEVO_CONF)
  347.                 LD (HL),A
  348.                 INC HL
  349.                 LD BC,RD_77
  350. NMISERV002      INIR
  351.                 INI
  352.                 LD B,1                          ;прерывания разрешены
  353.                 LD A,R
  354.                 JP PE,NMISERV001
  355.                 LD A,R
  356.                 JP PE,NMISERV001
  357.                 DEC B                           ;прерывания запрещены
  358. NMISERV001      XOR A
  359.                 LD I,A                          ;обработчик прерывания переставилии для адреса 00FF
  360.                 PEC_ON M_SHADOW_BF
  361.                 CALL GET_NUM_IM
  362.  
  363. ;               LD DE,0XA70F                    ;дальше сохраняем текущую палитру
  364. ;               LD BC,0XBD77
  365. ;               OUT (C),D                       ;включение текстмода
  366. ;               LD (ADR_PALITRA),HL
  367. ;               LD BC,RD_PALITRA
  368. ;               EI
  369. ;               HALT
  370. ;               DI
  371. ;NMISERV003     LD A,E
  372. ;               BIT 3,E
  373. ;               OUT (0XFE),A
  374. ;               JR Z,NMISERV004
  375. ;               OUT (0XF6),A
  376. ;NMISERV004     IN A,(C)
  377. ;               LD (HL),A
  378. ;               INC HL
  379. ;               DEC E
  380. ;               JP P,NMISERV003                 ;палитру сохранили
  381. ;               LD HL,MAGIC_PAL
  382. ;               LD E,0X0F
  383. ;SETPAL1                LD A,E
  384. ;               BIT 3,E
  385. ;               OUT (0XFE),A
  386. ;               JR Z,$+4
  387. ;               OUT (0XF6),A
  388. ;               LD A,(HL)
  389. ;               INC HL
  390. ;               OR %00001100
  391. ;               OUT (0XFF),A
  392. ;               DEC E
  393. ;               JP P,SETPAL1
  394. ;               LD BC,0XFF77
  395. ;               OUT (C),D
  396.  
  397.                 PUSH DE
  398.                 LD BC,WIN_P6
  399.                 XOR A
  400.                 OUT (C),A                       ;включили последнюю страницу озу
  401.                 LD B,HIGH (WIN_A3)
  402.                 LD A,0X40
  403.                 OUT (C),A                       ;сняли зависимость 3 окна от порта 7FFD
  404.                 LD DE,CPU6
  405.                 ADD HL,DE
  406.                 LD (ADR_PALITRA),HL
  407.                 LD HL,CPU6
  408.                 ADD HL,SP
  409.                 LD SP,HL
  410.                 LD B,HIGH (WIN_A0)
  411.                 LD A,ROM_RST83
  412.                 OUT (C),A
  413.                 POP HL
  414.                 LD (NUM_IM),HL
  415. ;PEREHVAT       DUPL 3,0
  416. ;               LD A,(DEBUG_ONOFF)
  417. ;               AND A
  418. ;               JR NZ,IN_DEBUG
  419.                 LD HL,CONTINUE_MAGIC
  420.                 PUSH HL
  421.                 JP OUT_NMI
  422.  
  423. ;IN_DEBUG       XOR A
  424. ;               IN A,(0XFE)
  425. ;               CPL
  426. ;               AND 0X1F
  427. ;               JR NZ,IN_DEBUG
  428. ;               LD B,HIGH (WIN_P0)
  429. ;               LD A,PAGE_STS
  430. ;               OUT (C),A
  431. ;               LD HL,DEBUGGER
  432. ;               PUSH HL
  433. ;               JP OUT_NMI
  434.  
  435. ;выход из магика
  436. EXITNMISERVICE  LD HL,ADR_MAGIC
  437.                 LD (HL),0XC9                    ;заглушка на MAGIC
  438.                 IN A,(PEVO_CONF)
  439.                 OR M_NMI_BF
  440.                 OUT (PEVO_CONF),A
  441.                 AND M_NMI_BF!0XFF
  442.                 OUT (PEVO_CONF),A
  443.                 HALT                            ;ждем срабатывания MAGIC
  444. FALSE_NMI       LD HL,ADR_MAGIC
  445.                 LD (HL),0XC3                    ;разрешение обработчика MAGIC перед выходом
  446.  
  447. ;               LD HL,0
  448. ;ADR_PALITRA    EQU $-2
  449. ;               LD A,(N_77-CPU6)
  450. ;               LD E,0X0F
  451. ;               AND E
  452. ;               OR 0XA0
  453. ;               LD D,A
  454. ;               LD BC,0XBD77                    ;доступ к палитре
  455. ;               OUT (C),D                       ;вкл.PAL
  456. ;SETPAL0                LD A,E
  457. ;               BIT 3,E
  458. ;               OUT (0XFE),A
  459. ;               JR Z,$+4
  460. ;               OUT (0XF6),A
  461. ;               LD A,(HL)
  462. ;               INC HL
  463. ;               OR %00001100
  464. ;               OUT (0XFF),A
  465. ;               DEC E
  466. ;               JP P,SETPAL0
  467. ;               LD BC,0XFF77
  468. ;               OUT (C),D
  469.  
  470.                 LD C,LOW (WIN_A0)
  471.                 LD A,(N_7FFD-CPU6)
  472.                 AND 0X10
  473.                 LD HL,B0_CPU0-CPU6
  474.                 JR Z,ENS11
  475.                 LD HL,B1_CPU0-CPU6
  476. ENS11           LD A,4
  477. ENS12           EX AF,AF'
  478.                 LD E,(HL)                       ;байт для записи в порт
  479.                 INC HL
  480.                 LD D,(HL)                       ;старший байт адреса порта
  481.                 INC HL
  482.                 LD A,D
  483.                 OR 0X3F
  484.                 LD B,A
  485.                 BIT 3,D
  486.                 JR NZ,ENS15
  487.                 LD A,D
  488.                 AND 3
  489.                 RRCA
  490.                 RRCA
  491.                 OUT (C),A
  492.                 RES 3,B
  493. ENS15           OUT (C),E
  494.                 EX AF,AF'
  495.                 DEC A
  496.                 JR NZ,ENS12
  497.                 PEC_OFF M_SHADOW_BF
  498.                 LD BC,PENT_CONF
  499.                 LD A,(N_EFF7-CPU6)
  500.                 OUT (C),A
  501.                 PEC_ON M_SHADOW_BF
  502.                 LD BC,(B_PORT77-CPU6)
  503.                 LD A,C
  504.                 LD C,0X77
  505.                 OUT (C),A
  506.                 LD A,(N_BF-CPU6)
  507.                 OUT (PEVO_CONF),A
  508.                 LD BC,CONF_128
  509.                 LD A,(N_7FFD-CPU6)
  510.                 OUT (C),A
  511.                 LD HL,NMI_SERVICE
  512.                 LD (ADR_NMI_JUMP),HL
  513.                 XOR A
  514.                 LD (FOR_RET),A
  515.                 LD SP,NADRRET_L-CPU6
  516.                
  517.                 LD HL,(NMI_SAVE_SP-CPU6)
  518.                 POP DE
  519.                 LD (HL),E
  520.                 INC HL
  521.                 LD (HL),D                       ;восстановление адреса возврата
  522.  
  523.                 POP AF
  524.                 EX AF,AF'
  525.                 POP IY
  526.                 POP IX
  527.                 POP BC
  528.                 POP DE
  529.                 POP HL
  530.                 EXX
  531.                 POP BC
  532.                 POP DE
  533.                 POP AF
  534.                 JP PO,ENMISERV1
  535.                 EI
  536. ENMISERV1       LD A,0X80+3-REG_R_CORRECT
  537.                 LD HL,NREG_R-CPU6
  538.                 SLA (HL)
  539.                 RLA
  540.                 ADD A,(HL)
  541.                 RRCA
  542.                 LD R,A
  543.                 POP AF
  544.                 LD I,A
  545.                 POP AF
  546.                 POP HL
  547.                 LD SP,(NMI_SAVE_SP-CPU6)
  548.                 OUT (0XBE),A
  549.                 RETN
  550.  
  551. ;MAGIC_PAL      DB 0X0C,0X2D,0X4E,0X6F,0X9C,0XBD,0XDE,0XFF
  552. ;               DB 0XEC,0XED,0XEE,0XEF,0XFC,0XFD,0XFE,0XFF
  553.  
  554. LDIR__BYTES     LD HL,CPU6
  555.                 ADD HL,SP
  556.                 LD SP,HL
  557.                 LD A,(R_7FFD-CPU6)
  558.                 AND 0X10
  559.                 LD HL,B0_CPU1-CPU2
  560.                 JR Z,LDIR_BYTES5
  561.                 LD HL,B1_CPU1-CPU2
  562. LDIR_BYTES5     LD C,LOW (WIN_A0)
  563.                 LD A,3
  564. LDIR_BYTES3     EX AF,AF'
  565.                 LD E,(HL)                       ;байт для записи в порт
  566.                 INC HL
  567.                 LD D,(HL)                       ;старший байт адреса порта
  568.                 INC HL
  569.                 LD A,D
  570.                 OR 0X3F
  571.                 LD B,A
  572.                 BIT 3,D
  573.                 JR NZ,LDIR_BYTES4
  574.                 LD A,D
  575.                 AND 3
  576.                 RRCA
  577.                 RRCA
  578.                 OUT (C),A
  579.                 RES 3,B
  580. LDIR_BYTES4     OUT (C),E
  581.                 EX AF,AF'
  582.                 DEC A
  583.                 JR NZ,LDIR_BYTES3
  584.                 EXX
  585.                 LDIR
  586.                 LD BC,WIN_P6
  587.                 XOR A
  588.                 OUT (C),A
  589.                 LD HL,CPU6
  590.                 ADD HL,SP
  591.                 LD SP,HL
  592.                 LD BC,WIN_A0
  593.                 LD A,ROM_RST83
  594.                 JP ADR_SEL_ROM
  595.  
  596. NUM_IM2         LD A,1
  597.                 RET
  598.  
  599. GET_NUM_IM      PUSH HL
  600.                 LD D,B                          ;INT ON/OFF
  601.                 LD HL,0X0038
  602.                 LD (HL),0XAF
  603.                 LD L,0XFF
  604.                 LD (HL),LOW (NUM_IM2)
  605.                 INC HL
  606.                 LD (HL),HIGH (NUM_IM2)
  607.                 EI
  608.                 HALT
  609.                 DI
  610.                 LD E,A                          ;0-IM 1, 1-IM 2
  611.                 LD HL,0X0038
  612.                 LD (HL),0XFB
  613.                 LD L,0XFF
  614.                 LD (HL),LOW (IM_EI_RET)
  615.                 INC HL
  616.                 LD (HL),HIGH (IM_EI_RET)
  617.                 POP HL
  618.                 RET
  619.  
  620.                 PHASE $+CPU6
  621. ;вызов подпрограмм из других страниц
  622. CALL2PAGE       EX (SP),HL
  623.                 PUSH BC
  624.                 PUSH AF
  625.                 LD C,(HL)
  626.                 INC HL
  627.                 LD B,(HL)
  628.                 INC HL
  629.                 LD (ADRCALL),BC
  630.                 LD BC,RD_7FFD
  631.                 IN A,(C)
  632.                 AND 0X10
  633.                 LD BC,RD_0WINA0
  634.                 JR Z,CALL2PAGE1
  635.                 LD BC,RD_1WINA0
  636. CALL2PAGE1      IN A,(C)
  637.                 AND 0X3F
  638.                 LD BC,STEK_PAGES
  639. TEKPAGE         EQU $-2
  640.                 LD (BC),A
  641.                 INC BC
  642.                 LD (TEKPAGE),BC
  643.                 LD A,(HL)
  644.                 INC HL
  645.                 LD BC,WIN_A0
  646.                 OUT (C),A
  647.                 POP AF
  648.                 POP BC
  649.                 EX (SP),HL
  650.                 CALL 0
  651. ADRCALL         EQU $-2
  652.                 PUSH BC
  653.                 PUSH AF
  654.                 LD BC,(TEKPAGE)
  655.                 DEC BC
  656.                 LD A,(BC)
  657.                 LD (TEKPAGE),BC
  658.                 LD BC,WIN_A0
  659.                 OUT (C),A
  660.                 POP AF
  661.                 POP BC
  662.                 RET
  663.  
  664. ;установка CASH REMEMBER и STS 4.3
  665. INST_CASHRM     PUSH HL
  666.                 LD BC,WIN_P3
  667.                 LD A,RAM_PROFROM
  668.                 OUT (C),A
  669.                 LD HL,CASHREMEMBER
  670.                 LD DE,CPU3
  671.                 PCALL UNPACK,ROM_CASHRM
  672.                 LD BC,WIN_P3
  673.                 LD A,RAM_STS
  674.                 OUT (C),A
  675.                 LD HL,STS_MAIN
  676.                 LD DE,CPU3+0X1B00
  677.                 PCALL UNPACK,ROM_CASHRMSTS
  678.                 LD BC,WIN_P3
  679.                 LD A,RAM_ADDSTS
  680.                 OUT (C),A
  681.                 LD HL,STS_ADD
  682.                 LD DE,CPU3+0X3B00
  683.                 PCALL UNPACK,ROM_CASHRMSTS
  684.                 POP HL
  685.                 SET B_CASH_INST,(HL)
  686.                 RET
  687.  
  688. ;вход в CASH REMEMBER
  689. CASHRM          LD HL,CPU6+DEBUG_ONOFF
  690.                 BIT B_CASH_INST,(HL)
  691.                 CALL Z,INST_CASHRM              ;установка CASH REMEMBER и STS 4.3
  692.                 BIT B_CASH_ACTIV,(HL)
  693.                 JR Z,CASHRM1
  694. ;принудительный вход в отладчик с возвратом в основное меню NMI
  695.                 LD BC,WIN_P3
  696.                 LD A,RAM_PROFROM
  697.                 OUT (C),A
  698.                 SET B_CASH_ACTIV,(HL)
  699.                 LD HL,DBG2MAINMENU
  700.                 PUSH HL
  701.                 JP CPU3
  702.  
  703. ;вход в отладчик из основного меню
  704. CASHRM1         LD HL,RESTART_MAIN
  705.                 PUSH HL
  706.                 LD HL,EXIT_CASHRM
  707.                 PUSH HL
  708.                 LD HL,CPU6+DEBUG_ONOFF
  709.                 SET B_DBG_ACTIV,(HL)
  710.  
  711. EXIT_CASHRM     LD HL,CPU6+DEBUG_ONOFF
  712.                 RES B_CASH_ACTIV,(HL)
  713. NO_EXIT_CASHRM  JR NO_EXIT_DEBUG
  714.  
  715. ;вход в отладчик
  716. DEBUGGER        DI
  717.                 LD HL,CPU6+DEBUG_ONOFF
  718.                 BIT B_DBG_ACTIV,(HL)
  719.                 JR Z,DEBUGGER1
  720. ;принудительный вход в отладчик с возвратом в основное меню NMI
  721.                 LD HL,DBG2MAINMENU
  722.                 PUSH HL
  723.                 JR DEBUGGER2
  724.  
  725. ;вход в отладчик из основного меню NMI
  726. DEBUGGER1       LD HL,RESTART_MAIN
  727.                 PUSH HL
  728.                 LD HL,EXIT_DEBUG
  729.                 PUSH HL
  730.                 LD HL,CPU6+DEBUG_ONOFF
  731.                 SET B_DBG_ACTIV,(HL)
  732. DEBUGGER2       LD HL,CONTINUE_PROG
  733.                 LD DE,NADRRET_L
  734.                 EVOPORT WIN_P3,RAM_STS          ;включили страницу с установленным STS
  735.                 LD BC,N_BF
  736.                 LD A,(N_77)
  737.                 EX AF,AF'
  738.                 LD A,NO_EXIT_DEBUG-EXIT_DEBUG
  739.                 JP START_STS
  740.  
  741. ;нормальный выход из отладчика
  742. EXIT_DEBUG      LD HL,CPU6+DEBUG_ONOFF
  743.                 RES B_DBG_ACTIV,(HL)
  744. ;выход из отладчика минуя основное меню NMI
  745. NO_EXIT_DEBUG   EVOPORT WIN_A0,ROM_RST82
  746.                 LD HL,CPU6+DEBUG_ONOFF
  747.                 LD A,M_TRACE_DBG
  748.                 AND (HL)
  749.                 RET Z
  750.                 LD HL,TRACER_DBG
  751.                 EX (SP),HL
  752.                 RET
  753.  
  754. ;вход в CASH REMEMBER минуя основное меню NMI
  755. CASH2MAINMENU   LD HL,CPU6+DEBUG_ONOFF
  756.                 RES B_CASH_ACTIV,(HL)
  757.                 EVOPORT WIN_A0,ROM_RST83
  758.                 LD A,M_CASH_ACTIV
  759.                 AND (HL)
  760.                 JP NZ,CONTMAGIC3
  761.                 JP RESTART_NMI
  762.  
  763. ;вход в отладчик минуя основное меню NMI
  764. DBG2MAINMENU    LD HL,CPU6+DEBUG_ONOFF
  765.                 RES B_DBG_ACTIV,(HL)
  766.                 EVOPORT WIN_A0,ROM_RST83
  767.                 LD A,M_TRACE_DBG
  768.                 AND (HL)
  769.                 JP NZ,CONTMAGIC3
  770.                 JP RESTART_NMI
  771.  
  772. ;возврат из NMI для отладчика. не восстанавливается:
  773. ;палитра, фонт, видеорежим
  774. NMI_EXIT_DBG    EVOPORT WIN_A0,ROM_RST82
  775.                 PCALL RESTORE_AY,ROM_RST83      ;восстановление рагистров AY
  776.                 LD HL,ADR_MAGIC
  777.                 LD (HL),0XC9                    ;заглушка на MAGIC
  778.                 IN A,(PEVO_CONF)
  779.                 OR M_NMI_BF
  780.                 OUT (PEVO_CONF),A
  781.                 AND M_NMI_BF!0XFF
  782.                 OUT (PEVO_CONF),A
  783.                 HALT                            ;ждем срабатывания MAGIC
  784.                 LD HL,ADR_MAGIC
  785.                 LD (HL),0XC3                    ;разрешение обработчика MAGIC перед выходом
  786.                 LD C,LOW (WIN_A0)
  787.                 LD A,(N_7FFD-CPU6)
  788.                 AND 0X10
  789.                 LD HL,B0_CPU0-CPU6
  790.                 JR Z,ENSDBG11
  791.                 LD HL,B1_CPU0-CPU6
  792. ENSDBG11        LD A,4
  793. ENSDBG12        EX AF,AF'
  794.                 LD E,(HL)                       ;байт для записи в порт
  795.                 INC HL
  796.                 LD D,(HL)                       ;старший байт адреса порта
  797.                 INC HL
  798.                 LD A,D
  799.                 OR 0X3F
  800.                 LD B,A
  801.                 BIT 3,D
  802.                 JR NZ,ENSDBG15
  803.                 LD A,D
  804.                 AND 3
  805.                 RRCA
  806.                 RRCA
  807.                 OUT (C),A
  808.                 RES 3,B
  809. ENSDBG15        OUT (C),E
  810.                 EX AF,AF'
  811.                 DEC A
  812.                 JR NZ,ENSDBG12
  813.                 PEC_OFF M_SHADOW_BF
  814.                 LD BC,PENT_CONF
  815.                 LD A,(N_EFF7-CPU6)
  816.                 OUT (C),A
  817.                 PEC_ON M_SHADOW_BF
  818. ;               LD BC,(B_PORT77-CPU6)
  819. ;               LD A,C
  820. ;               LD C,0X77
  821. ;               OUT (C),A
  822.                 LD A,(N_BF-CPU6)
  823.                 OUT (PEVO_CONF),A
  824.                 LD BC,CONF_128
  825.                 LD A,(N_7FFD-CPU6)
  826.                 OUT (C),A
  827.                 LD HL,NMI_SERVICE
  828.                 LD (ADR_NMI_JUMP),HL
  829.                 XOR A
  830.                 LD (FOR_RET),A
  831.                 LD SP,NADRRET_L-CPU6
  832.                 POP AF                          ;сброс адреса возврата
  833.                 POP AF
  834.                 EX AF,AF'
  835.                 POP IY
  836.                 POP IX
  837.                 POP BC
  838.                 POP DE
  839.                 POP HL
  840.                 EXX
  841.                 POP BC
  842.                 POP DE
  843. ;               EI
  844. ;               HALT
  845. ;               DI
  846.                 POP AF
  847.                 JP PO,ENMIDBGSERV1
  848.                 EI
  849. ENMIDBGSERV1    LD A,0X80+3-REG_R_CORRECT
  850.                 LD HL,NREG_R-CPU6
  851.                 SLA (HL)
  852.                 RLA
  853.                 ADD A,(HL)
  854.                 RRCA
  855.                 LD R,A
  856.                 POP AF
  857.                 LD I,A
  858.                 POP AF
  859.                 POP HL
  860.                 LD SP,(NMI_SAVE_SP-CPU6)
  861.                 OUT (0XBE),A
  862.                 RETN
  863.  
  864. SET_CPU3        PUSH BC
  865.                 LD BC,WIN_A3
  866.                 EX AF,AF'
  867.                 LD A,0X40
  868.                 OUT (C),A
  869.                 EX AF,AF'
  870.                 LD B,HIGH (WIN_P3)
  871.                 OUT (C),A
  872.                 POP BC
  873.                 RET
  874.  
  875. NMI_CASH_REM
  876.                 RET
  877.  
  878. STEK_PAGES      DUPL 0X10,0XFF                  ;10
  879. RST_FLAGS       DB 0XFF                         ;1
  880. TXT_COLOR       DB 0XFF                         ;1
  881. COORD_XY        DW 0XFF                         ;2
  882. COLBUF          DUPL 0X50,0XFF                  ;50 буфер сохранения строки цвета с экрана
  883. MOUSE_BUFF      DUPL 0X10,0XFF                  ;10 буфер сохранения части экрана под курсором мыши
  884. PRESSEDKEY      DW 0XFFFF                       ;2 адрес списка горячих клавиш после вывода окна
  885. FLAGS           DB 0XFF                         ;1 системные флаги
  886.  BITMASK VIDEO_MODE,    7                       ;BIT 7-=1-TXT, =0-ZX SCREEN MODE
  887.                                                 ;BIT 6
  888.                                                 ;BIT 5
  889.  BITMASK WIN_INT_EXT,   4                       ;BIT 4-=1-внешнее окно, =0-внутреннее окно
  890.  BITMASK RUN_FAT_DSK,   3                       ;BIT 3-=1-запуск с FAT, =0-запуск с дискеты
  891.  BITMASK CLOCK_PRESENT, 2                       ;BIT 2-=1-часы найдены, =0-нет
  892.  BITMASK MOUSE_PRESENT, 1                       ;BIT 1-=1-мышь есть, =0-нет
  893.  BITMASK CURSOR_NUM,    0                       ;BIT 0-какой курсор рисовать, для мигания
  894. NEXTBYTERST8    DB 0XFF                         ;1 следующий байт после вызова RST 8, код для вызова драйвера
  895. OLD_STACK       DW 0XFFFF                       ;2
  896. ADR_INT         DW 0XFFFF                       ;2
  897. ADR_PALITRA     DW 0XFFFF                       ;2
  898. XNEW            DB 0XFF                         ;1
  899. ADRSTR_Y        DB 0XFF                         ;1
  900. ADRSTR_X        DB 0XFF                         ;1
  901. TXNEW           DB 0XFF                         ;1
  902. TADRSTR_Y       DB 0XFF                         ;1
  903. TADRSTR_X       DB 0XFF                         ;1
  904. NO_INW          DB 0XFF                         ;1
  905. COLOR4SYM       DB 0XFF                         ;1
  906. PAGE4READ       DB 0XFF                         ;1
  907. PAGE4SCR        DB 0XFF                         ;1
  908. DAT_MAIN_MENU   DUPL 3,0                        ;3
  909. DAT_SETUP_MENU  DUPL 3,0                        ;3
  910. DAT_FILEBROWS   DUPL 5,0                        ;5
  911. DAT_MOUNT       DUPL 3,0                        ;3
  912. WIN_DEV         DUPL 0X30,0                     ;30
  913. COL_CURSOR      DW 0XFFFF                       ;2
  914. _MORG           DB 0XFF                         ;1
  915. ARXY            DW 0XFFFF                       ;2
  916. ADR_REST        DW 0XFFFF                       ;2
  917. MOUPOS          DW 0XFFFF                       ;2
  918. TEK_MODES       DB 0XFF                         ;1
  919. CMP_FONT_FLAG   DB 0XFF                         ;1
  920. BUFF4TXT        DUPL 0X2B,0XFF                  ;2B
  921. EXT4FOUND       DUPL 0X10*3+1,0XFF              ;10*3+1
  922. CMOS4CRC16      DUPL ECMOS_DEFAULT-CMOS_DEFAULT,0XFF
  923. KSTATE0         DB 0XFF                         ;1 |
  924. KSTATE1         DB 0                            ;1 |
  925. KSTATE2         DB 0                            ;1 |
  926. KSTATE3         DB 0                            ;1 |
  927. KSTATE4         DB 0XFF                         ;1 |    аналог
  928. KSTATE5         DB 0                            ;1 |    BASIC
  929. KSTATE6         DB 0                            ;1 |    переменных
  930. KSTATE7         DB 0                            ;1 |    опроса
  931. LAST_K          DB 0                            ;1 |    клавиатуры
  932. REPDEL          DB 0X10                         ;1 |
  933. REPPER          DB 1                            ;1 |
  934. FLAGS_KEY       DB 0                            ;1 |
  935. FLAGS_KEY1      DB 0X10                         ;1 |
  936. MOUNT_SYM       DB 0XFF                         ;1 номер монтирумого диска
  937. EXT_TYPE        DB 0XFF                         ;1
  938. OST_HWOST       DW 0XFFFF                       ;2
  939. KUDA_HWOST      DW 0XFFFF                       ;2
  940. SCROLL_MODE     DB 0XFF                         ;1
  941. NEXT4PAGE       DW 0XFFFF                       ;2
  942. OSTAT_SECT      DW 0XFFFF                       ;2
  943. NACH_SECT       DW 0XFFFF                       ;2
  944. START_DATA      DW 0XFFFF                       ;2
  945. AY_REGS         DUPL 0X0E,0XFF                  ;D
  946. TEKBUFTSC       DW 0XFFFF                       ;2
  947. TEK_TEXT        DW 0XFFFF                       ;2
  948. TURBO_MODE      DUPL 5,0XFF                     ;5
  949. MEMORY_MODE     DUPL 4,0XFF                     ;3
  950. BUFF_TIME       DB 0X16,0X00,0X48,0X17,CYAN<<3+BLUE+0XC0
  951. TXT_TIME        DB "00:00:00",0X16,0X01,0X48
  952. TXT_DATA        DB "00.00.00",0X17,0XFF,0
  953. EBUFF_TIME
  954. NAME_RAMDISK    DUPL 0X20,0
  955. FILE_DEST       DUPL 0X20,0XFF                  ;20 описатель открытого файла (куда)
  956. FB_EXT          DUPL 0X0B,0XFF                  ;B буфер 8.3 для поиска имени
  957. SAVE_IY         DW 0XFFFF                       ;2 внутренее сохранение регистров для дальнейшего использования
  958. ADR_MASK_EXT    DW 0XFFFF                       ;2 адрес расширений файлов для поиска
  959. ADR_SKLAD       DW 0XFFFF                       ;2 адрес складирования найденного
  960. ADR_SKLAD_NAME  DW 0XFFFF                       ;2
  961. MAKS_ADR        DB 0XFF                         ;1 старший байт максимального адреса буфера складирования
  962. KOL_FOUNDED     DW 0XFFFF                       ;2 количество найденных описателей
  963. OUT_NAME_FILE   DB 0X17,0XFF,0X16,0,0,0
  964. OUT_NAME_FILET  EQU $-3
  965. BUF_FILEITEM    DUPL 0X20,0XFF                  ;20
  966. EXTERN_PAL      DUPL 0X10,0XFF                  ;10
  967. ENMI_SERVICE
  968. HDDTIMEOUT      EQU EXTERN_PAL+0X10             ;1
  969.  
  970.                 DEPHASE
  971.                 PHASE $-CPU6
  972.