Subversion Repositories pentevo

Rev

Rev 832 | Rev 999 | Go to most recent revision | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed | ?url?

  1.  
  2. ;LAST UPDATE: 04.08.2019 savelij
  3.  
  4.                 TITLE "virtual.a80"
  5.  
  6.                 DB 0XFF                         ;DCU
  7.  
  8. ;[КОПИРОВАНИЕ 256 БАЙТ]
  9. COPY_BLOCK      REPT 128                        ;КОПИРОВАНИЕ БЛОКА 256 БАЙТ
  10.                 LDI
  11.                 ENDM
  12. COPYHBLOCK      REPT 126
  13.                 LDI
  14.                 ENDM
  15.                 JR COPY_BLOCK1
  16.                
  17.                 DW 0XFFFF                       ;ДЛЯ ВЕКТОРА ПРЕРЫВАНИЙ IM2 I=9
  18.  
  19. COPY_BLOCK1     LDI
  20.                 LDI
  21.                 RET
  22.  
  23. ;номера внутренних функций
  24.  INIT_VAR
  25.  SETVAR _OUT_1F
  26.  SETVAR _OUT_3F
  27.  SETVAR _OUT_5F
  28.  SETVAR _OUT_7F
  29.  SETVAR _OUT_FF
  30.  SETVAR _OUTI
  31.  SETVAR _IN_1F
  32.  SETVAR _IN_3F
  33.  SETVAR _IN_5F
  34.  SETVAR _IN_7F
  35.  SETVAR _IN_FF
  36.  SETVAR _INI
  37.  SETVAR _OUT_C_D
  38.  SETVAR _IN_H_C
  39.  SETVAR _WR_RD_SECT
  40.  SETVAR _CMP_RAMDISK
  41.  SETVAR _SET_VIRT_BITS
  42.  
  43.  SETVAR WOUTCA
  44.  SETVAR WWRITE_SEC_
  45.  SETVAR WREAD_SEC_
  46.  SETVAR WINI_RET
  47.  
  48. ;адреса внутренних функций
  49. ;[С ВОЗВРАТОМ В МЕСТО ВЫЗОВА]
  50. W_DATA          DW W_OUT1F                      ;00 ЗАПИСЬ ПОРТА 1F
  51.                 DW W_OUT3F                      ;01 ЗАПИСЬ ПОРТА 3F
  52.                 DW W_OUT5F                      ;02 ЗАПИСЬ ПОРТА 5F
  53.                 DW W_OUT7F                      ;03 ЗАПИСЬ ПОРТА 7F
  54.                 DW W_OUTFF                      ;04 ЗАПИСЬ ПОРТА FF
  55.                 DW W_OUTI                       ;05 OUTI
  56.                 DW W_IN1F                       ;06 ЧТЕНИЕ ПОРТА 1F
  57.                 DW W_IN3F                       ;07 ЧТЕНИЕ ПОРТА 3F
  58.                 DW W_IN5F                       ;08 ЧТЕНИЕ ПОРТА 5F
  59.                 DW W_IN7F                       ;09 ЧТЕНИЕ ПОРТА 7F
  60.                 DW W_INFF                       ;0A ЧТЕНИЕ ПОРТА FF
  61.                 DW W_INI                        ;0B INI
  62.                 DW W_OUTCD                      ;0C ЗАПИСЬ РЕГИСТРА 'D' В ПОРТ 'BC'
  63.                 DW W_INHC                       ;0D ЧТЕНИЕ В РЕГИСТР 'H' ИЗ ПОРТА 'BC'
  64.                 DW READ_WRITE_SEC               ;0E ЧТЕНИЕ/ЗАПИСЬ СЕКТОРА
  65.                 DW CMP_RAM_DISK                 ;12 ПРОВЕРКА RAM ДИСКА
  66.                 DW SET_VIRT_BITS                ;13 УСТАНОВКА ПЕРЕМЕННОЙ СЧИТАННОЙ ИЗ RST 8
  67. EW_DATA
  68. ;[БЕЗ ВОЗВРАТА В МЕСТО ВЫЗОВА]
  69.                 DW W_OUTCA                      ;13 ЗАПИСЬ РЕГИСТРА 'A' В ПОРТ 'BC'
  70.                 DW WRITE_SEC_                   ;14 ЗАПИСЬ СЕКТОРА БЕЗ ВОЗВРАТА В АДРЕС ВЫЗОВА
  71.                 DW READ_SEC_                    ;15 ЧТЕНИЕ СЕКТОРА БЕЗ ВОЗВРАТА В АДРЕС ВЫЗОВА
  72.                 DW W_INI                        ;16 INI БЕЗ ВОЗВРАТА В АДРЕС ВЫЗОВА
  73.  
  74. TEXT4VIRTDRV    DB 0X16,ZASTV_Y+2,1
  75. TXT4VIRTDRV     DC "Virtual Drive: "
  76. ETXT4VIRTDRV
  77.  
  78. DOS_NOEMUL      DB ROM_BAS48 | 0X80             ;СТРАНИЦА DOS С ЭМУЛЯЦИЕЙ ТОЛЬКО ДЛЯ 3D13
  79. DOS_EMUL        DB ROM_ADD_BAS48 | 0X80         ;СТРАНИЦА DOS С ПОЛНЫМ ПЕРЕХВАТОМ ПОРТОВ
  80.  
  81. NUM_ALT_PAGE    IF EMU3D2F=1
  82.                 DB ROM_ADD_BAS48 | 0X80
  83.                 ELSE
  84.                 DB ROM_BAS48 | 0X80
  85.                 ENDIF
  86.  
  87. ;[ОБРАБОТЧИК RST 30]
  88. RST30_WORK      EX (SP),HL
  89.                 PUSH AF
  90.                 PUSH BC
  91.                 LD A,I
  92.                 JP PE,RST30_WORK1
  93.                 LD A,I
  94. RST30_WORK1     DI
  95.                 PUSH AF
  96.                 LD A,(NUM_ALT_PAGE)             ;НОМЕР ТЕКУЩЕЙ СТРАНИЦЫ ПЗУ
  97.                 PUSH AF
  98.                 AND 0X3E                        ;НОМЕР РЕАЛЬНОЙ СТРАНИЦЫ БЕЗ ЗАВИСИМОСТИ
  99.                 LD BC,WIN_A0
  100.                 OUT (C),A
  101.                 LD B,HIGH (WIN_P0)
  102.                 LD A,RAM_EVODOS
  103.                 OUT (C),A
  104.                 IN A,(PEVO_CONF)
  105.                 LD (WR_BF),A
  106.                 OR 1
  107.                 OUT (PEVO_CONF),A
  108.                 POP AF
  109.                 LD (TEK_ROMPAGE),A
  110.                 LD A,(HL)
  111.                 LD (DOS_STEK),SP
  112.                 LD SP,DOS_STEK
  113.                 PUSH HL                         ;ПОЛОЖИЛИ HL=АДРЕС ВОЗВРАТА
  114.                 PUSH DE
  115.                 LD HL,(DOS_STEK)
  116.                 LD DE,REG_IF
  117.                 REPT 8
  118.                 LDI
  119.                 ENDM
  120.                 LD HL,EXIT_RST30
  121.                 PUSH HL                         ;ПОЛОЖИЛИ АДРЕС ЗАВЕРШЕНИЯ
  122.                 LD HL,W_DATA
  123.                 ADD A,A
  124.                 ADD A,L        
  125.                 LD L,A
  126.                 LD A,(HL)
  127.                 INC L
  128.                 LD H,(HL)
  129.                 LD L,A
  130.                 JP (HL)
  131.  
  132. EXIT_RST30      LD HL,REG_IF
  133.                 LD DE,(DOS_STEK)
  134.                 REPT 8
  135.                 LDI
  136.                 ENDM
  137.                 POP DE
  138.                 POP HL
  139.                 LD SP,(DOS_STEK)
  140.                 LD A,(HL)
  141.                 INC HL
  142.                 CP LOW ((EW_DATA-W_DATA)/2)
  143.                 JR C,EXIT_RST302
  144.                 LD HL,FOR_RET                   ;АДРЕС ВЫХОДА БЕЗ ВОЗВРАТА В МЕСТО ВЫЗОВА
  145. EXIT_RST302     PUSH HL
  146.                 LD HL,(COPY_VIRT_BITS)
  147.                 LD A,(MASK_MNT_DRV)
  148.                 AND L
  149.                 LD A,ROM_ADD_BAS48 | 0X80       ;СТРАНИЦА ДЛЯ 3D2F
  150.                 JR NZ,EXIT_RST305               ;ВЫБОР ROM 3D2F ЕСЛИ ЕСТЬ ПРИМОНТИРОВАННЫЙ
  151.                 LD HL,(VIRT_DRIVE)              ;ИЛИ ПРОВЕРКА ДЛЯ РАМДИСКА
  152.                 LD A,(MASK_WRK_DRV)
  153.                 CP L
  154.                 LD A,ROM_ADD_BAS48 | 0X80       ;СТРАНИЦА ДЛЯ 3D2F
  155.                 JR Z,EXIT_RST305
  156.                 LD A,ROM_BAS48 | 0X80           ;СТРАНИЦЫ ДЛЯ 3D13
  157. EXIT_RST305     LD HL,(WR_BF)
  158.                 LD BC,WIN_A0
  159. EXIT_RST303     CALL WR_BYTE_RET
  160.                 LD A,L
  161.                 POP HL
  162.                 OUT (PEVO_CONF),A
  163.                 POP AF
  164.                 JP PO,EXIT_RST304
  165.                 EI
  166. EXIT_RST304     POP BC
  167.                 POP AF
  168.                 EX (SP),HL
  169.                 RET
  170.  
  171. ;[ЗАПИСЬ "A" В ПОРТ 0X1F]
  172. W_OUT1F         LD A,(REG_A)
  173.                 LD (WR_1F),A
  174.                 CP 0X10
  175.                 JR NC,W_OUT1F10
  176. ;00-0F КОМАНДА ВОССТАНОВЛЕНИЯ
  177.                 XOR A
  178.                 LD (PORT_3F),A
  179.                 LD (PORT_5F),A
  180.                 OUT (0X3F),A
  181.                 OUT (0X5F),A
  182.                 JR INFF_BIT6
  183.  
  184. W_OUT1F10       CP 0X20
  185.                 JR NC,W_OUT1F20
  186. ;10-1F КОМАНДА ПОИСКА
  187.                 LD A,(PORT_7F)
  188.                 LD (PORT_3F),A 
  189.                 OUT (0X3F),A
  190.                 CALL DISK_NONE
  191.                 LD A,0X80
  192.                 JR C,INFF_BIT61
  193. INFF_BIT6       XOR A
  194. INFF_BIT61      LD (RD_1F),A
  195.                 LD A,0XBF
  196.                 LD (RD_FF),A
  197.                 RET
  198.  
  199. W_OUT1F20       CP 0X40
  200.                 JR NC,W_OUT1F40
  201. ;20-3F КОМАНДА ШАГ В ПРЕДЫДУЩЕМ НАПРАВЛЕНИИ
  202.                 LD A,(PORT_3F)
  203. NAPRAVL         NOP
  204.                 LD (PORT_3F),A
  205.                 OUT (0X3F),A
  206.                 JR INFF_BIT6
  207.  
  208. W_OUT1F40       CP 0X60
  209.                 JR NC,W_OUT1F60
  210. ;40-5F КОМАНДА ШАГ ВПЕРЕД
  211.                 LD A,(PORT_3F)
  212.                 INC A
  213.                 LD (PORT_3F),A 
  214.                 OUT (0X3F),A
  215.                 LD A,0X3C
  216.                 LD (NAPRAVL),A
  217.                 JR INFF_BIT6
  218.  
  219. W_OUT1F60       CP 0X80
  220.                 JR NC,W_OUT1F80
  221. ;60-7F КОМАНДА ШАГ НАЗАД
  222.                 LD A,(PORT_3F)
  223.                 DEC A
  224.                 LD (PORT_3F),A 
  225.                 OUT (0X3F),A
  226.                 LD A,0X3D
  227.                 LD (NAPRAVL),A
  228.                 JR INFF_BIT6
  229.  
  230. W_OUT1F80       CP 0XA0
  231.                 JR NC,W_OUT1FA0
  232. ;80-9F КОМАНДА ЧТЕНИЕ СЕКТОРА
  233.                 JR INFF_BIT6
  234.  
  235. W_OUT1FA0       CP 0XC0
  236.                 JR NC,W_OUT1FD0
  237. ;A0-BF КОМАНДА ЗАПИСЬ СЕКТОРА
  238.                 JR INFF_BIT6
  239.  
  240. INFF_BIT7       XOR A
  241.                 LD (RD_1F),A
  242.                 LD A,0X7F
  243.                 LD (RD_FF),A
  244.                 RET
  245.  
  246. W_OUT1FD0       CP 0XD0
  247.                 JR NC,W_OUT1FE0
  248. ;C0-CF ЧТЕНИЕ АДРЕСА
  249.                 JR INFF_BIT6
  250.  
  251. W_OUT1FE0       CP 0XE0
  252.                 JR NC,W_OUT1FF0
  253. ;D0-DF ПРИНУДИТЕЛЬНОЕ ПРЕРЫВАНИЕ
  254.                 LD A,0XBF
  255.                 LD (RD_FF),A
  256.                 RET
  257.  
  258. W_OUT1FF0       CP 0XF0
  259.                 JR C,INFF_BIT6
  260. ;E0-EF ЧТЕНИЕ ДОРОЖКИ
  261.                 JR INFF_BIT6
  262.  
  263. ;[ЗАПИСЬ "A" В ПОРТ 0X3F]
  264. W_OUT3F         LD A,(REG_A)
  265.                 LD (PORT_3F),A
  266.                 OUT (0X3F),A
  267.                 RET
  268.  
  269. ;[ЗАПИСЬ "A" В ПОРТ 0X5F]
  270. W_OUT5F         LD A,(REG_A)
  271.                 LD (PORT_5F),A
  272.                 OUT (0X5F),A
  273.                 RET
  274.  
  275. ;[ЗАПИСЬ "A" В ПОРТ 0X7F]
  276. W_OUT7F         LD A,(REG_A)
  277.                 LD (PORT_7F),A
  278.                 OUT (0X7F),A
  279.                 RET
  280.  
  281. ;[ЗАПИСЬ "A" В ПОРТ 0XFF]
  282. W_OUTFF         LD A,(REG_A)
  283.                 LD (WR_FF),A
  284.                 OUT (0XFF),A
  285.                 AND 3
  286.                 LD (MASK_WRK_DRV),A             ;номер дисковода
  287.                 INC A
  288.                 LD B,A
  289.                 LD A,%00001000
  290. .L1             RLCA
  291.                 DJNZ .L1
  292.                 LD (MASK_MNT_DRV),A             ;маска смонтированного дисковода
  293.                 RET
  294.  
  295. ;[ЗАПИСЬ "A" В ПОРТ (C)]
  296. W_OUTCA         LD A,(REG_A)
  297. W_OUTCA1        LD D,A
  298.                 LD BC,(REG_C)                   ;ЕСЛИ ПОРТ НЕ TR-DOS
  299.                 LD A,C
  300. ;ОПРЕДЕЛЕНИЕ В КАКОЙ ПОРТ ЗАПИСЬ       
  301.                 CP 0X1F
  302.                 JP Z,W_OUT1F
  303.                 CP 0X3F
  304.                 JR Z,W_OUT3F
  305.                 CP 0X5F
  306.                 JR Z,W_OUT5F
  307.                 CP 0X7F
  308.                 JR Z,W_OUT7F
  309.                 CP 0XFF
  310.                 JR Z,W_OUTFF
  311.                 CP LOW (WIN_A0)
  312.                 JR Z,W_OUTCA3
  313. W_OUTCA4        OUT (C),D
  314.                 RET
  315.  
  316. ;[ЗАПИСЬ В ПОРТЫ ATM/PENTEVO]
  317. W_OUTCA3        LD A,B
  318.                 LD HL,BB_CPU1
  319.                 CP HIGH (WIN_A1)
  320.                 JR Z,W_OUTCA2
  321.                 CP HIGH (WIN_P2)
  322.                 JR Z,W_OUTCA2
  323.                 LD HL,BB_CPU2
  324.                 CP HIGH (WIN_A2)
  325.                 JR Z,W_OUTCA2
  326.                 CP HIGH (WIN_P2)
  327.                 JR NZ,W_OUTCA4
  328. W_OUTCA2        LD E,B
  329.                 PUSH DE
  330.                 PUSH HL
  331.                 CALL READ_WCPU12
  332.                 POP HL
  333.                 POP DE
  334.                 LD (HL),D
  335.                 INC HL
  336.                 LD (HL),E
  337.                 JP WRITE_WCPU12
  338.  
  339. ;[ЗАПИСЬ "D" В ПОРТ (C)]
  340. W_OUTCD         LD A,(IREG_D)
  341.                 JR W_OUTCA1
  342.  
  343. ;[ПЕРЕДАЧА БАЙТА, КОМАНДА OUTI]
  344. W_OUTI          LD HL,(BUFF_SECT)
  345.                 EXX
  346.                 LD A,(HL)
  347.                 INC HL
  348.                 EXX
  349.                 LD (HL),A
  350.                 INC HL
  351.                 LD (BUFF_SECT),HL
  352.                 RET
  353.  
  354. ;[ЧТЕНИЕ ПОРТА 0X1F]
  355. W_IN1F          LD A,(WR_1F)
  356.                 AND 0XF0
  357.                 CP 0X10
  358.                 JR C,W_IN1F1
  359.                 CP 0X20
  360.                 JR C,W_IN1F3
  361.                 CP 0XD0
  362.                 JR Z,W_IN1F1
  363.                 XOR A
  364.                 JR W_IN1F2
  365.  
  366. W_IN1F3         LD A,(INDEX)
  367.                 XOR %00000100
  368.                 JR W_IN1F4
  369.  
  370. W_IN1F1         LD A,0X24
  371. INDEX           EQU $-1
  372. W_IN1F4         XOR %00000010
  373.                 LD (INDEX),A
  374. W_IN1F2         LD (RD_1F),A
  375.                 LD (REG_A),A
  376.                 RET
  377.  
  378. ;[ЧТЕНИЕ ПОРТА 0X3F]
  379. W_IN3F          LD A,(PORT_3F)
  380.                 LD (REG_A),A
  381.                 RET
  382.  
  383. ;[ЧТЕНИЕ ПОРТА 0X5F]
  384. W_IN5F          LD A,(PORT_5F)
  385.                 LD (REG_A),A
  386.                 RET
  387.  
  388. ;[ЧТЕНИЕ ПОРТА 0X7F]
  389. W_IN7F          LD A,(PORT_7F)
  390.                 LD (REG_A),A
  391.                 RET
  392.  
  393. ;[ЧТЕНИЕ ПОРТА 0XFF]
  394. W_INFF          LD A,(RD_FF)
  395.                 LD (REG_A),A
  396.                 RET
  397.  
  398. ;[ЧТЕНИЕ В "H" ИЗ (С)]
  399. W_INHC          LD A,(REG_C)
  400. ;[ОПРЕДЕЛЕНИЕ ИЗ КАКОГО ПОРТА ЧТЕНИЕ]
  401. W_INHC1         CP 0X1F
  402.                 JR NZ,W_INHC2
  403.                 LD A,(RD_1F)
  404.                 LD (REG_H),A
  405.                 RET
  406.  
  407. W_INHC2         CP 0X3F
  408.                 JR NZ,W_INHC3
  409.                 LD A,(PORT_3F)
  410.                 LD (REG_H),A
  411.                 RET
  412.        
  413. W_INHC3         CP 0X5F
  414.                 JR NZ,W_INHC4
  415.                 LD A,(PORT_5F)
  416.                 LD (REG_H),A
  417.                 RET
  418.        
  419. W_INHC4         CP 0X7F
  420.                 JR NZ,W_INHC5
  421.                 LD A,(PORT_7F)
  422.                 LD (REG_H),A
  423.                 RET
  424.        
  425. W_INHC5         CP 0XFF
  426.                 JR NZ,W_INHC6
  427.                 LD A,(WR_FF)
  428.                 LD (REG_H),A
  429.                 RET
  430.  
  431. W_INHC6         LD BC,(REG_C)
  432.                 IN A,(C)
  433.                 LD (REG_H),A
  434.                 RET
  435.  
  436. ;[ЧТЕНИЕ INI]
  437. W_INI           LD A,(RD_1F)
  438.                 LD HL,(REG_L)
  439.                 LD (HL),A
  440.                 INC HL
  441.                 DEC B
  442.                 LD (REG_L),HL
  443.                 RET
  444.  
  445. ;[ЧТЕНИЕ СЕКТОРА ИЛИ ПОРТОВ]
  446. READ_SEC_       LD A,(WR_1F)
  447.                 AND 0X0F0
  448.                 CP 0X80
  449.                 JP C,INFF_BIT6
  450.                 CP 0XC0
  451.                 JR NZ,READ_SEC_1
  452.                 LD A,(PORT_3F)
  453.                 LD HL,(REG_L)
  454.                 LD (HL),A
  455.                 INC HL
  456.                 DEC B
  457.                 LD A,(PORT_5F)
  458.                 LD (HL),A
  459.                 INC HL
  460.                 DEC B
  461.                 LD (REG_L),HL
  462.                 RET
  463.  
  464. ;[ЧТЕНИЕ/ЗАПИСЬ СЕКТОРА]
  465. ;IXL=0-ЧТЕНИЕ, =FF-ЗАПИСЬ
  466. READ_WRITE_SEC  PUSH IX
  467.                 JR WRITE_SEC_1
  468.  
  469. ;[ЧТЕНИЕ СЕКТОРА]
  470. READ_SEC_1      PUSH IX
  471.                 LD IXL,0
  472.                 JR WRITE_SEC_1
  473.  
  474. ;[ЗАПИСЬ СЕКТОРА]
  475. WRITE_SEC_      PUSH IX
  476.                 LD IXL,0XFF
  477. WRITE_SEC_1     CALL READ_WCPU12
  478.                 CALL W_WR_RD_SECT
  479.                 LD IX,0X8090
  480.                 LD (REG_F),IX                   ;ЭМУЛЯЦИЯ ФЛАГА УСПЕШНОГО ЧТЕНИЯ/ЗАПИСИ СЕКТОРА
  481.                 CALL WRITE_WCPU12
  482.                 POP IX
  483.                 RET
  484.  
  485. ;[ЧТЕНИЕ ИЛИ ЗАПИСЬ СЕКТОРА РАМДИСКА]
  486. W_WR_RD_SECT    LD A,(WR_FF)
  487.                 AND 3
  488.                 INC A
  489.                 LD B,A
  490.                 LD A,(COPY_VIRT_BITS)
  491.                 REPT 5
  492.                 RRCA
  493.                 ENDM
  494.                 DJNZ $-1
  495.                 JP C,WR_RD_SEC_M                ;РАБОТА С ПРИМОНТИРОВАННЫМ ОБРАЗОМ
  496.                 LD BC,WIN_A1
  497.                 LD A,0X40
  498.                 OUT (C),A
  499.                 LD B,HIGH (WIN_P1)
  500.                 LD A,RAM_RAMDISK
  501.                 OUT (C),A                       ;СТРАНИЦА ЗАГОЛОВКОВ РАМДИСКА
  502.                 LD A,(PORT_3F)                  ;ВЗЯЛИ НОМЕР ТРЕКА
  503.                 ADD A,A                         ;СТОРОН 2
  504.                 LD C,A
  505.                 LD A,(WR_FF)
  506.                 AND 0X10                        ;ПРОВЕРКА КАКАЯ СТОРОНА ДИСКА
  507.                 JR NZ,WWRRD1
  508.                 INC C                           ;ДЛЯ СТОРОНЫ 1
  509. WWRRD1          LD B,HIGH (CPU1)+2              ;АДРЕС НАЧАЛА ИНФЫ О СЕКТОРАХ НА ДОРОЖКЕ
  510.                 LD A,(PORT_5F)                  ;ВЗЯЛИ НОМЕР СЕКТОРА
  511.                 LD L,A
  512.                 LD H,0
  513. WWRRD3          LD A,(BC)
  514.                 LD D,A                          ;ВЗЯЛИ НОМЕР СЕКТОРА
  515.                 INC B
  516.                 LD A,(BC)
  517.                 LD E,A                          ;ВЗЯЛИ РАЗМЕР СЕКТОРА
  518.                 INC B
  519. ;               LD A,D
  520. ;               AND A
  521. ;               JR Z,WWRRD_ERR
  522.                 LD A,L
  523.                 CP D
  524.                 JR Z,WWRRD2
  525.                 LD A,E
  526.                 ADD A,H
  527.                 LD H,A
  528.                 JR WWRRD3
  529.  
  530. WWRRD2          LD A,E
  531.                 RRCA
  532.                 LD (PORT_7F),A 
  533.                 OUT (0X7F),A                    ;РАЗМЕР НАЙДЕННОГО СЕКТОРА
  534.                 LD L,0
  535.                 LD E,L
  536.                 SRL H
  537.                 RR L                            ;HL=СМЕЩЕНИЕ В БЛОКАХ ДО НАЙДЕННОГО СЕКТОРА
  538.                 LD B,HIGH (CPU1)
  539.                 LD A,(BC)
  540.                 LD D,A
  541.                 ADD HL,DE                       ;HL=СМЕЩЕНИЕ ОТ НАЧАЛА СТРАНИЦЫ В БЛОКАХ
  542.                 INC B
  543.                 LD A,(BC)
  544.                 LD C,A                          ;СМЕЩЕНИЕ В СТРАНИЦАХ ОТ НАЧАЛА РАМДИСКА
  545.                 LD A,H
  546.                 CP HIGH (CPU1)
  547.                 JR C,WWRRD5
  548.                 SUB 0X40
  549.                 LD H,A
  550.                 INC C
  551. ;HL=СМЕЩЕНИЕ В СТРАНИЦЕ ДО НАЧАЛА СЕКТОРА
  552. WWRRD5          LD A,C                          ;СМЕЩЕНИЕ ДО НОМЕРА СТРАНИЦЫ, ГДЕ УКАЗАННЫЙ СЕКТОР НАЧИНАЕТСЯ
  553.                 ADD A,RAM_DATARAMD              ;ПРИБАВИЛИ НОМЕР НАЧАЛА РАМДИСК И +1. В 0 СТРАНИЦЕ РАМДИСКА ОПИСАТЕЛИ СЕКТОРОВ
  554.                 LD IXH,A                        ;СОХРАНИЛИ НОМЕР ВЫЧИСЛЕННОЙ СТРАНИЦЫ
  555.                 LD DE,(REG_L)
  556.                 LD BC,(BB_CPU1)
  557.                 LD A,C
  558.                 LD C,LOW (WIN_A0)
  559.                 OUT (C),A                       ;ВЕРНУЛИ СТАНДАРТНУЮ 5 СТРАНИЦУ
  560. SP_RAMD9        LD A,D                          ;ПРОВЕРКА ГРАНИЦЫ ОТКУДА/КУДА КОПИРОВАТЬ
  561.                 CP HIGH (CPU2)
  562.                 PUSH DE
  563.                 LD DE,CPU1+HIGH (WIN_P1)
  564.                 LD BC,WIN_A1                    ;ЕСЛИ ВЕРХНИЕ 32КБ ОЗУ, ТО НУЖНО ВКЛЮЧИТЬ В 1 ОКНЕ ПРОЕЦИРОВАНИЯ
  565.                 JR NC,SP_RAMD1
  566.                 LD DE,CPU2+HIGH (WIN_P2)
  567.                 LD B,HIGH (WIN_A2)              ;ЕСЛИ НИЖНИЕ 32КБ ОЗУ, ТО НУЖНО ВКЛЮЧИТЬ ВО 2 ОКНЕ ПРОЕЦИРОВАНИЯ
  568. SP_RAMD1        LD A,0X40
  569.                 OUT (C),A
  570.                 LD B,E
  571.                 LD A,IXH                        ;НОМЕР ВЫЧИСЛЕННОЙ СТРАНИЦЫ ОЗУ
  572.                 OUT (C),A                       ;ВКЛЮЧИЛИ ВЫЧИСЛЕННУЮ СТРАНИЦУ
  573.                 LD B,D                          ;СТАРШИЙ БАЙТ АДРЕСА НАЧАЛА ВКЛЮЧЕННОЙ СТРАНИЦЫ
  574.                 POP DE
  575.                 LD A,B
  576.                 ADD A,H
  577.                 LD H,A
  578.                 LD A,IXL
  579.                 AND A
  580.                 JR NZ,IN_ROM1
  581.                 LD A,D
  582.                 INC A
  583.                 JR NZ,IN_ROM1
  584.                 LD A,E
  585.                 AND A
  586.                 JR Z,IN_ROM1
  587. IN_ROM4         NEG
  588.                 LD C,A
  589.                 LD B,0
  590.                 LDIR
  591.                 NEG
  592.                 LD C,A
  593. IN_ROM2         EX DE,HL
  594.                 ADD HL,BC
  595.                 EX DE,HL
  596.                 ADD HL,BC
  597.                 LD A,(PORT_7F)
  598.                 JP SP_RAMD8_
  599.  
  600. IN_ROM1         LD A,D
  601.                 CP HIGH (CPU1)
  602.                 JR NC,IN_ROM3
  603.                 LD A,(PORT_7F)
  604.                 AND A
  605.                 LD BC,0X80
  606.                 JR Z,IN_ROM2
  607.                 LD BC,0X100
  608.                 JR IN_ROM2
  609.  
  610. IN_ROM3         CP HIGH (CPU2)                  ;ПРОВЕРКА ПЕРЕХОДА ГРАНИЦЫ СТРАНИЦ
  611.                 JP NC,SP_RAMD3                  ;ЕСЛИ ВЫШЕ ТО СРАЗУ КОПИРУЕМ
  612.                 CP HIGH (CPU2)-1
  613.                 JP C,SP_RAMD3                   ;ЕСЛИ НИЖЕ ТАК ЖЕ СРАЗУ КОПИРУЕМ
  614.                 LD A,E
  615.                 AND A                           ;ЕСЛИ СЕКТОР ПОЛНОСТЬЮ УКЛАДЫВЕТСЯ ДО ГРАНИЦЫ, ТО СРАЗУ КОПИРУЕМ
  616.                 JR Z,SP_RAMD3                   ;ИНАЧЕ ПРИНУДИТЕЛЬНО КОПИРУЕМ В ДВА ПРИЕМА
  617.                 LD A,IXL                        ;ЧТЕНИЕ ИЛИ ЗАПИСЬ?
  618.                 AND A
  619.                 LD A,E                          ;МЛАДШИЙ БАЙТ АДРЕС В БЛОКЕ
  620.                 JR Z,SP_RAMD4
  621.                 EX DE,HL                        ;ДЛЯ ЗАПИСИ МЕНЯЕМ НАПРАВЛЕНИЕ
  622. SP_RAMD4        NEG
  623.                 LD C,A                          ;КОПИРУЕМ ОСТАТОК ДО КОНЦА БЛОКА
  624.                 LD B,0
  625.                 LDIR
  626.                 NEG
  627.                 PUSH AF                 ;СПРЯТАЛИ СКОЛЬКО ОСТАЛОСЬ КОПИРОВАТЬ ИЗ НАЧАЛА СЛЕДУЮЩЕГО БЛОКА
  628.                 LD BC,(BB_CPU2)
  629.                 LD A,C
  630.                 LD C,LOW (WIN_A0)
  631.                 OUT (C),A
  632.                 LD B,HIGH (WIN_A1)
  633.                 LD A,0X40
  634.                 OUT (C),A
  635.                 LD B,HIGH (WIN_P1)
  636.                 LD A,IXH
  637.                 OUT (C),A                       ;ВЫЧИСЛЕННУЮ СТРАНИЦУ ВКЛЮЧАЕМ В 1 ОКНЕ ПРОЕЦИРОВАНИЯ
  638.                 LD A,IXL                        ;ЧТЕНИЕ ИЛИ ЗАПИСЬ
  639.                 AND A
  640.                 JR Z,SP_RAMD5
  641.                 LD A,D                          ;ДЛЯ ЗАПИСИ
  642.                 SUB 0X40                        ;ИЗМЕНИЛИ АДРЕС КУДА КОПИРОВАТЬ НА ДРУГОЕ ОКНО ПРОЕЦИРОВАНИЯ
  643.                 LD D,A
  644.                 JR SP_RAMD6
  645.  
  646. SP_RAMD5        LD A,H                          ;ДЛЯ ЧТЕНИЯ  
  647.                 SUB 0X40                        ;ИЗМЕНИЛИ АДРЕС КУДА КОПИРОВАТЬ НА ДРУГОЕ ОКНО ПРОЕЦИРОВАНИЯ
  648.                 LD H,A
  649. SP_RAMD6        POP AF
  650.                 LD C,A                          ;СКОЛЬКО ОСТАЛОСЬ СКОПИРОВАТЬ БАЙТ
  651.                 LD B,0
  652.                 LDIR
  653.                 LD A,(PORT_7F)
  654.                 JR SP_RAMD8_
  655.  
  656. SP_RAMD3        LD A,IXL                        ;ЧТЕНИЕ ИЛИ ЗАПИСЬ
  657.                 AND A
  658.                 JR Z,SP_RAMD7
  659.                 EX DE,HL                        ;ДЛЯ ЗАПИСИ МЕНЯЕМ НАПРАВЛЕНИЕ
  660. SP_RAMD7        LD A,(PORT_7F)
  661.                 AND A
  662.                 JR NZ,SP_RAMD8
  663.                 CALL COPYHBLOCK                 ;ДЛЯ СЕКТОРА РАЗМЕРОМ 128 БАЙТ КОПИРУЕМ ПОЛОВИНУ И ВЫХОДИМ
  664. ECOPY_BLOCK     LD A,IXL
  665.                 AND A
  666.                 JR Z,ECOPY_BLOCK1
  667.                 EX DE,HL
  668. ECOPY_BLOCK1    LD (REG_L),DE
  669.                 RET
  670.  
  671. SP_RAMD8        CALL COPY_BLOCK                 ;ДЛЯ СЕКТОРА 256 БАЙТ КОПИРУЕМ ВЕСЬ И ВЫХОДИМ
  672. SP_RAMD8_       DEC A
  673.                 JR Z,ECOPY_BLOCK
  674.                 LD (PORT_7F),A
  675.                 OUT (0X7F),A
  676.                 LD A,IXL
  677.                 AND A
  678.                 JR Z,SP_RAMD0
  679.                 EX DE,HL
  680. SP_RAMD0        LD A,0X3F
  681.                 AND H
  682.                 LD H,A
  683.                 JP SP_RAMD9
  684.  
  685. CP_TYPEDRIVE    PUSH BC
  686.                 PUSH HL
  687.                 LD H,VIRT_REAL_DRIVE
  688.                 CALL READCMOS
  689.                 POP HL
  690.                 AND 3
  691.                 LD B,A
  692.                 LD A,(TRD_5CF6)
  693.                 CP B
  694.                 POP BC
  695.                 RET
  696.  
  697. ;[УСТАНОВКА ПЕРЕМЕННЫХ ТЕКУЩЕГО ПРИВОДА]
  698. SET_DRIVENAME   LD H,VIRT_REAL_DRIVE
  699.                 CALL READCMOS
  700.                 RRCA
  701.                 RRCA
  702.                 AND 3
  703.                 LD (TRD_5D19),A
  704.                 LD (TRD_5CF6),A
  705.                 OR 0X3C
  706.                 LD (TRD_5D16),A
  707.                 RET
  708.  
  709. ;[ФОРМАТИРОВАНИЕ RAM ДИСКА]
  710. FORMAT_RAM      LD A,(TRD_5CF6)
  711.                 LD B,A
  712.                 INC B
  713.                 LD A,%00001000
  714.                 RLCA
  715.                 DJNZ $-1
  716.                 LD B,A
  717. ;               LD A,(COPY_VIRT_BITS)
  718.                 RST8D _MOUNTER,_GET_VIRT_BITS
  719.                 LD (COPY_VIRT_BITS),A
  720.                 AND B
  721.                 JR NZ,FORMAT_RAM3               ;ЕСЛИ БИТ=1 ФОРМАТ ПРИМОНТИРОВАННОГО ОБРАЗА
  722.                 CALL CP_TYPEDRIVE
  723.                 RET NZ                          ;ВЫХОД ДЛЯ ФОРМАТА РЕЛЬНОГО ДИСКА
  724.                 CALL CREATE_TRDTABL             ;ФОРМАТ РАМДИСКА
  725.                 XOR A
  726.                 RET
  727.  
  728. FORMAT_RAM3     LD HL,TRD_5D25
  729.                 LD DE,TRD_5D26
  730.                 LD BC,0XFF
  731.                 LD (HL),B
  732.                 LDIR
  733.                 LD D,B
  734.                 LD E,B
  735.                 LD B,0X10
  736. FORMAT_RAM1     PUSH BC
  737.                 PUSH DE
  738.                 LD B,1
  739.                 LD HL,TRD_5D25
  740.                 CALL COM_06
  741.                 POP DE
  742.                 POP BC
  743.                 INC E
  744.                 DJNZ FORMAT_RAM1
  745.                 XOR A
  746.                 RET
  747.  
  748. ;[ПРОВЕРКА НАЛИЧИЯ МАРКЕРА РАМДИСКА]
  749. CMP_RAM_DISK    CALL READ_WCPU12
  750.                 LD BC,WIN_P1
  751.                 LD A,RAM_RAMDISK
  752.                 OUT (C),A
  753.                 LD HL,CPU1+0X3FFF
  754.                 LD D,(HL)
  755.                 DEC H
  756.                 LD E,(HL)                       ;ВЗЯЛИ БАЙТЫ ДЛЯ ПРОВЕРКИ МАРКЕРА
  757.                 CALL WRITE_WCPU12
  758.                 LD HL,"RD"
  759.                 AND A
  760.                 SBC HL,DE
  761.                 RET Z                           ;ЕСЛИ МАРКЕР НА МЕСТЕ, ТО РАМДИСК НЕ СОЗДАЕМ
  762. ;[СОЗДАНИЕ ЧИСТОГО РАМДИСКА]
  763. CREATE_TRDTABL  LD BC,WIN_P1
  764.                 LD A,RAM_RAMDISK                ;НУЖНА СТРАНИЦА НАЧАЛА РАМДИСКА, ГДЕ БУДЕТ ТАБЛИЦА ОПИСАТЕЛЕЙ
  765.                 OUT (C),A
  766.                 LD HL,CPU1
  767.                 PUSH HL
  768.                 LD DE,CPU1+1
  769.                 LD BC,0X3FFF
  770.                 LD (HL),L
  771.                 LDIR                            ;ОЧИСТИЛИ СТРАНИЦУ
  772.                 POP DE                          ;АДРЕС НАЧАЛА
  773.                 LD HL,0                         ;СМЕЩЕНИЕ В БЛОКАХ И СТРАНИЦАХ
  774.                 LD A,0XA0
  775. ELT2            PUSH AF
  776.                 LD BC,0X1000                    ;СЧЕТЧИК НОМЕРОВ СЕКТОРОВ И ИХ НОМЕРА
  777.                 LD A,L
  778.                 RRCA
  779.                 RRCA
  780.                 LD (DE),A                       ;СМЕЩЕНИЕ В БЛОКАХ ДОРОЖКИ В СТРАНИЦЕ
  781.                 INC D
  782.                 LD A,H
  783.                 LD (DE),A                       ;СМЕЩЕНИЕ В СТРАНИЦАХ ДО ДОРОЖКИ
  784.                 INC D
  785. ELT1            INC C
  786.                 LD A,C
  787.                 LD (DE),A                       ;НОМЕР СЕКТОРА
  788.                 INC D
  789.                 LD A,2
  790.                 LD (DE),A                       ;РАЗМЕР СЕКТОРА
  791.                 INC D
  792.                 DJNZ ELT1                       ;ВНОСИМ В ТАБЛИЦУ ВСЕ НОМЕРА СЕКТОРОВ С РАЗМЕРАМИ
  793.                 LD D,HIGH (CPU1)                ;ВЕРНУЛИ УКАЗАТЕЛЬ В НАЧАЛО
  794.                 INC E                           ;ДЛЯ СЛЕДУЮЩЕЙ ДОРОЖКИ
  795.                 LD BC,0X40
  796.                 ADD HL,BC                       ;ПЕРЕХОД К СЛЕДУЮЩЕЙ ДОРОЖКЕ
  797.                 POP AF
  798.                 DEC A
  799.                 JR NZ,ELT2                      ;ПОВТОРЯЕМ ДЛЯ ВСЕХ ДОРОЖЕК
  800.                 LD HL,CPU1+0X3FFF
  801.                 LD (HL),"R"                     ;ВНОСИМ МАРКЕР РАМДИСКА
  802.                 DEC H
  803.                 LD (HL),"D"
  804.                 LD BC,WIN_P1
  805.                 LD A,RAM_DATARAMD
  806.                 OUT (C),A
  807.                 LD HL,CPU1
  808.                 LD DE,CPU1+1
  809.                 LD BC,0X0FFF
  810.                 LD (HL),L
  811.                 LDIR
  812.                 LD HL,DSKINFO
  813.                 LD DE,CPU1+0X8E1
  814.                 LD BC,DSK_END-DSKINFO
  815.                 LDIR
  816.                 LD BC,WIN_A1
  817.                 LD A,0X7A
  818.                 OUT (C),A
  819.                 RET
  820.  
  821. ;[ВОССТАНОВЛЕНИЕ КОНФИГУРАЦИИ ОКОН ПРОЕЦИРОВАНИЯ 1,2]
  822. WRITE_WCPU12    LD BC,(BB_CPU1)
  823.                 LD A,C
  824.                 LD C,LOW (WIN_A0)
  825.                 OUT (C),A
  826.                 LD BC,(BB_CPU2)
  827.                 LD A,C
  828.                 LD C,LOW (WIN_A0)
  829.                 OUT (C),A
  830.                 RET
  831.  
  832. ;[ЧТЕНИЕ КОНФИГУРАЦИИ ОКОН ПРОЕЦИРОВАНИЯ 1,2]
  833. READ_WCPU12     LD BC,RD_RAMNROM
  834.                 IN L,(C)                        ;БИТЫ RAM & ROM
  835.                 INC B
  836.                 IN H,(C)                        ;БИТЫ DOS & 7FFD
  837.                 ADD HL,HL
  838.                 LD B,HIGH (RD_1WINA1)
  839.                 IN A,(C)
  840.                 CP 0XC0
  841.                 JR NC,RST30_01
  842.                 LD E,A
  843.                 LD D,HIGH (WIN_P1)
  844.                 JR RST30_02
  845.  
  846. RST30_01        RLCA
  847.                 RLCA
  848.                 SLA L
  849.                 RRA
  850.                 SLA H
  851.                 RRA
  852.                 LD E,A
  853.                 LD D,HIGH (WIN_A1)
  854. RST30_02        LD (BB_CPU1),DE
  855.                 INC B
  856.                 IN A,(C)
  857.                 CP 0XC0
  858.                 JR NC,RST30_03
  859.                 LD E,A
  860.                 LD D,HIGH (WIN_P2)
  861.                 JR RST30_04
  862.  
  863. RST30_03        RLCA
  864.                 RLCA
  865.                 SLA L
  866.                 RRA
  867.                 SLA H
  868.                 RRA
  869.                 LD E,A
  870.                 LD D,HIGH (WIN_A2)
  871. RST30_04        LD (BB_CPU2),DE
  872.                 RET
  873.  
  874. DISK_NONE       PUSH HL
  875.                 PUSH BC
  876.                 CALL READ_WCPU12
  877.                 LD BC,WIN_A1
  878.                 LD A,0X40
  879.                 OUT (C),A
  880.                 LD B,HIGH (WIN_P1)
  881.                 LD A,RAM_RAMDISK
  882.                 OUT (C),A
  883.                 LD HL,CPU1+0X3FFF
  884.                 LD A,(HL)
  885.                 DEC H
  886.                 CP "R"
  887.                 SCF
  888.                 JR NZ,DISK_NONE1
  889.                 LD A,(HL)
  890.                 CP "D"
  891.                 SCF
  892.                 JR NZ,DISK_NONE1
  893.                 XOR A
  894. DISK_NONE1      PUSH AF
  895.                 CALL WRITE_WCPU12
  896.                 POP AF
  897.                 POP BC
  898.                 POP HL
  899.                 RET
  900.  
  901. SET_RWPORT0     RST8D _MOUNTER,_MOUNT_RAMDISK
  902.                 RST30 _SET_VIRT_BITS
  903.                 RET
  904.  
  905. SET_VIRT_BITS   LD A,(REG_A)
  906.                 LD (COPY_VIRT_BITS),A
  907.                 LD C,A
  908.                 AND 3
  909.                 LD (VIRT_DRIVE),A
  910.                 LD A,C
  911.                 RRCA
  912.                 RRCA
  913.                 AND 3
  914.                 LD (REAL_DRIVE),A
  915.                 RET
  916.