Subversion Repositories pentevo

Rev

Rev 761 | Rev 831 | Go to most recent revision | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed

  1.  
  2. ;LAST UPDATE: 05.09.2017 savelij
  3.  
  4.                 TITLE "virtual.a80"
  5.  
  6.                 DB 0XFF                         ;DCU
  7.  
  8. ;[КОПИРОВАНИЕ 256 БАЙТ]
  9. COPY_BLOCK      REPT 128                        ;КОПИРОВАНИЕ БЛОКА 256 БАЙТ
  10.                 LDI
  11.                 ENDM
  12. COPYHBLOCK      REPT 126
  13.                 LDI
  14.                 ENDM
  15.                 JR COPY_BLOCK1
  16.                
  17.                 DW 0XFFFF                       ;ДЛЯ ВЕКТОРА ПРЕРЫВАНИЙ IM2 I=9
  18.  
  19. COPY_BLOCK1     LDI
  20.                 LDI
  21.                 RET
  22.  
  23. _OUT_1F         EQU 0
  24. _OUT_3F         EQU 1
  25. _OUT_5F         EQU 2
  26. _OUT_7F         EQU 3
  27. _OUT_FF         EQU 4
  28. _OUTI           EQU 5
  29. _IN_1F          EQU 6
  30. _IN_3F          EQU 7
  31. _IN_5F          EQU 8
  32. _IN_7F          EQU 9
  33. _IN_FF          EQU 0X0A
  34. _INI            EQU 0X0B
  35. _OUT_C_D        EQU 0X0C
  36. _IN_H_C         EQU 0X0D
  37. _WR_RD_SECT     EQU 0X0E
  38. _SET_BYTE_DRIVE EQU 0X0F
  39. _GET_BYTE_DRIVE EQU 0X10
  40. _NEW_BYTE_DRIVE EQU 0X11
  41. _CMP_RAMDISK    EQU 0X12
  42.  
  43. WOUTCA          EQU 0X13
  44. WWRITE_SEC_     EQU 0X14
  45. WREAD_SEC_      EQU 0X15
  46. WINI_RET        EQU 0X16
  47.  
  48. ;[С ВОЗВРАТОМ В МЕСТО ВЫЗОВА]
  49. W_DATA          DW W_OUT1F                      ;00 ЗАПИСЬ ПОРТА 1F
  50.                 DW W_OUT3F                      ;01 ЗАПИСЬ ПОРТА 3F
  51.                 DW W_OUT5F                      ;02 ЗАПИСЬ ПОРТА 5F
  52.                 DW W_OUT7F                      ;03 ЗАПИСЬ ПОРТА 7F
  53.                 DW W_OUTFF                      ;04 ЗАПИСЬ ПОРТА FF
  54.                 DW W_OUTI                       ;05 OUTI
  55.                 DW W_IN1F                       ;06 ЧТЕНИЕ ПОРТА 1F
  56.                 DW W_IN3F                       ;07 ЧТЕНИЕ ПОРТА 3F
  57.                 DW W_IN5F                       ;08 ЧТЕНИЕ ПОРТА 5F
  58.                 DW W_IN7F                       ;09 ЧТЕНИЕ ПОРТА 7F
  59.                 DW W_INFF                       ;0A ЧТЕНИЕ ПОРТА FF
  60.                 DW W_INI                        ;0B INI
  61.                 DW W_OUTCD                      ;0C ЗАПИСЬ РЕГИСТРА 'D' В ПОРТ 'BC'
  62.                 DW W_INHC                       ;0D ЧТЕНИЕ В РЕГИСТР 'H' ИЗ ПОРТА 'BC'
  63.                 DW READ_WRITE_SEC               ;0E ЧТЕНИЕ/ЗАПИСЬ СЕКТОРА
  64.                 DW WR_BYTE_DRIVE                ;0F
  65.                 DW RD_BYTE_DRIVE                ;10
  66.                 DW NEO_BYTE_DRIVE               ;11
  67.                 DW CMP_RAM_DISK                 ;12 ПРОВЕРКА RAM ДИСКА
  68. EW_DATA
  69. ;[БЕЗ ВОЗВРАТА В МЕСТО ВЫЗОВА]
  70.                 DW W_OUTCA                      ;13 ЗАПИСЬ РЕГИСТРА 'A' В ПОРТ 'BC'
  71.                 DW WRITE_SEC_                   ;14 ЗАПИСЬ СЕКТОРА БЕЗ ВОЗВРАТА В АДРЕС ВЫЗОВА
  72.                 DW READ_SEC_                    ;15 ЧТЕНИЕ СЕКТОРА БЕЗ ВОЗВРАТА В АДРЕС ВЫЗОВА
  73.                 DW W_INI                        ;16 INI БЕЗ ВОЗВРАТА В АДРЕС ВЫЗОВА
  74.  
  75. TEXT4VIRTDRV    DB 0X16,ZASTV_Y+2,1
  76. TXT4VIRTDRV     DC "Virtual Drive: "
  77. ETXT4VIRTDRV
  78.  
  79. DOS_NOEMUL      DB ROM_BAS48|0X80               ;СТРАНИЦА DOS С ЭМУЛЯЦИЕЙ ТОЛЬКО ДЛЯ 3D13
  80. DOS_EMUL        DB ROM_ADD_BAS48|0X80           ;СТРАНИЦА DOS С ПОЛНЫМ ПЕРЕХВАТОМ ПОРТОВ
  81.  
  82. NUM_ALT_PAGE    IF EMU3D2F=1
  83.                 DB ROM_ADD_BAS48|0X80
  84.                 ELSE
  85.                 DB ROM_BAS48|0X80
  86.                 ENDIF
  87.  
  88. ;[ОБРАБОТЧИК RST 30]
  89. RST30_WORK      EX (SP),HL
  90.                 PUSH AF
  91.                 PUSH BC
  92.                 LD A,I
  93.                 JP PE,RST30_WORK1
  94.                 LD A,I
  95. RST30_WORK1     DI
  96.                 PUSH AF
  97.                 LD A,(NUM_ALT_PAGE)             ;НОМЕР ТЕКУЩЕЙ СТРАНИЦЫ ПЗУ
  98.                 PUSH AF
  99.                 AND 0X3E                        ;НОМЕР РЕАЛЬНОЙ СТРАНИЦЫ БЕЗ ЗАВИСИМОСТИ
  100.                 LD BC,WIN_A0
  101.                 OUT (C),A
  102.                 LD B,HIGH (WIN_P0)
  103.                 LD A,RAM_EVODOS
  104.                 OUT (C),A
  105.                 IN A,(PEVO_CONF)
  106.                 LD (WR_BF),A
  107.                 OR 1
  108.                 OUT (PEVO_CONF),A
  109.                 POP AF
  110.                 LD (TEK_ROMPAGE),A
  111.                 LD A,(HL)
  112.                 LD (DOS_STEK),SP
  113.                 LD SP,DOS_STEK
  114.                 PUSH HL                         ;ПОЛОЖИЛИ HL=АДРЕС ВОЗВРАТА
  115.                 PUSH DE
  116.                 LD HL,(DOS_STEK)
  117.                 LD DE,REG_IF
  118.                 REPT 8
  119.                 LDI
  120.                 ENDM
  121.                 LD HL,EXIT_RST30
  122.                 PUSH HL                         ;ПОЛОЖИЛИ АДРЕС ЗАВЕРШЕНИЯ
  123.                 LD HL,W_DATA
  124.                 ADD A,A
  125.                 ADD A,L        
  126.                 LD L,A
  127.                 LD A,(HL)
  128.                 INC L
  129.                 LD H,(HL)
  130.                 LD L,A
  131.                 JP (HL)
  132.  
  133. EXIT_RST30      LD HL,REG_IF
  134.                 LD DE,(DOS_STEK)
  135.                 REPT 8
  136.                 LDI
  137.                 ENDM
  138.                 POP DE
  139.                 POP HL
  140.                 LD SP,(DOS_STEK)
  141.                 LD A,(HL)
  142.                 INC HL
  143.                 CP LOW ((EW_DATA-W_DATA)/2)
  144.                 JR C,EXIT_RST302
  145.                 LD HL,FOR_RET                   ;АДРЕС ВЫХОДА БЕЗ ВОЗВРАТА В МЕСТО ВЫЗОВА
  146. EXIT_RST302     PUSH HL
  147.                 LD HL,(COPY_VIRT_BITS)
  148.                 LD A,(MASK_MNT_DRV)
  149.                 AND L
  150. EXIT_RST305     LD HL,(WR_BF)
  151.                 LD BC,WIN_A0
  152.                 LD A,ROM_BAS48|0X80
  153.                 JR Z,EXIT_RST303
  154.                 LD A,ROM_ADD_BAS48|0X80
  155. EXIT_RST303     CALL WR_BYTE_RET
  156.                 LD A,L
  157.                 POP HL
  158.                 OUT (PEVO_CONF),A
  159.                 POP AF
  160.                 JP PO,EXIT_RST304
  161.                 EI
  162. EXIT_RST304     POP BC
  163.                 POP AF
  164.                 EX (SP),HL
  165.                 RET
  166.  
  167. ;[ЗАПИСЬ "A" В ПОРТ 0X1F]
  168. W_OUT1F         LD A,(REG_A)
  169.                 LD (WR_1F),A
  170.                 CP 0X10
  171.                 JR NC,W_OUT1F10
  172. ;00-0F КОМАНДА ВОССТАНОВЛЕНИЯ
  173.                 XOR A
  174.                 LD (PORT_3F),A
  175.                 OUT (0X3F),A
  176.                 JR INFF_BIT6
  177.  
  178. W_OUT1F10       CP 0X20
  179.                 JR NC,W_OUT1F20
  180. ;10-1F КОМАНДА ПОИСКА
  181.                 LD A,(PORT_7F)
  182.                 LD (PORT_3F),A 
  183.                 OUT (0X3F),A
  184.                 CALL DISK_NONE
  185.                 LD A,0X80
  186.                 JR C,INFF_BIT61
  187. INFF_BIT6       XOR A
  188. INFF_BIT61      LD (RD_1F),A
  189.                 LD A,0XBF
  190.                 LD (RD_FF),A
  191.                 RET
  192.  
  193. W_OUT1F20       CP 0X40
  194.                 JR NC,W_OUT1F40
  195. ;20-3F КОМАНДА ШАГ В ПРЕДЫДУЩЕМ НАПРАВЛЕНИИ
  196.                 LD A,(PORT_3F)
  197. NAPRAVL         NOP
  198.                 LD (PORT_3F),A
  199.                 OUT (0X3F),A
  200.                 JR INFF_BIT6
  201.  
  202. W_OUT1F40       CP 0X60
  203.                 JR NC,W_OUT1F60
  204. ;40-5F КОМАНДА ШАГ ВПЕРЕД
  205.                 LD A,(PORT_3F)
  206.                 INC A
  207.                 LD (PORT_3F),A 
  208.                 OUT (0X3F),A
  209.                 LD A,0X3C
  210.                 LD (NAPRAVL),A
  211.                 JR INFF_BIT6
  212.  
  213. W_OUT1F60       CP 0X80
  214.                 JR NC,W_OUT1F80
  215. ;60-7F КОМАНДА ШАГ НАЗАД
  216.                 LD A,(PORT_3F)
  217.                 DEC A
  218.                 LD (PORT_3F),A 
  219.                 OUT (0X3F),A
  220.                 LD A,0X3D
  221.                 LD (NAPRAVL),A
  222.                 JR INFF_BIT6
  223.  
  224. W_OUT1F80       CP 0XA0
  225.                 JR NC,W_OUT1FA0
  226. ;80-9F КОМАНДА ЧТЕНИЕ СЕКТОРА
  227.                 JR INFF_BIT6
  228.  
  229. W_OUT1FA0       CP 0XC0
  230.                 JR NC,W_OUT1FD0
  231. ;A0-BF КОМАНДА ЗАПИСЬ СЕКТОРА
  232.                 JR INFF_BIT6
  233.  
  234. INFF_BIT7       XOR A
  235.                 LD (RD_1F),A
  236.                 LD A,0X7F
  237.                 LD (RD_FF),A
  238.                 RET
  239.  
  240. W_OUT1FD0       CP 0XD0
  241.                 JR NC,W_OUT1FE0
  242. ;C0-CF ЧТЕНИЕ АДРЕСА
  243.                 JR INFF_BIT6
  244.  
  245. W_OUT1FE0       CP 0XE0
  246.                 JR NC,W_OUT1FF0
  247. ;D0-DF ПРИНУДИТЕЛЬНОЕ ПРЕРЫВАНИЕ
  248.                 LD A,0XBF
  249.                 LD (RD_FF),A
  250.                 RET
  251.  
  252. W_OUT1FF0       CP 0XF0
  253.                 JR C,INFF_BIT6
  254. ;E0-EF ЧТЕНИЕ ДОРОЖКИ
  255.                 JR INFF_BIT6
  256.  
  257. ;[ЗАПИСЬ "A" В ПОРТ 0X3F]
  258. W_OUT3F         LD A,(REG_A)
  259.                 LD (PORT_3F),A
  260.                 OUT (0X3F),A
  261.                 RET
  262.  
  263. ;[ЗАПИСЬ "A" В ПОРТ 0X5F]
  264. W_OUT5F         LD A,(REG_A)
  265.                 LD (PORT_5F),A
  266.                 OUT (0X5F),A
  267.                 RET
  268.  
  269. ;[ЗАПИСЬ "A" В ПОРТ 0X7F]
  270. W_OUT7F         LD A,(REG_A)
  271.                 LD (PORT_7F),A
  272.                 OUT (0X7F),A
  273.                 RET
  274.  
  275. ;[ЗАПИСЬ "A" В ПОРТ 0XFF]
  276. W_OUTFF         LD A,(REG_A)
  277.                 LD (WR_FF),A
  278.                 OUT (0XFF),A
  279.                 AND 3
  280.                 LD (MASK_WRK_DRV),A             ;номер дисковода
  281.                 INC A
  282.                 LD B,A
  283.                 LD A,%10001000
  284.                 RLCA
  285.                 DJNZ $-1
  286.                 LD (MASK_MNT_DRV),A             ;маска смонтированного дисковода
  287.                 RET
  288.  
  289. ;[ЗАПИСЬ "A" В ПОРТ (C)]
  290. W_OUTCA         LD A,(REG_A)
  291. W_OUTCA1        LD D,A
  292.                 LD BC,(REG_C)                   ;ЕСЛИ ПОРТ НЕ TR-DOS
  293.                 LD A,C
  294. ;ОПРЕДЕЛЕНИЕ В КАКОЙ ПОРТ ЗАПИСЬ       
  295.                 CP 0X1F
  296.                 JP Z,W_OUT1F
  297.                 CP 0X3F
  298.                 JR Z,W_OUT3F
  299.                 CP 0X5F
  300.                 JR Z,W_OUT5F
  301.                 CP 0X7F
  302.                 JR Z,W_OUT7F
  303.                 CP 0XFF
  304.                 JR Z,W_OUTFF
  305.                 CP LOW (WIN_A0)
  306.                 JR Z,W_OUTCA3
  307. W_OUTCA4        OUT (C),D
  308.                 RET
  309.  
  310. ;[ЗАПИСЬ В ПОРТЫ ATM/PENTEVO]
  311. W_OUTCA3        LD A,B
  312.                 LD HL,BB_CPU1
  313.                 CP HIGH (WIN_A1)
  314.                 JR Z,W_OUTCA2
  315.                 CP HIGH (WIN_P2)
  316.                 JR Z,W_OUTCA2
  317.                 LD HL,BB_CPU2
  318.                 CP HIGH (WIN_A2)
  319.                 JR Z,W_OUTCA2
  320.                 CP HIGH (WIN_P2)
  321.                 JR NZ,W_OUTCA4
  322. W_OUTCA2        LD E,B
  323.                 PUSH DE
  324.                 PUSH HL
  325.                 CALL READ_WCPU12
  326.                 POP HL
  327.                 POP DE
  328.                 LD (HL),D
  329.                 INC HL
  330.                 LD (HL),E
  331.                 JP WRITE_WCPU12
  332.  
  333. ;[ЗАПИСЬ "D" В ПОРТ (C)]
  334. W_OUTCD         LD A,(IREG_D)
  335.                 JR W_OUTCA1
  336.  
  337. ;[ПЕРЕДАЧА БАЙТА, КОМАНДА OUTI]
  338. W_OUTI          LD HL,(BUFF_SECT)
  339.                 EXX
  340.                 LD A,(HL)
  341.                 INC HL
  342.                 EXX
  343.                 LD (HL),A
  344.                 INC HL
  345.                 LD (BUFF_SECT),HL
  346.                 RET
  347.  
  348. ;[ЧТЕНИЕ ПОРТА 0X1F]
  349. W_IN1F          LD A,(WR_1F)
  350.                 AND 0XF0
  351.                 CP 0X10
  352.                 JR C,W_IN1F1
  353.                 CP 0X20
  354.                 JR C,W_IN1F3
  355.                 CP 0XD0
  356.                 JR Z,W_IN1F1
  357.                 XOR A
  358.                 JR W_IN1F2
  359.  
  360. W_IN1F3         LD A,(INDEX)
  361.                 XOR %00000100
  362.                 JR W_IN1F4
  363.  
  364. W_IN1F1         LD A,0X24
  365. INDEX           EQU $-1
  366. W_IN1F4         XOR %00000010
  367.                 LD (INDEX),A
  368. W_IN1F2         LD (RD_1F),A
  369.                 LD (REG_A),A
  370.                 RET
  371.  
  372. ;[ЧТЕНИЕ ПОРТА 0X3F]
  373. W_IN3F          LD A,(PORT_3F)
  374.                 LD (REG_A),A
  375.                 RET
  376.  
  377. ;[ЧТЕНИЕ ПОРТА 0X5F]
  378. W_IN5F          LD A,(PORT_5F)
  379.                 LD (REG_A),A
  380.                 RET
  381.  
  382. ;[ЧТЕНИЕ ПОРТА 0X7F]
  383. W_IN7F          LD A,(PORT_7F)
  384.                 LD (REG_A),A
  385.                 RET
  386.  
  387. ;[ЧТЕНИЕ ПОРТА 0XFF]
  388. W_INFF          LD A,(RD_FF)
  389.                 LD (REG_A),A
  390.                 RET
  391.  
  392. ;[ЧТЕНИЕ В "H" ИЗ (С)]
  393. W_INHC          LD A,(REG_C)
  394. ;[ОПРЕДЕЛЕНИЕ ИЗ КАКОГО ПОРТА ЧТЕНИЕ]
  395. W_INHC1         CP 0X1F
  396.                 JR NZ,W_INHC2
  397.                 LD A,(RD_1F)
  398.                 LD (REG_H),A
  399.                 RET
  400.  
  401. W_INHC2         CP 0X3F
  402.                 JR NZ,W_INHC3
  403.                 LD A,(PORT_3F)
  404.                 LD (REG_H),A
  405.                 RET
  406.        
  407. W_INHC3         CP 0X5F
  408.                 JR NZ,W_INHC4
  409.                 LD A,(PORT_5F)
  410.                 LD (REG_H),A
  411.                 RET
  412.        
  413. W_INHC4         CP 0X7F
  414.                 JR NZ,W_INHC5
  415.                 LD A,(PORT_7F)
  416.                 LD (REG_H),A
  417.                 RET
  418.        
  419. W_INHC5         CP 0XFF
  420.                 JR NZ,W_INHC6
  421.                 LD A,(WR_FF)
  422.                 LD (REG_H),A
  423.                 RET
  424.  
  425. W_INHC6         LD BC,(REG_C)
  426.                 IN A,(C)
  427.                 LD (REG_H),A
  428.                 RET
  429.  
  430. ;[ЧТЕНИЕ INI]
  431. W_INI           LD A,(RD_1F)
  432.                 LD HL,(REG_L)
  433.                 LD (HL),A
  434.                 INC HL
  435.                 DEC B
  436.                 LD (REG_L),HL
  437.                 RET
  438.  
  439. WR_BYTE_DRIVE   LD H,VIRT_REAL_DRIVE
  440.                 CALL READCMOS
  441.                 JR NEOBYTEDRIVE1
  442.  
  443. RD_BYTE_DRIVE   LD A,(BYTE_DRIVE)
  444.                 LD (REG_A),A
  445.                 RET
  446.  
  447. NEO_BYTE_DRIVE  LD A,(REG_A)
  448. NEOBYTEDRIVE1   AND 0X0F
  449.                 LD L,A
  450.                 LD A,(BYTE_DRIVE)
  451.                 AND 0XF0
  452.                 OR L
  453.                 LD (BYTE_DRIVE),A
  454.                 RET
  455.  
  456. ;[ЧТЕНИЕ СЕКТОРА ИЛИ ПОРТОВ]
  457. READ_SEC_       LD A,(WR_1F)
  458.                 AND 0X0F0
  459.                 CP 0X80
  460.                 JP C,INFF_BIT6
  461.                 CP 0XC0
  462.                 JR NZ,READ_SEC_1
  463.                 LD A,(PORT_3F)
  464.                 LD HL,(REG_L)
  465.                 LD (HL),A
  466.                 INC HL
  467.                 DEC B
  468.                 LD A,(PORT_5F)
  469.                 LD (HL),A
  470.                 INC HL
  471.                 DEC B
  472.                 LD (REG_L),HL
  473.                 RET
  474.  
  475. ;[ЧТЕНИЕ/ЗАПИСЬ СЕКТОРА]
  476. ;IXL=0-ЧТЕНИЕ, =FF-ЗАПИСЬ
  477. READ_WRITE_SEC  PUSH IX
  478.                 JR WRITE_SEC_1
  479.  
  480. ;[ЧТЕНИЕ СЕКТОРА]
  481. READ_SEC_1      PUSH IX
  482.                 LD IXL,0
  483.                 JR WRITE_SEC_1
  484.  
  485. ;[ЗАПИСЬ СЕКТОРА]
  486. WRITE_SEC_      PUSH IX
  487.                 LD IXL,0XFF
  488. WRITE_SEC_1     CALL READ_WCPU12
  489.                 CALL W_WR_RD_SECT
  490.                 LD IX,0X8090
  491.                 LD (REG_F),IX                   ;ЭМУЛЯЦИЯ ФЛАГА УСПЕШНОГО ЧТЕНИЯ/ЗАПИСИ СЕКТОРА
  492.                 CALL WRITE_WCPU12
  493.                 POP IX
  494.                 RET
  495.  
  496. ;[ЧТЕНИЕ ИЛИ ЗАПИСЬ СЕКТОРА РАМДИСКА]
  497. W_WR_RD_SECT    LD A,(WR_FF)
  498.                 AND 3
  499.                 INC A
  500.                 LD B,A
  501.                 LD A,(COPY_VIRT_BITS)
  502.                 REPT 5
  503.                 RRCA
  504.                 ENDM
  505.                 DJNZ $-1
  506.                 JP C,WR_RD_SEC_M                ;РАБОТА С ПРИМОНТИРОВАННЫМ ОБРАЗОМ
  507.                 LD BC,WIN_A1
  508.                 LD A,0X40
  509.                 OUT (C),A
  510.                 LD B,HIGH (WIN_P1)
  511.                 LD A,RAM_RAMDISK
  512.                 OUT (C),A                       ;СТРАНИЦА ЗАГОЛОВКОВ РАМДИСКА
  513.                 LD A,(PORT_3F)                  ;ВЗЯЛИ НОМЕР ТРЕКА
  514.                 ADD A,A                         ;СТОРОН 2
  515.                 LD C,A
  516.                 LD A,(WR_FF)
  517.                 AND 0X10                        ;ПРОВЕРКА КАКАЯ СТОРОНА ДИСКА
  518.                 JR NZ,WWRRD1
  519.                 INC C                           ;ДЛЯ СТОРОНЫ 1
  520. WWRRD1          LD B,HIGH (CPU1)+2              ;АДРЕС НАЧАЛА ИНФЫ О СЕКТОРАХ НА ДОРОЖКЕ
  521.                 LD A,(PORT_5F)                  ;ВЗЯЛИ НОМЕР СЕКТОРА
  522.                 LD L,A
  523.                 LD H,0
  524. WWRRD3          LD A,(BC)
  525.                 LD D,A                          ;ВЗЯЛИ НОМЕР СЕКТОРА
  526.                 INC B
  527.                 LD A,(BC)
  528.                 LD E,A                          ;ВЗЯЛИ РАЗМЕР СЕКТОРА
  529.                 INC B
  530. ;               LD A,D
  531. ;               AND A
  532. ;               JR Z,WWRRD_ERR
  533.                 LD A,L
  534.                 CP D
  535.                 JR Z,WWRRD2
  536.                 LD A,E
  537.                 ADD A,H
  538.                 LD H,A
  539.                 JR WWRRD3
  540.  
  541. WWRRD2          LD A,E
  542.                 RRCA
  543.                 LD (PORT_7F),A 
  544.                 OUT (0X7F),A                    ;РАЗМЕР НАЙДЕННОГО СЕКТОРА
  545.                 LD L,0
  546.                 LD E,L
  547.                 SRL H
  548.                 RR L                            ;HL=СМЕЩЕНИЕ В БЛОКАХ ДО НАЙДЕННОГО СЕКТОРА
  549.                 LD B,HIGH (CPU1)
  550.                 LD A,(BC)
  551.                 LD D,A
  552.                 ADD HL,DE                       ;HL=СМЕЩЕНИЕ ОТ НАЧАЛА СТРАНИЦЫ В БЛОКАХ
  553.                 INC B
  554.                 LD A,(BC)
  555.                 LD C,A                          ;СМЕЩЕНИЕ В СТРАНИЦАХ ОТ НАЧАЛА РАМДИСКА
  556.                 LD A,H
  557.                 CP HIGH (CPU1)
  558.                 JR C,WWRRD5
  559.                 SUB 0X40
  560.                 LD H,A
  561.                 INC C
  562. ;HL=СМЕЩЕНИЕ В СТРАНИЦЕ ДО НАЧАЛА СЕКТОРА
  563. WWRRD5          LD A,C                          ;СМЕЩЕНИЕ ДО НОМЕРА СТРАНИЦЫ, ГДЕ УКАЗАННЫЙ СЕКТОР НАЧИНАЕТСЯ
  564.                 ADD A,RAM_DATARAMD              ;ПРИБАВИЛИ НОМЕР НАЧАЛА РАМДИСК И +1. В 0 СТРАНИЦЕ РАМДИСКА ОПИСАТЕЛИ СЕКТОРОВ
  565.                 LD IXH,A                        ;СОХРАНИЛИ НОМЕР ВЫЧИСЛЕННОЙ СТРАНИЦЫ
  566.                 LD DE,(REG_L)
  567.                 LD BC,(BB_CPU1)
  568.                 LD A,C
  569.                 LD C,LOW (WIN_A0)
  570.                 OUT (C),A                       ;ВЕРНУЛИ СТАНДАРТНУЮ 5 СТРАНИЦУ
  571. SP_RAMD9        LD A,D                          ;ПРОВЕРКА ГРАНИЦЫ ОТКУДА/КУДА КОПИРОВАТЬ
  572.                 CP HIGH (CPU2)
  573.                 PUSH DE
  574.                 LD DE,CPU1+HIGH (WIN_P1)
  575.                 LD BC,WIN_A1                    ;ЕСЛИ ВЕРХНИЕ 32КБ ОЗУ, ТО НУЖНО ВКЛЮЧИТЬ В 1 ОКНЕ ПРОЕЦИРОВАНИЯ
  576.                 JR NC,SP_RAMD1
  577.                 LD DE,CPU2+HIGH (WIN_P2)
  578.                 LD B,HIGH (WIN_A2)              ;ЕСЛИ НИЖНИЕ 32КБ ОЗУ, ТО НУЖНО ВКЛЮЧИТЬ ВО 2 ОКНЕ ПРОЕЦИРОВАНИЯ
  579. SP_RAMD1        LD A,0X40
  580.                 OUT (C),A
  581.                 LD B,E
  582.                 LD A,IXH                        ;НОМЕР ВЫЧИСЛЕННОЙ СТРАНИЦЫ ОЗУ
  583.                 OUT (C),A                       ;ВКЛЮЧИЛИ ВЫЧИСЛЕННУЮ СТРАНИЦУ
  584.                 LD B,D                          ;СТАРШИЙ БАЙТ АДРЕСА НАЧАЛА ВКЛЮЧЕННОЙ СТРАНИЦЫ
  585.                 POP DE
  586.                 LD A,B
  587.                 ADD A,H
  588.                 LD H,A
  589.                 LD A,IXL
  590.                 AND A
  591.                 JR NZ,IN_ROM1
  592.                 LD A,D
  593.                 INC A
  594.                 JR NZ,IN_ROM1
  595.                 LD A,E
  596.                 AND A
  597.                 JR Z,IN_ROM1
  598. IN_ROM4         NEG
  599.                 LD C,A
  600.                 LD B,0
  601.                 LDIR
  602.                 NEG
  603.                 LD C,A
  604. IN_ROM2         EX DE,HL
  605.                 ADD HL,BC
  606.                 EX DE,HL
  607.                 ADD HL,BC
  608.                 LD A,(PORT_7F)
  609.                 JP SP_RAMD8_
  610.  
  611. IN_ROM1         LD A,D
  612.                 CP HIGH (CPU1)
  613.                 JR NC,IN_ROM3
  614.                 LD A,(PORT_7F)
  615.                 AND A
  616.                 LD BC,0X80
  617.                 JR Z,IN_ROM2
  618.                 LD BC,0X100
  619.                 JR IN_ROM2
  620.  
  621. IN_ROM3         CP HIGH (CPU2)                  ;ПРОВЕРКА ПЕРЕХОДА ГРАНИЦЫ СТРАНИЦ
  622.                 JP NC,SP_RAMD3                  ;ЕСЛИ ВЫШЕ ТО СРАЗУ КОПИРУЕМ
  623.                 CP HIGH (CPU2)-1
  624.                 JP C,SP_RAMD3                   ;ЕСЛИ НИЖЕ ТАК ЖЕ СРАЗУ КОПИРУЕМ
  625.                 LD A,E
  626.                 AND A                           ;ЕСЛИ СЕКТОР ПОЛНОСТЬЮ УКЛАДЫВЕТСЯ ДО ГРАНИЦЫ, ТО СРАЗУ КОПИРУЕМ
  627.                 JR Z,SP_RAMD3                   ;ИНАЧЕ ПРИНУДИТЕЛЬНО КОПИРУЕМ В ДВА ПРИЕМА
  628.                 LD A,IXL                        ;ЧТЕНИЕ ИЛИ ЗАПИСЬ?
  629.                 AND A
  630.                 LD A,E                          ;МЛАДШИЙ БАЙТ АДРЕС В БЛОКЕ
  631.                 JR Z,SP_RAMD4
  632.                 EX DE,HL                        ;ДЛЯ ЗАПИСИ МЕНЯЕМ НАПРАВЛЕНИЕ
  633. SP_RAMD4        NEG
  634.                 LD C,A                          ;КОПИРУЕМ ОСТАТОК ДО КОНЦА БЛОКА
  635.                 LD B,0
  636.                 LDIR
  637.                 NEG
  638.                 PUSH AF                 ;СПРЯТАЛИ СКОЛЬКО ОСТАЛОСЬ КОПИРОВАТЬ ИЗ НАЧАЛА СЛЕДУЮЩЕГО БЛОКА
  639.                 LD BC,(BB_CPU2)
  640.                 LD A,C
  641.                 LD C,LOW (WIN_A0)
  642.                 OUT (C),A
  643.                 LD B,HIGH (WIN_A1)
  644.                 LD A,0X40
  645.                 OUT (C),A
  646.                 LD B,HIGH (WIN_P1)
  647.                 LD A,IXH
  648.                 OUT (C),A                       ;ВЫЧИСЛЕННУЮ СТРАНИЦУ ВКЛЮЧАЕМ В 1 ОКНЕ ПРОЕЦИРОВАНИЯ
  649.                 LD A,IXL                        ;ЧТЕНИЕ ИЛИ ЗАПИСЬ
  650.                 AND A
  651.                 JR Z,SP_RAMD5
  652.                 LD A,D                          ;ДЛЯ ЗАПИСИ
  653.                 SUB 0X40                        ;ИЗМЕНИЛИ АДРЕС КУДА КОПИРОВАТЬ НА ДРУГОЕ ОКНО ПРОЕЦИРОВАНИЯ
  654.                 LD D,A
  655.                 JR SP_RAMD6
  656.  
  657. SP_RAMD5        LD A,H                          ;ДЛЯ ЧТЕНИЯ  
  658.                 SUB 0X40                        ;ИЗМЕНИЛИ АДРЕС КУДА КОПИРОВАТЬ НА ДРУГОЕ ОКНО ПРОЕЦИРОВАНИЯ
  659.                 LD H,A
  660. SP_RAMD6        POP AF
  661.                 LD C,A                          ;СКОЛЬКО ОСТАЛОСЬ СКОПИРОВАТЬ БАЙТ
  662.                 LD B,0
  663.                 LDIR
  664.                 LD A,(PORT_7F)
  665.                 JR SP_RAMD8_
  666.  
  667. SP_RAMD3        LD A,IXL                        ;ЧТЕНИЕ ИЛИ ЗАПИСЬ
  668.                 AND A
  669.                 JR Z,SP_RAMD7
  670.                 EX DE,HL                        ;ДЛЯ ЗАПИСИ МЕНЯЕМ НАПРАВЛЕНИЕ
  671. SP_RAMD7        LD A,(PORT_7F)
  672.                 AND A
  673.                 JR NZ,SP_RAMD8
  674.                 CALL COPYHBLOCK                 ;ДЛЯ СЕКТОРА РАЗМЕРОМ 128 БАЙТ КОПИРУЕМ ПОЛОВИНУ И ВЫХОДИМ
  675. ECOPY_BLOCK     LD A,IXL
  676.                 AND A
  677.                 JR Z,ECOPY_BLOCK1
  678.                 EX DE,HL
  679. ECOPY_BLOCK1    LD (REG_L),DE
  680.                 RET
  681.  
  682. SP_RAMD8        CALL COPY_BLOCK                 ;ДЛЯ СЕКТОРА 256 БАЙТ КОПИРУЕМ ВЕСЬ И ВЫХОДИМ
  683. SP_RAMD8_       DEC A
  684.                 JR Z,ECOPY_BLOCK
  685.                 LD (PORT_7F),A
  686.                 OUT (0X7F),A
  687.                 LD A,IXL
  688.                 AND A
  689.                 JR Z,SP_RAMD0
  690.                 EX DE,HL
  691. SP_RAMD0        LD A,0X3F
  692.                 AND H
  693.                 LD H,A
  694.                 JP SP_RAMD9
  695.  
  696. CP_TYPEDRIVE    PUSH BC
  697.                 PUSH HL
  698.                 LD H,VIRT_REAL_DRIVE
  699.                 CALL READCMOS
  700.                 POP HL
  701.                 AND 3
  702.                 LD B,A
  703.                 LD A,(TRD_5CF6)
  704.                 CP B
  705.                 POP BC
  706.                 RET
  707.  
  708. ;[УСТАНОВКА ПЕРЕМЕННЫХ ТЕКУЩЕГО ПРИВОДА]
  709. SET_DRIVENAME   LD H,VIRT_REAL_DRIVE
  710.                 CALL READCMOS
  711.                 RRCA
  712.                 RRCA
  713.                 AND 3
  714.                 LD (TRD_5D19),A
  715.                 LD (TRD_5CF6),A
  716.                 OR 0X3C
  717.                 LD (TRD_5D16),A
  718.                 RET
  719.  
  720. ;[ФОРМАТИРОВАНИЕ RAM ДИСКА]
  721. FORMAT_RAM      LD A,(TRD_5CF6)
  722.                 LD B,A
  723.                 INC B
  724.                 LD A,8
  725.                 RLCA
  726.                 DJNZ $-1
  727.                 LD B,A
  728.                 LD A,(COPY_VIRT_BITS)
  729.                 AND B
  730.                 JR NZ,FORMAT_RAM3               ;ЕСЛИ БИТ=1 ФОРМАТ ПРИМОНТИРОВАННОГО ОБРАЗА
  731.                 CALL CP_TYPEDRIVE
  732.                 RET NZ                          ;ВЫХОД ДЛЯ ФОРМАТА РЕЛЬНОГО ДИСКА
  733.                 CALL CREATE_TRDTABL             ;ФОРМАТ РАМДИСКА
  734.                 XOR A
  735.                 RET
  736.  
  737. FORMAT_RAM3     LD HL,TRD_5D25
  738.                 LD DE,TRD_5D26
  739.                 LD BC,0XFF
  740.                 LD (HL),B
  741.                 LDIR
  742.                 LD D,B
  743.                 LD E,B
  744.                 LD B,0X10
  745. FORMAT_RAM1     PUSH BC
  746.                 PUSH DE
  747.                 LD B,1
  748.                 LD HL,TRD_5D25
  749.                 CALL COM_06
  750.                 POP DE
  751.                 POP BC
  752.                 INC E
  753.                 DJNZ FORMAT_RAM1
  754.                 XOR A
  755.                 RET
  756.  
  757. ;[ПРОВЕРКА НАЛИЧИЯ МАРКЕРА РАМДИСКА]
  758. CMP_RAM_DISK    CALL READ_WCPU12
  759.                 LD BC,WIN_P1
  760.                 LD A,RAM_RAMDISK
  761.                 OUT (C),A
  762.                 LD HL,CPU1+0X3FFF
  763.                 LD D,(HL)
  764.                 DEC H
  765.                 LD E,(HL)                       ;ВЗЯЛИ БАЙТЫ ДЛЯ ПРОВЕРКИ МАРКЕРА
  766.                 CALL WRITE_WCPU12
  767.                 LD HL,"RD"
  768.                 AND A
  769.                 SBC HL,DE
  770.                 RET Z                           ;ЕСЛИ МАРКЕР НА МЕСТЕ, ТО РАМДИСК НЕ СОЗДАЕМ
  771. ;[СОЗДАНИЕ ЧИСТОГО РАМДИСКА]
  772. CREATE_TRDTABL  LD BC,WIN_P1
  773.                 LD A,RAM_RAMDISK                ;НУЖНА СТРАНИЦА НАЧАЛА РАМДИСКА, ГДЕ БУДЕТ ТАБЛИЦА ОПИСАТЕЛЕЙ
  774.                 OUT (C),A
  775.                 LD HL,CPU1
  776.                 PUSH HL
  777.                 LD DE,CPU1+1
  778.                 LD BC,0X3FFF
  779.                 LD (HL),L
  780.                 LDIR                            ;ОЧИСТИЛИ СТРАНИЦУ
  781.                 POP DE                          ;АДРЕС НАЧАЛА
  782.                 LD HL,0                         ;СМЕЩЕНИЕ В БЛОКАХ И СТРАНИЦАХ
  783.                 LD A,0XA0
  784. ELT2            PUSH AF
  785.                 LD BC,0X1000                    ;СЧЕТЧИК НОМЕРОВ СЕКТОРОВ И ИХ НОМЕРА
  786.                 LD A,L
  787.                 RRCA
  788.                 RRCA
  789.                 LD (DE),A                       ;СМЕЩЕНИЕ В БЛОКАХ ДОРОЖКИ В СТРАНИЦЕ
  790.                 INC D
  791.                 LD A,H
  792.                 LD (DE),A                       ;СМЕЩЕНИЕ В СТРАНИЦАХ ДО ДОРОЖКИ
  793.                 INC D
  794. ELT1            INC C
  795.                 LD A,C
  796.                 LD (DE),A                       ;НОМЕР СЕКТОРА
  797.                 INC D
  798.                 LD A,2
  799.                 LD (DE),A                       ;РАЗМЕР СЕКТОРА
  800.                 INC D
  801.                 DJNZ ELT1                       ;ВНОСИМ В ТАБЛИЦУ ВСЕ НОМЕРА СЕКТОРОВ С РАЗМЕРАМИ
  802.                 LD D,HIGH (CPU1)                ;ВЕРНУЛИ УКАЗАТЕЛЬ В НАЧАЛО
  803.                 INC E                           ;ДЛЯ СЛЕДУЮЩЕЙ ДОРОЖКИ
  804.                 LD BC,0X40
  805.                 ADD HL,BC                       ;ПЕРЕХОД К СЛЕДУЮЩЕЙ ДОРОЖКЕ
  806.                 POP AF
  807.                 DEC A
  808.                 JR NZ,ELT2                      ;ПОВТОРЯЕМ ДЛЯ ВСЕХ ДОРОЖЕК
  809.                 LD HL,CPU1+0X3FFF
  810.                 LD (HL),"R"                     ;ВНОСИМ МАРКЕР РАМДИСКА
  811.                 DEC H
  812.                 LD (HL),"D"
  813.                 LD BC,WIN_P1
  814.                 LD A,RAM_DATARAMD
  815.                 OUT (C),A
  816.                 LD HL,CPU1
  817.                 LD DE,CPU1+1
  818.                 LD BC,0X0FFF
  819.                 LD (HL),L
  820.                 LDIR
  821.                 LD HL,DSKINFO
  822.                 LD DE,CPU1+0X8E1
  823.                 LD BC,DSK_END-DSKINFO
  824.                 LDIR
  825. ;[ВОССТАНОВЛЕНИЕ КОНФИГУРАЦИИ ОКОН ПРОЕЦИРОВАНИЯ 1,2]
  826. WRITE_WCPU12    LD BC,(BB_CPU1)
  827.                 LD A,C
  828.                 LD C,LOW (WIN_A0)
  829.                 OUT (C),A
  830.                 LD BC,(BB_CPU2)
  831.                 LD A,C
  832.                 LD C,LOW (WIN_A0)
  833.                 OUT (C),A
  834.                 RET
  835.  
  836. ;[ЧТЕНИЕ КОНФИГУРАЦИИ ОКОН ПРОЕЦИРОВАНИЯ 1,2]
  837. READ_WCPU12     LD BC,RD_RAMNROM
  838.                 IN L,(C)                        ;БИТЫ RAM & ROM
  839.                 INC B
  840.                 IN H,(C)                        ;БИТЫ DOS & 7FFD
  841.                 ADD HL,HL
  842.                 LD B,HIGH (RD_1WINA1)
  843.                 IN A,(C)
  844.                 CP 0XC0
  845.                 JR NC,RST30_01
  846.                 LD E,A
  847.                 LD D,HIGH (WIN_P1)
  848.                 JR RST30_02
  849.  
  850. RST30_01        RLCA
  851.                 RLCA
  852.                 SLA L
  853.                 RRA
  854.                 SLA H
  855.                 RRA
  856.                 LD E,A
  857.                 LD D,HIGH (WIN_A1)
  858. RST30_02        LD (BB_CPU1),DE
  859.                 INC B
  860.                 IN A,(C)
  861.                 CP 0XC0
  862.                 JR NC,RST30_03
  863.                 LD E,A
  864.                 LD D,HIGH (WIN_P2)
  865.                 JR RST30_04
  866.  
  867. RST30_03        RLCA
  868.                 RLCA
  869.                 SLA L
  870.                 RRA
  871.                 SLA H
  872.                 RRA
  873.                 LD E,A
  874.                 LD D,HIGH (WIN_A2)
  875. RST30_04        LD (BB_CPU2),DE
  876.                 RET
  877.  
  878. DISK_NONE       PUSH HL
  879.                 PUSH BC
  880.                 CALL READ_WCPU12
  881.                 LD BC,WIN_A1
  882.                 LD A,0X40
  883.                 OUT (C),A
  884.                 LD B,HIGH (WIN_P1)
  885.                 LD A,RAM_RAMDISK
  886.                 OUT (C),A
  887.                 LD HL,CPU1+0X3FFF
  888.                 LD A,(HL)
  889.                 DEC H
  890.                 CP "R"
  891.                 SCF
  892.                 JR NZ,DISK_NONE1
  893.                 LD A,(HL)
  894.                 CP "D"
  895.                 SCF
  896.                 JR NZ,DISK_NONE1
  897.                 XOR A
  898. DISK_NONE1      PUSH AF
  899.                 CALL WRITE_WCPU12
  900.                 POP AF
  901.                 POP BC
  902.                 POP HL
  903.                 RET
  904.  
  905. SET_RWPORT0     RST8D _MOUNTER,_MOUNT_RAMDISK
  906.                 RET
  907.