Subversion Repositories pentevo

Rev

Rev 1031 | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed | ?url?

  1.  
  2. ; LAST UPDATE: 12.02.2024 savelij
  3.  
  4.         TITLE "addon1.a80 ROM_RST81"
  5.  
  6.                 PHASE CPU0
  7.                 JP $
  8.  
  9.                 DUPL 0x0008 - $,0xFF
  10.                 JP $
  11.  
  12.                 DUPL 0x0010 - $,0xFF
  13.                 JP $
  14.  
  15.                 DUPL ADR_SEL_ROM - $,0xFF
  16.                 OUT (C),A                       ; 0014
  17.                 NOP
  18.                 RET
  19.  
  20.                 DUPL 0x0018 - $,0xFF
  21.                 JP $
  22.  
  23.                 DUPL 0x0020 - $,0xFF
  24.                 JP $
  25.  
  26.                 DUPL 0x0028 - $,0xFF
  27.                 JP $
  28.  
  29.                 DUPL 0x0030 - $,0xFF
  30.                 JP CALL2PAGE
  31.  
  32.                 DUPL ADR_PERFECT - $,0xFF
  33.                 DW PERFECTCOM
  34.  
  35.                 DUPL 0x0038 - $,0xFF            ; 0038
  36.                 EI
  37.                 RET
  38.  
  39.                 DUPL 0x003E - $,0xFF
  40.                 EI
  41.                 RET
  42.  
  43.                 DUPL 0x0040 - $,0xFF
  44.                 JP INSTALL_NMIRST               ; установка обработчиков NMI и RST
  45.  
  46.                 DUPL 0x0080 - $,0xFF
  47.                 binclude ../../dec40.bin
  48.  
  49.                 DUPL 0x00FF - $,0xFF
  50.                 DW 0x0038
  51.  
  52.                 PHASE $ + 0x4000
  53.                 include rst8_data.a80
  54.  
  55.                 PHASE $ & 0x3FFF
  56.  
  57.                 DUPL (HIGH ($) + 1) * 0x100 - $,0xFF
  58. BUF_CRC16_TABL  DB 0x00,0x10,0x20,0x30,0x40,0x50,0x60,0x70,0x81,0x91,0xA1,0xB1,0xC1,0xD1,0xE1,0xF1
  59.                 DB 0x12,0x02,0x32,0x22,0x52,0x42,0x72,0x62,0x93,0x83,0xB3,0xA3,0xD3,0xC3,0xF3,0xE3
  60.                 DB 0x24,0x34,0x04,0x14,0x64,0x74,0x44,0x54,0xA5,0xB5,0x85,0x95,0xE5,0xF5,0xC5,0xD5
  61.                 DB 0x36,0x26,0x16,0x06,0x76,0x66,0x56,0x46,0xB7,0xA7,0x97,0x87,0xF7,0xE7,0xD7,0xC7
  62.                 DB 0x48,0x58,0x68,0x78,0x08,0x18,0x28,0x38,0xC9,0xD9,0xE9,0xF9,0x89,0x99,0xA9,0xB9
  63.                 DB 0x5A,0x4A,0x7A,0x6A,0x1A,0x0A,0x3A,0x2A,0xDB,0xCB,0xFB,0xEB,0x9B,0x8B,0xBB,0xAB
  64.                 DB 0x6C,0x7C,0x4C,0x5C,0x2C,0x3C,0x0C,0x1C,0xED,0xFD,0xCD,0xDD,0xAD,0xBD,0x8D,0x9D
  65.                 DB 0x7E,0x6E,0x5E,0x4E,0x3E,0x2E,0x1E,0x0E,0xFF,0xEF,0xDF,0xCF,0xBF,0xAF,0x9F,0x8F
  66.                 DB 0x91,0x81,0xB1,0xA1,0xD1,0xC1,0xF1,0xE1,0x10,0x00,0x30,0x20,0x50,0x40,0x70,0x60
  67.                 DB 0x83,0x93,0xA3,0xB3,0xC3,0xD3,0xE3,0xF3,0x02,0x12,0x22,0x32,0x42,0x52,0x62,0x72
  68.                 DB 0xB5,0xA5,0x95,0x85,0xF5,0xE5,0xD5,0xC5,0x34,0x24,0x14,0x04,0x74,0x64,0x54,0x44
  69.                 DB 0xA7,0xB7,0x87,0x97,0xE7,0xF7,0xC7,0xD7,0x26,0x36,0x06,0x16,0x66,0x76,0x46,0x56
  70.                 DB 0xD9,0xC9,0xF9,0xE9,0x99,0x89,0xB9,0xA9,0x58,0x48,0x78,0x68,0x18,0x08,0x38,0x28
  71.                 DB 0xCB,0xDB,0xEB,0xFB,0x8B,0x9B,0xAB,0xBB,0x4A,0x5A,0x6A,0x7A,0x0A,0x1A,0x2A,0x3A
  72.                 DB 0xFD,0xED,0xDD,0xCD,0xBD,0xAD,0x9D,0x8D,0x7C,0x6C,0x5C,0x4C,0x3C,0x2C,0x1C,0x0C
  73.                 DB 0xEF,0xFF,0xCF,0xDF,0xAF,0xBF,0x8F,0x9F,0x6E,0x7E,0x4E,0x5E,0x2E,0x3E,0x0E,0x1E
  74.                 DB 0x00,0x21,0x42,0x63,0x84,0xA5,0xC6,0xE7,0x08,0x29,0x4A,0x6B,0x8C,0xAD,0xCE,0xEF
  75.                 DB 0x31,0x10,0x73,0x52,0xB5,0x94,0xF7,0xD6,0x39,0x18,0x7B,0x5A,0xBD,0x9C,0xFF,0xDE
  76.                 DB 0x62,0x43,0x20,0x01,0xE6,0xC7,0xA4,0x85,0x6A,0x4B,0x28,0x09,0xEE,0xCF,0xAC,0x8D
  77.                 DB 0x53,0x72,0x11,0x30,0xD7,0xF6,0x95,0xB4,0x5B,0x7A,0x19,0x38,0xDF,0xFE,0x9D,0xBC
  78.                 DB 0xC4,0xE5,0x86,0xA7,0x40,0x61,0x02,0x23,0xCC,0xED,0x8E,0xAF,0x48,0x69,0x0A,0x2B
  79.                 DB 0xF5,0xD4,0xB7,0x96,0x71,0x50,0x33,0x12,0xFD,0xDC,0xBF,0x9E,0x79,0x58,0x3B,0x1A
  80.                 DB 0xA6,0x87,0xE4,0xC5,0x22,0x03,0x60,0x41,0xAE,0x8F,0xEC,0xCD,0x2A,0x0B,0x68,0x49
  81.                 DB 0x97,0xB6,0xD5,0xF4,0x13,0x32,0x51,0x70,0x9F,0xBE,0xDD,0xFC,0x1B,0x3A,0x59,0x78
  82.                 DB 0x88,0xA9,0xCA,0xEB,0x0C,0x2D,0x4E,0x6F,0x80,0xA1,0xC2,0xE3,0x04,0x25,0x46,0x67
  83.                 DB 0xB9,0x98,0xFB,0xDA,0x3D,0x1C,0x7F,0x5E,0xB1,0x90,0xF3,0xD2,0x35,0x14,0x77,0x56
  84.                 DB 0xEA,0xCB,0xA8,0x89,0x6E,0x4F,0x2C,0x0D,0xE2,0xC3,0xA0,0x81,0x66,0x47,0x24,0x05
  85.                 DB 0xDB,0xFA,0x99,0xB8,0x5F,0x7E,0x1D,0x3C,0xD3,0xF2,0x91,0xB0,0x57,0x76,0x15,0x34
  86.                 DB 0x4C,0x6D,0x0E,0x2F,0xC8,0xE9,0x8A,0xAB,0x44,0x65,0x06,0x27,0xC0,0xE1,0x82,0xA3
  87.                 DB 0x7D,0x5C,0x3F,0x1E,0xF9,0xD8,0xBB,0x9A,0x75,0x54,0x37,0x16,0xF1,0xD0,0xB3,0x92
  88.                 DB 0x2E,0x0F,0x6C,0x4D,0xAA,0x8B,0xE8,0xC9,0x26,0x07,0x64,0x45,0xA2,0x83,0xE0,0xC1
  89.                 DB 0x1F,0x3E,0x5D,0x7C,0x9B,0xBA,0xD9,0xF8,0x17,0x36,0x55,0x74,0x93,0xB2,0xD1,0xF0
  90.  
  91. ; быстрая (табличная) функция подсчёта CRC-16,
  92. ; IX = *DATA, HL = SIZE
  93. ; на выходе: -> HL = подсчитанное значение
  94. CRC16_FAST      LD B,H
  95.                 LD C,L
  96.                 LD HL,0xFFFF
  97.                 EXX
  98.                 PUSH HL
  99.                 LD DE,BUF_CRC16_TABL
  100.                 LD C,0
  101.                 EXX
  102. CRC16F0         LD A,(IX)
  103.                 XOR H
  104.                 INC IX
  105.                 EXX
  106.                 LD L,A
  107.                 LD H,C
  108.                 ADD HL,DE
  109.                 LD A,(HL)
  110.                 INC H
  111.                 EXX
  112.                 XOR L
  113.                 LD H,A
  114.                 EXX
  115.                 LD A,(HL)
  116.                 EXX
  117.                 LD L,A
  118.                 DEC BC
  119.                 LD A,B
  120.                 OR C
  121.                 JP NZ,CRC16F0
  122.                 EXX
  123.                 POP HL
  124.                 EXX
  125.                 RET
  126.  
  127. ; установка обработчиков RST 8 и NMI, инициализация переменных
  128. INSTALL_NMIRST
  129.         ATMPORT WIN_A3,0x40                     ; сняли зависимость от порта 7FFD
  130.         EVOPORT WIN_P6,0                        ; включили страницу переменных
  131.                 LD BC,FDD_EMU_PORT
  132.                 XOR A
  133.                 OUT (C),A                       ; сброс виртуальных дисководов
  134.                 LD (B_PORT_VIRT),A
  135.                 LD A,0xEF
  136.                 IN A,(0xFE)
  137.                 RRCA
  138.                 JR NC,.L2
  139.                 LD IX,CPU2+STACK_NMI
  140.                 LD HL,0x40
  141.                 CALL CRC16_FAST                 ; считаем CRC на месте обработчика
  142.                 PUSH HL                         ; сохранили CRC
  143.                 LD IX,CODE_NMIRST + STACK_NMI
  144.                 LD HL,0x40
  145.                 CALL CRC16_FAST
  146.                 POP BC                          ; вернули ранее посчитанное CRC
  147.                 XOR A
  148.                 SBC HL,BC                       ; сравнили
  149.                 JR Z,.L1                        ; если совпало больше ничего не делаем
  150.         EVOPORT WIN_P3,RAM_PROFROM
  151.                 LD HL,CPU0
  152.                 CALL FILL_MEM                   ; очистка страницы ОЗУ PROFROM
  153. ; не совпало, первый запуск после включения питания или обработчики были испорчены
  154. .L2             LD A,(HDDTIMEOUT)               ; сохраняем ячейку вне зависимости от содежимого
  155.                 LD HL,CPU3
  156.                 CALL FILL_MEM                   ; очистка последней страницы RAM
  157.                 LD (HDDTIMEOUT),A               ; восстанавливаем ячейку
  158.                 LD HL,CODE_NMIRST
  159.                 LD DE,CPU6
  160.                 LD BC,ENMI_SERVICE - ADR_SEL_ROM - CPU6
  161.                 LDIR                            ; установили обработчики
  162.                 LD (BUF_TABLVOL + 0xFE),BC      ; сброс CRC таблицы найденных разделов
  163.         EVOPORT WIN_P3,RAM_MOUNTER              ; включили страницу монтировщика образов
  164.                 LD HL,CPU0
  165.                 CALL FILL_MEM                   ; очистка страницы монтировщика образов
  166.                 XOR A
  167.                 LD (CPU6 + DEBUG_ONOFF),A       ; 0 - DEBUGGER OFF
  168.                 LD (FLAGS_DRV),A                ; сброс флагов драйверов
  169.                 LD A,CMOS_BYTE_00
  170.                 LD BC,CMOSD_SET_ADR
  171.                 OUT (C),A
  172.                 LD BC,CMOSD_RD_WR
  173.                 IN A,(C)
  174.                 CALL LD_SET_FONT
  175.                 LD A,VIRT_REAL_DRIVE
  176.                 LD BC,CMOSD_SET_ADR
  177.                 OUT (C),A
  178.                 LD BC,CMOSD_RD_WR
  179.                 IN A,(C)
  180.                 LD (CPU2 + VIRT_BITS),A         ; при ините монтируем только рамдиск
  181. .L1
  182.         IF BUILD_DEBUG=1
  183.         ROMCALL UNPACK_STS,ROM_RST80
  184.         ENDIF
  185.         ROMCALL INIT_CMOS,ROM_RST82             ; проверка и инициализация CMOS при ошибке CRC
  186.                 CALL SET4RESETFONT
  187.         IF 0;USB_ENABLE
  188.         EVOPORT WIN_P3,RAM_SCR_FONT             ; страницы для драйвера
  189.         EVOPORT WIN_A2,ROM_RST83
  190.                 LD HL,USB_DRV + CPU2            ; адрес драйвера
  191.                 LD DE,OFFSET_USBDRV + CPU3      ; адрес работы
  192.                 LD BC,ECOMUSBF - COMUSBF
  193.                 LDIR
  194.         EVOPORT WIN_P6,0
  195.         ENDIF
  196.                 LD BC,0xFF << 8 + PN_1F7
  197.                 IN A,(C)
  198.                 CP 0x50
  199.                 LD A,1
  200.                 JR Z,.L3
  201.                 LD A,(HDDTIMEOUT)
  202.                 DEC A
  203.                 JR Z,.L5                        ; если ячейка равна 1 задержку из CMOS игнорируем
  204.                 LD H,HDD_TIMEOUT
  205.         ROMCALL READCMOS,ROM_RST82
  206.                 AND A
  207.                 LD A,1
  208.                 JR Z,.L3
  209.                 XOR A
  210. .L4             ADD A,25
  211.                 DEC L
  212.                 JR NZ,.L4
  213. .L3             LD (HDDTIMEOUT),A
  214. .L5             LD HL,STEK_PAGES
  215.                 LD (TEKPAGE),HL
  216.                 LD HL,READ_KEYS
  217.                 LD (ADR_INT),HL
  218.                 LD BC,WIN_A0
  219.                 XOR A
  220.                 LD (CPU6 + FOR_RET),A
  221.                 JP ADR_SEL_ROM
  222.  
  223. FILL_MEM        EX DE,HL
  224.                 LD HL,0
  225.                 ADD HL,SP
  226.                 EX DE,HL
  227.                 LD SP,HL
  228.                 LD HL,0
  229.                 LD B,L
  230. FILL_MEM1
  231.         REPT 0x20
  232.                 PUSH HL
  233.         ENDM
  234.                 DJNZ FILL_MEM1
  235.                 EX DE,HL
  236.                 LD SP,HL
  237.                 RET
  238.  
  239. SETUP_FONT      LD A,(RREG_A)
  240.                 AND A
  241.                 LD HL,ATM_FONT
  242.                 JR Z,SET_FONT1
  243.                 DEC A
  244.                 LD HL,CP866_FONT
  245.                 JR Z,SET_FONT1
  246.                 DEC A
  247.                 RET NZ
  248.                 LD HL,(RREG_L)
  249.                 JR SET_FONT1
  250.  
  251. SET4RESETFONT   LD A,CMOS_BYTE_00
  252.                 LD BC,CMOSD_SET_ADR
  253.                 OUT (C),A
  254.                 LD BC,CMOSD_RD_WR
  255.                 IN A,(C)
  256.                 LD L,A
  257.                 AND M_RELOAD_FONT
  258.                 RET NZ                          ; если 1, то шрифт не перезагружаем
  259.                 LD A,L
  260. LD_SET_FONT     AND M_TYPE_FONT                 ; определение выбранного шрифта
  261.                 LD HL,ATM_FONT                  ; 0 = шрифт ATM
  262.                 JR Z,SET_FONT1
  263.                 LD HL,CP866_FONT                ; 1 = шрифт CP866
  264. SET_FONT1       LD DE,CPU3 + OFFSET_BUFSYM
  265.         EVOPORT WIN_P3,RAM_SCR_FONT
  266.                 PUSH DE
  267.         ROMCALL UNPACK,ROM_RST80
  268.                 POP HL
  269.                 LD BC,0x0800
  270.                 LD D,C
  271.                 LD E,C
  272.         PEC_ON M_SHADOW_BF+M_FONT_BF
  273.                 LDIR
  274.         PEC_OFF M_FONT_BF
  275.                 RET
  276.  
  277. CurrAdr := $
  278.  
  279.                 include nmi_service.a80
  280.  
  281.                 PHASE $ + CurrAdr
  282. PERFECTCOM      binclude perfpack_pack.bin
  283.  
  284. FREE_ADDON1     EQU 0x3FF6 - $
  285.  
  286.                 DUPL FREE_ADDON1,0xFF
  287.                 DW FREE_ADDON1                  ; размер свободного места
  288.                 DB "ADDON1"
  289.                 DW DATA_VERS
  290.