Subversion Repositories pentevo

Rev

Rev 702 | Rev 764 | Go to most recent revision | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed | ?url?

  1.  
  2. ;LAST UPDATE: 31.12.2016 savelij
  3.  
  4.                 DB 0XFF                         ;DCU
  5.  
  6. ;[КОПИРОВАНИЕ 256 БАЙТ]
  7. COPY_BLOCK      REPT 128                        ;КОПИРОВАНИЕ БЛОКА 256 БАЙТ
  8.                 LDI
  9.                 ENDM
  10. COPYHBLOCK      REPT 126
  11.                 LDI
  12.                 ENDM
  13.                 JR COPY_BLOCK1
  14.                
  15.                 DW 0XFFFF                       ;ДЛЯ ВЕКТОРА ПРЕРЫВАНИЙ IM2 I=9
  16.  
  17. COPY_BLOCK1     LDI
  18.                 LDI
  19.                 RET
  20.  
  21. _OUT_1F         EQU 0
  22. _OUT_3F         EQU 1
  23. _OUT_5F         EQU 2
  24. _OUT_7F         EQU 3
  25. _OUT_FF         EQU 4
  26. _OUTI           EQU 5
  27. _IN_1F          EQU 6
  28. _IN_3F          EQU 7
  29. _IN_5F          EQU 8
  30. _IN_7F          EQU 9
  31. _IN_FF          EQU 0X0A
  32. _INI            EQU 0X0B
  33. _OUT_C_D        EQU 0X0C
  34. _IN_H_C         EQU 0X0D
  35. _WR_RD_SECT     EQU 0X0E
  36. _SET_BYTE_DRIVE EQU 0X0F
  37. _GET_BYTE_DRIVE EQU 0X10
  38. _NEW_BYTE_DRIVE EQU 0X11
  39. _CMP_RAMDISK    EQU 0X12
  40.  
  41. WOUTCA          EQU 0X13
  42. WWRITE_SEC_     EQU 0X14
  43. WREAD_SEC_      EQU 0X15
  44. WINI_RET        EQU 0X16
  45.  
  46. ;[С ВОЗВРАТОМ В МЕСТО ВЫЗОВА]
  47. W_DATA          DW W_OUT1F                      ;00 ЗАПИСЬ ПОРТА 1F
  48.                 DW W_OUT3F                      ;01 ЗАПИСЬ ПОРТА 3F
  49.                 DW W_OUT5F                      ;02 ЗАПИСЬ ПОРТА 5F
  50.                 DW W_OUT7F                      ;03 ЗАПИСЬ ПОРТА 7F
  51.                 DW W_OUTFF                      ;04 ЗАПИСЬ ПОРТА FF
  52.                 DW W_OUTI                       ;05 OUTI
  53.                 DW W_IN1F                       ;06 ЧТЕНИЕ ПОРТА 1F
  54.                 DW W_IN3F                       ;07 ЧТЕНИЕ ПОРТА 3F
  55.                 DW W_IN5F                       ;08 ЧТЕНИЕ ПОРТА 5F
  56.                 DW W_IN7F                       ;09 ЧТЕНИЕ ПОРТА 7F
  57.                 DW W_INFF                       ;0A ЧТЕНИЕ ПОРТА FF
  58.                 DW W_INI                        ;0B INI
  59.                 DW W_OUTCD                      ;0C ЗАПИСЬ РЕГИСТРА 'D' В ПОРТ 'BC'
  60.                 DW W_INHC                       ;0D ЧТЕНИЕ В РЕГИСТР 'H' ИЗ ПОРТА 'BC'
  61.                 DW READ_WRITE_SEC               ;0E ЧТЕНИЕ/ЗАПИСЬ СЕКТОРА
  62.                 DW WR_BYTE_DRIVE                ;0F
  63.                 DW RD_BYTE_DRIVE                ;10
  64.                 DW NEO_BYTE_DRIVE               ;11
  65.                 DW CMP_RAM_DISK                 ;12 ПРОВЕРКА RAM ДИСКА
  66. EW_DATA
  67. ;[БЕЗ ВОЗВРАТА В МЕСТО ВЫЗОВА]
  68.                 DW W_OUTCA                      ;13 ЗАПИСЬ РЕГИСТРА 'A' В ПОРТ 'BC'
  69.                 DW WRITE_SEC_                   ;14 ЗАПИСЬ СЕКТОРА БЕЗ ВОЗВРАТА В АДРЕС ВЫЗОВА
  70.                 DW READ_SEC_                    ;15 ЧТЕНИЕ СЕКТОРА БЕЗ ВОЗВРАТА В АДРЕС ВЫЗОВА
  71.                 DW W_INI                        ;16 INI БЕЗ ВОЗВРАТА В АДРЕС ВЫЗОВА
  72.  
  73. TEXT4VIRTDRV    DB 0X16,ZASTV_Y+2,1
  74. TXT4VIRTDRV     DC "Virtual Drive: "
  75. ETXT4VIRTDRV
  76.  
  77. DOS_NOEMUL      DB ROM_BAS48|0X80               ;СТРАНИЦА DOS С ЭМУЛЯЦИЕЙ ТОЛЬКО ДЛЯ 3D13
  78. DOS_EMUL        DB ROM_ADD_BAS48|0X80           ;СТРАНИЦА DOS С ПОЛНЫМ ПЕРЕХВАТОМ ПОРТОВ
  79.  
  80. NUM_ALT_PAGE    IF EMU3D2F=1
  81.                 DB ROM_ADD_BAS48|0X80
  82.                 ELSE
  83.                 DB ROM_BAS48|0X80
  84.                 ENDIF
  85.  
  86. ;[ОБРАБОТЧИК RST 30]
  87. RST30_WORK      EX (SP),HL
  88.                 PUSH AF
  89.                 PUSH BC
  90.                 LD A,I
  91.                 JP PE,RST30_WORK1
  92.                 LD A,I
  93. RST30_WORK1     DI
  94.                 PUSH AF
  95.                 LD A,(NUM_ALT_PAGE)             ;НОМЕР ТЕКУЩЕЙ СТРАНИЦЫ ПЗУ
  96.                 PUSH AF
  97.                 AND 0X3E                        ;НОМЕР РЕАЛЬНОЙ СТРАНИЦЫ БЕЗ ЗАВИСИМОСТИ
  98.                 LD BC,WIN_A0
  99.                 OUT (C),A
  100.                 LD B,HIGH (WIN_P0)
  101.                 LD A,ROM_DOS
  102.                 OUT (C),A
  103.                 IN A,(PEVO_CONF)
  104.                 LD (WR_BF),A
  105.                 OR 1
  106.                 OUT (PEVO_CONF),A
  107.                 POP AF
  108.                 LD (TEK_ROMPAGE),A
  109.                 LD A,(HL)
  110.                 LD (DOS_STEK),SP
  111.                 LD SP,DOS_STEK
  112.                 PUSH HL                         ;ПОЛОЖИЛИ HL=АДРЕС ВОЗВРАТА
  113.                 PUSH DE
  114.                 LD HL,(DOS_STEK)
  115.                 LD DE,REG_IF
  116.                 REPT 8
  117.                 LDI
  118.                 ENDM
  119.                 LD HL,EXIT_RST30
  120.                 PUSH HL                         ;ПОЛОЖИЛИ АДРЕС ЗАВЕРШЕНИЯ
  121.                 LD HL,W_DATA
  122.                 ADD A,A
  123.                 ADD A,L        
  124.                 LD L,A
  125.                 LD A,(HL)
  126.                 INC L
  127.                 LD H,(HL)
  128.                 LD L,A
  129.                 JP (HL)
  130.  
  131. EXIT_RST30      LD HL,REG_IF
  132.                 LD DE,(DOS_STEK)
  133.                 REPT 8
  134.                 LDI
  135.                 ENDM
  136.                 POP DE
  137.                 POP HL
  138.                 LD SP,(DOS_STEK)
  139.                 LD A,(HL)
  140.                 INC HL
  141.                 CP LOW ((EW_DATA-W_DATA)/2)
  142.                 JR C,EXIT_RST302
  143.                 LD HL,FOR_RET                   ;АДРЕС ВЫХОДА БЕЗ ВОЗВРАТА В МЕСТО ВЫЗОВА
  144. EXIT_RST302     PUSH HL
  145.                 LD HL,(MASK_MNT_DRV)            ;H=MASK_WRK_DRV, L=MASK_MNT_DRV
  146.                 IN A,(RW_PORT0)
  147.                 LD B,A
  148.                 AND L
  149.                 CP L
  150.                 JR Z,EXIT_RST305                ;ЕСЛИ СОВПАЛО С ПРИМОНТИРОВАННЫМ
  151. ;ПРОВЕРКА ДЛЯ РАМДИСКА
  152.                 LD A,B
  153.                 AND 3
  154.                 CP H
  155. EXIT_RST305     LD HL,(WR_BF)
  156.                 LD BC,WIN_A0
  157.                 LD A,ROM_BAS48|0X80
  158.                 JR NZ,EXIT_RST303
  159.                 LD A,ROM_ADD_BAS48|0X80
  160. EXIT_RST303     CALL WR_BYTE_RET
  161.                 LD A,L
  162.                 POP HL
  163.                 OUT (PEVO_CONF),A
  164.                 POP AF
  165.                 JP PO,EXIT_RST304
  166.                 EI
  167. EXIT_RST304     POP BC
  168.                 POP AF
  169.                 EX (SP),HL
  170.                 RET
  171.  
  172. ;[ЗАПИСЬ "A" В ПОРТ 0X1F]
  173. W_OUT1F         LD A,(REG_A)
  174.                 LD (WR_1F),A
  175.                 CP 0X10
  176.                 JR NC,W_OUT1F10
  177. ;00-0F КОМАНДА ВОССТАНОВЛЕНИЯ
  178.                 XOR A
  179.                 LD (PORT_3F),A
  180.                 OUT (0X3F),A
  181.                 JR INFF_BIT6
  182.  
  183. W_OUT1F10       CP 0X20
  184.                 JR NC,W_OUT1F20
  185. ;10-1F КОМАНДА ПОИСКА
  186.                 LD A,(PORT_7F)
  187.                 LD (PORT_3F),A 
  188.                 OUT (0X3F),A
  189.                 CALL DISK_NONE
  190.                 LD A,0X80
  191.                 JR C,INFF_BIT61
  192. INFF_BIT6       XOR A
  193. INFF_BIT61      LD (RD_1F),A
  194.                 LD A,0XBF
  195.                 LD (RD_FF),A
  196.                 RET
  197.  
  198. W_OUT1F20       CP 0X40
  199.                 JR NC,W_OUT1F40
  200. ;20-3F КОМАНДА ШАГ В ПРЕДЫДУЩЕМ НАПРАВЛЕНИИ
  201.                 LD A,(PORT_3F)
  202. NAPRAVL         NOP
  203.                 LD (PORT_3F),A
  204.                 OUT (0X3F),A
  205.                 JR INFF_BIT6
  206.  
  207. W_OUT1F40       CP 0X60
  208.                 JR NC,W_OUT1F60
  209. ;40-5F КОМАНДА ШАГ ВПЕРЕД
  210.                 LD A,(PORT_3F)
  211.                 INC A
  212.                 LD (PORT_3F),A 
  213.                 OUT (0X3F),A
  214.                 LD A,0X3C
  215.                 LD (NAPRAVL),A
  216.                 JR INFF_BIT6
  217.  
  218. W_OUT1F60       CP 0X80
  219.                 JR NC,W_OUT1F80
  220. ;60-7F КОМАНДА ШАГ НАЗАД
  221.                 LD A,(PORT_3F)
  222.                 DEC A
  223.                 LD (PORT_3F),A 
  224.                 OUT (0X3F),A
  225.                 LD A,0X3D
  226.                 LD (NAPRAVL),A
  227.                 JR INFF_BIT6
  228.  
  229. W_OUT1F80       CP 0XA0
  230.                 JR NC,W_OUT1FA0
  231. ;80-9F КОМАНДА ЧТЕНИЕ СЕКТОРА
  232.                 JR INFF_BIT6
  233.  
  234. W_OUT1FA0       CP 0XC0
  235.                 JR NC,W_OUT1FD0
  236. ;A0-BF КОМАНДА ЗАПИСЬ СЕКТОРА
  237.                 JR INFF_BIT6
  238.  
  239. INFF_BIT7       XOR A
  240.                 LD (RD_1F),A
  241.                 LD A,0X7F
  242.                 LD (RD_FF),A
  243.                 RET
  244.  
  245. W_OUT1FD0       CP 0XD0
  246.                 JR NC,W_OUT1FE0
  247. ;C0-CF ЧТЕНИЕ АДРЕСА
  248.                 JR INFF_BIT6
  249.  
  250. W_OUT1FE0       CP 0XE0
  251.                 JR NC,W_OUT1FF0
  252. ;D0-DF ПРИНУДИТЕЛЬНОЕ ПРЕРЫВАНИЕ
  253.                 LD A,0XBF
  254.                 LD (RD_FF),A
  255.                 RET
  256.  
  257. W_OUT1FF0       CP 0XF0
  258.                 JR C,INFF_BIT6
  259. ;E0-EF ЧТЕНИЕ ДОРОЖКИ
  260.                 JR INFF_BIT6
  261.  
  262. ;[ЗАПИСЬ "A" В ПОРТ 0X3F]
  263. W_OUT3F         LD A,(REG_A)
  264.                 LD (PORT_3F),A
  265.                 OUT (0X3F),A
  266.                 RET
  267.  
  268. ;[ЗАПИСЬ "A" В ПОРТ 0X5F]
  269. W_OUT5F         LD A,(REG_A)
  270.                 LD (PORT_5F),A
  271.                 OUT (0X5F),A
  272.                 RET
  273.  
  274. ;[ЗАПИСЬ "A" В ПОРТ 0X7F]
  275. W_OUT7F         LD A,(REG_A)
  276.                 LD (PORT_7F),A
  277.                 OUT (0X7F),A
  278.                 RET
  279.  
  280. ;[ЗАПИСЬ "A" В ПОРТ 0XFF]
  281. W_OUTFF         LD A,(REG_A)
  282.                 LD (WR_FF),A
  283.                 OUT (0XFF),A
  284.                 AND 3
  285.                 LD (MASK_WRK_DRV),A
  286.                 INC A
  287.                 LD B,A
  288.                 LD A,%00001000
  289.                 RLCA
  290.                 DJNZ $-1
  291.                 LD (MASK_MNT_DRV),A
  292.                 RET
  293.  
  294. ;[ЗАПИСЬ "A" В ПОРТ (C)]
  295. W_OUTCA         LD A,(REG_A)
  296. W_OUTCA1        LD D,A
  297.                 LD BC,(REG_C)                   ;ЕСЛИ ПОРТ НЕ TR-DOS
  298.                 LD A,C
  299. ;ОПРЕДЕЛЕНИЕ В КАКОЙ ПОРТ ЗАПИСЬ       
  300.                 CP 0X1F
  301.                 JP Z,W_OUT1F
  302.                 CP 0X3F
  303.                 JR Z,W_OUT3F
  304.                 CP 0X5F
  305.                 JR Z,W_OUT5F
  306.                 CP 0X7F
  307.                 JR Z,W_OUT7F
  308.                 CP 0XFF
  309.                 JR Z,W_OUTFF
  310.                 CP LOW (WIN_A0)
  311.                 JR Z,W_OUTCA3
  312. W_OUTCA4        OUT (C),D
  313.                 RET
  314.  
  315. ;[ЗАПИСЬ В ПОРТЫ ATM/PENTEVO]
  316. W_OUTCA3        LD A,B
  317.                 LD HL,BB_CPU1
  318.                 CP HIGH (WIN_A1)
  319.                 JR Z,W_OUTCA2
  320.                 CP HIGH (WIN_P2)
  321.                 JR Z,W_OUTCA2
  322.                 LD HL,BB_CPU2
  323.                 CP HIGH (WIN_A2)
  324.                 JR Z,W_OUTCA2
  325.                 CP HIGH (WIN_P2)
  326.                 JR NZ,W_OUTCA4
  327. W_OUTCA2        LD E,B
  328.                 PUSH DE
  329.                 PUSH HL
  330.                 CALL READ_WCPU12
  331.                 POP HL
  332.                 POP DE
  333.                 LD (HL),D
  334.                 INC HL
  335.                 LD (HL),E
  336.                 JP WRITE_WCPU12
  337.  
  338. ;[ЗАПИСЬ "D" В ПОРТ (C)]
  339. W_OUTCD         LD A,(IREG_D)
  340.                 JR W_OUTCA1
  341.  
  342. ;[ПЕРЕДАЧА БАЙТА, КОМАНДА OUTI]
  343. W_OUTI          LD HL,(BUFF_SECT)
  344.                 EXX
  345.                 LD A,(HL)
  346.                 INC HL
  347.                 EXX
  348.                 LD (HL),A
  349.                 INC HL
  350.                 LD (BUFF_SECT),HL
  351.                 RET
  352.  
  353. ;[ЧТЕНИЕ ПОРТА 0X1F]
  354. W_IN1F          LD A,(WR_1F)
  355.                 AND 0XF0
  356.                 CP 0X10
  357.                 JR C,W_IN1F1
  358.                 CP 0X20
  359.                 JR C,W_IN1F3
  360.                 CP 0XD0
  361.                 JR Z,W_IN1F1
  362.                 XOR A
  363.                 JR W_IN1F2
  364.  
  365. W_IN1F3         LD A,(INDEX)
  366.                 XOR %00000100
  367.                 JR W_IN1F4
  368.  
  369. W_IN1F1         LD A,0X24
  370. INDEX           EQU $-1
  371. W_IN1F4         XOR %00000010
  372.                 LD (INDEX),A
  373. W_IN1F2         LD (RD_1F),A
  374.                 LD (REG_A),A
  375.                 RET
  376.  
  377. ;[ЧТЕНИЕ ПОРТА 0X3F]
  378. W_IN3F          LD A,(PORT_3F)
  379.                 LD (REG_A),A
  380.                 RET
  381.  
  382. ;[ЧТЕНИЕ ПОРТА 0X5F]
  383. W_IN5F          LD A,(PORT_5F)
  384.                 LD (REG_A),A
  385.                 RET
  386.  
  387. ;[ЧТЕНИЕ ПОРТА 0X7F]
  388. W_IN7F          LD A,(PORT_7F)
  389.                 LD (REG_A),A
  390.                 RET
  391.  
  392. ;[ЧТЕНИЕ ПОРТА 0XFF]
  393. W_INFF          LD A,(RD_FF)
  394.                 LD (REG_A),A
  395.                 RET
  396.  
  397. ;[ЧТЕНИЕ В "H" ИЗ (С)]
  398. W_INHC          LD A,(REG_C)
  399. ;[ОПРЕДЕЛЕНИЕ ИЗ КАКОГО ПОРТА ЧТЕНИЕ]
  400. W_INHC1         CP 0X1F
  401.                 JR NZ,W_INHC2
  402.                 LD A,(RD_1F)
  403.                 LD (REG_H),A
  404.                 RET
  405.  
  406. W_INHC2         CP 0X3F
  407.                 JR NZ,W_INHC3
  408.                 LD A,(PORT_3F)
  409.                 LD (REG_H),A
  410.                 RET
  411.        
  412. W_INHC3         CP 0X5F
  413.                 JR NZ,W_INHC4
  414.                 LD A,(PORT_5F)
  415.                 LD (REG_H),A
  416.                 RET
  417.        
  418. W_INHC4         CP 0X7F
  419.                 JR NZ,W_INHC5
  420.                 LD A,(PORT_7F)
  421.                 LD (REG_H),A
  422.                 RET
  423.        
  424. W_INHC5         CP 0XFF
  425.                 JR NZ,W_INHC6
  426.                 LD A,(WR_FF)
  427.                 LD (REG_H),A
  428.                 RET
  429.  
  430. W_INHC6         LD BC,(REG_C)
  431.                 IN A,(C)
  432.                 LD (REG_H),A
  433.                 RET
  434.  
  435. ;[ЧТЕНИЕ INI]
  436. W_INI           LD A,(RD_1F)
  437.                 LD HL,(REG_L)
  438.                 LD (HL),A
  439.                 INC HL
  440.                 DEC B
  441.                 LD (REG_L),HL
  442.                 RET
  443.  
  444. WR_BYTE_DRIVE   LD H,VIRT_REAL_DRIVE
  445.                 CALL READCMOS
  446.                 JR NEOBYTEDRIVE1
  447.  
  448. RD_BYTE_DRIVE   LD A,(BYTE_DRIVE)
  449.                 LD (REG_A),A
  450.                 RET
  451.  
  452. NEO_BYTE_DRIVE  LD A,(REG_A)
  453. NEOBYTEDRIVE1   AND 0X0F
  454.                 LD L,A
  455.                 LD A,(BYTE_DRIVE)
  456.                 AND 0XF0
  457.                 OR L
  458.                 LD (BYTE_DRIVE),A
  459.                 RET
  460.  
  461. ;[ЧТЕНИЕ СЕКТОРА ИЛИ ПОРТОВ]
  462. READ_SEC_       LD A,(WR_1F)
  463.                 AND 0X0F0
  464.                 CP 0X80
  465.                 JP C,INFF_BIT6
  466.                 CP 0XC0
  467.                 JR NZ,READ_SEC_1
  468.                 LD A,(PORT_3F)
  469.                 LD HL,(REG_L)
  470.                 LD (HL),A
  471.                 INC HL
  472.                 DEC B
  473.                 LD A,(PORT_5F)
  474.                 LD (HL),A
  475.                 INC HL
  476.                 DEC B
  477.                 LD (REG_L),HL
  478.                 RET
  479.  
  480. ;[ЧТЕНИЕ/ЗАПИСЬ СЕКТОРА]
  481. ;IXL=0-ЧТЕНИЕ, =FF-ЗАПИСЬ
  482. READ_WRITE_SEC  PUSH IX
  483.                 JR WRITE_SEC_1
  484.  
  485. ;[ЧТЕНИЕ СЕКТОРА]
  486. READ_SEC_1      PUSH IX
  487.                 LD IXL,0
  488.                 JR WRITE_SEC_1
  489.  
  490. ;[ЗАПИСЬ СЕКТОРА]
  491. WRITE_SEC_      PUSH IX
  492.                 LD IXL,0XFF
  493. WRITE_SEC_1     CALL READ_WCPU12
  494.                 CALL W_WR_RD_SECT
  495.                 LD IX,0X8090
  496.                 LD (REG_F),IX                   ;ЕМУЛЯЦИЯ ФЛАГА УСПЕШНОГО ЧТЕНИЯ/ЗАПИСИ СЕКТОРА
  497.                 CALL WRITE_WCPU12
  498.                 POP IX
  499.                 RET
  500.  
  501. ;[ЧТЕНИЕ ИЛИ ЗАПИСЬ СЕКТОРА РАМДИСКА]
  502. W_WR_RD_SECT    LD A,(WR_FF)
  503.                 AND 3
  504.                 INC A
  505.                 LD B,A
  506.                 IN A,(RW_PORT0)
  507.                 REPT 5
  508.                 RRCA
  509.                 ENDM
  510.                 DJNZ $-1
  511.                 JP C,WR_RD_SEC_M                ;РАБОТА С ПРИМОНТИРОВАННЫМ ОБРАЗОМ
  512.                 LD BC,WIN_A1
  513.                 LD A,0X40
  514.                 OUT (C),A
  515.                 LD B,HIGH (WIN_P1)
  516.                 LD A,RAM_RAMDISK
  517.                 OUT (C),A                       ;СТРАНИЦА ЗАГОЛОВКОВ РАМДИСКА
  518.                 LD A,(PORT_3F)                  ;ВЗЯЛИ НОМЕР ТРЕКА
  519.                 ADD A,A                         ;СТОРОН 2
  520.                 LD C,A
  521.                 LD A,(WR_FF)
  522.                 AND 0X10                        ;ПРОВЕРКА КАКАЯ СТОРОНА ДИСКА
  523.                 JR NZ,WWRRD1
  524.                 INC C                           ;ДЛЯ СТОРОНЫ 1
  525. WWRRD1          LD B,HIGH (CPU1)+2              ;АДРЕС НАЧАЛА ИНФЫ О СЕКТОРАХ НА ДОРОЖКЕ
  526.                 LD A,(PORT_5F)                  ;ВЗЯЛИ НОМЕР СЕКТОРА
  527.                 LD L,A
  528.                 LD H,0
  529. WWRRD3          LD A,(BC)
  530.                 LD D,A                          ;ВЗЯЛИ НОМЕР СЕКТОРА
  531.                 INC B
  532.                 LD A,(BC)
  533.                 LD E,A                          ;ВЗЯЛИ РАЗМЕР СЕКТОРА
  534.                 INC B
  535. ;               LD A,D
  536. ;               AND A
  537. ;               JR Z,WWRRD_ERR
  538.                 LD A,L
  539.                 CP D
  540.                 JR Z,WWRRD2
  541.                 LD A,E
  542.                 ADD A,H
  543.                 LD H,A
  544.                 JR WWRRD3
  545.  
  546. WWRRD2          LD A,E
  547.                 RRCA
  548.                 LD (PORT_7F),A 
  549.                 OUT (0X7F),A                    ;РАЗМЕР НАЙДЕННОГО СЕКТОРА
  550.                 LD L,0
  551.                 LD E,L
  552.                 SRL H
  553.                 RR L                            ;HL=СМЕЩЕНИЕ В БЛОКАХ ДО НАЙДЕННОГО СЕКТОРА
  554.                 LD B,HIGH (CPU1)
  555.                 LD A,(BC)
  556.                 LD D,A
  557.                 ADD HL,DE                       ;HL=СМЕЩЕНИЕ ОТ НАЧАЛА СТРАНИЦЫ В БЛОКАХ
  558.                 INC B
  559.                 LD A,(BC)
  560.                 LD C,A                          ;СМЕЩЕНИЕ В СТРАНИЦАХ ОТ НАЧАЛА РАМДИСКА
  561.                 LD A,H
  562.                 CP HIGH (CPU1)
  563.                 JR C,WWRRD5
  564.                 SUB 0X40
  565.                 LD H,A
  566.                 INC C
  567. ;HL=СМЕЩЕНИЕ В СТРАНИЦЕ ДО НАЧАЛА СЕКТОРА
  568. WWRRD5          LD A,C                          ;СМЕЩЕНИЕ ДО НОМЕРА СТРАНИЦЫ, ГДЕ УКАЗАННЫЙ СЕКТОР НАЧИНАЕТСЯ
  569.                 ADD A,RAM_DATARAMD              ;ПРИБАВИЛИ НОМЕР НАЧАЛА РАМДИСК И +1. В 0 СТРАНИЦЕ РАМДИСКА ОПИСАТЕЛИ СЕКТОРОВ
  570.                 LD IXH,A                        ;СОХРАНИЛИ НОМЕР ВЫЧИСЛЕННОЙ СТРАНИЦЫ
  571.                 LD DE,(REG_L)
  572.                 LD BC,(BB_CPU1)
  573.                 LD A,C
  574.                 LD C,LOW (WIN_A0)
  575.                 OUT (C),A                       ;ВЕРНУЛИ СТАНДАРТНУЮ 5 СТРАНИЦУ
  576. SP_RAMD9        LD A,D                          ;ПРОВЕРКА ГРАНИЦЫ ОТКУДА/КУДА КОПИРОВАТЬ
  577.                 CP HIGH (CPU2)
  578.                 PUSH DE
  579.                 LD DE,CPU1+HIGH (WIN_P1)
  580.                 LD BC,WIN_A1                    ;ЕСЛИ ВЕРХНИЕ 32КБ ОЗУ, ТО НУЖНО ВКЛЮЧИТЬ В 1 ОКНЕ ПРОЕЦИРОВАНИЯ
  581.                 JR NC,SP_RAMD1
  582.                 LD DE,CPU2+HIGH (WIN_P2)
  583.                 LD B,HIGH (WIN_A2)              ;ЕСЛИ НИЖНИЕ 32КБ ОЗУ, ТО НУЖНО ВКЛЮЧИТЬ ВО 2 ОКНЕ ПРОЕЦИРОВАНИЯ
  584. SP_RAMD1        LD A,0X40
  585.                 OUT (C),A
  586.                 LD B,E
  587.                 LD A,IXH                        ;НОМЕР ВЫЧИСЛЕННОЙ СТРАНИЦЫ ОЗУ
  588.                 OUT (C),A                       ;ВКЛЮЧИЛИ ВЫЧИСЛЕННУЮ СТРАНИЦУ
  589.                 LD B,D                          ;СТАРШИЙ БАЙТ АДРЕСА НАЧАЛА ВКЛЮЧЕННОЙ СТРАНИЦЫ
  590.                 POP DE
  591.                 LD A,B
  592.                 ADD A,H
  593.                 LD H,A
  594.                 LD A,IXL
  595.                 AND A
  596.                 JR NZ,IN_ROM1
  597.                 LD A,D
  598.                 INC A
  599.                 JR NZ,IN_ROM1
  600.                 LD A,E
  601.                 AND A
  602.                 JR Z,IN_ROM1
  603. IN_ROM4         NEG
  604.                 LD C,A
  605.                 LD B,0
  606.                 LDIR
  607.                 NEG
  608.                 LD C,A
  609. IN_ROM2         EX DE,HL
  610.                 ADD HL,BC
  611.                 EX DE,HL
  612.                 ADD HL,BC
  613.                 LD A,(PORT_7F)
  614.                 JP SP_RAMD8_
  615.  
  616. IN_ROM1         LD A,D
  617.                 CP HIGH (CPU1)
  618.                 JR NC,IN_ROM3
  619.                 LD A,(PORT_7F)
  620.                 AND A
  621.                 LD BC,0X80
  622.                 JR Z,IN_ROM2
  623.                 LD BC,0X100
  624.                 JR IN_ROM2
  625.  
  626. IN_ROM3         CP HIGH (CPU2)                  ;ПРОВЕРКА ПЕРЕХОДА ГРАНИЦЫ СТРАНИЦ
  627.                 JP NC,SP_RAMD3                  ;ЕСЛИ ВЫШЕ ТО СРАЗУ КОПИРУЕМ
  628.                 CP HIGH (CPU2)-1
  629.                 JP C,SP_RAMD3                   ;ЕСЛИ НИЖЕ ТАК ЖЕ СРАЗУ КОПИРУЕМ
  630.                 LD A,E
  631.                 AND A                           ;ЕСЛИ СЕКТОР ПОЛНОСТЬЮ УКЛАДЫВЕТСЯ ДО ГРАНИЦЫ, ТО СРАЗУ КОПИРУЕМ
  632.                 JR Z,SP_RAMD3                   ;ИНАЧЕ ПРИНУДИТЕЛЬНО КОПИРУЕМ В ДВА ПРИЕМА
  633.                 LD A,IXL                        ;ЧТЕНИЕ ИЛИ ЗАПИСЬ?
  634.                 AND A
  635.                 LD A,E                          ;МЛАДШИЙ БАЙТ АДРЕС В БЛОКЕ
  636.                 JR Z,SP_RAMD4
  637.                 EX DE,HL                        ;ДЛЯ ЗАПИСИ МЕНЯЕМ НАПРАВЛЕНИЕ
  638. SP_RAMD4        NEG
  639.                 LD C,A                          ;КОПИРУЕМ ОСТАТОК ДО КОНЦА БЛОКА
  640.                 LD B,0
  641.                 LDIR
  642.                 NEG
  643.                 PUSH AF                 ;СПРЯТАЛИ СКОЛЬКО ОСТАЛОСЬ КОПИРОВАТЬ ИЗ НАЧАЛА СЛЕДУЮЩЕГО БЛОКА
  644.                 LD BC,(BB_CPU2)
  645.                 LD A,C
  646.                 LD C,LOW (WIN_A0)
  647.                 OUT (C),A
  648.                 LD B,HIGH (WIN_A1)
  649.                 LD A,0X40
  650.                 OUT (C),A
  651.                 LD B,HIGH (WIN_P1)
  652.                 LD A,IXH
  653.                 OUT (C),A                       ;ВЫЧИСЛЕННУЮ СТРАНИЦУ ВКЛЮЧАЕМ В 1 ОКНЕ ПРОЕЦИРОВАНИЯ
  654.                 LD A,IXL                        ;ЧТЕНИЕ ИЛИ ЗАПИСЬ
  655.                 AND A
  656.                 JR Z,SP_RAMD5
  657.                 LD A,D                          ;ДЛЯ ЗАПИСИ
  658.                 SUB 0X40                        ;ИЗМЕНИЛИ АДРЕС КУДА КОПИРОВАТЬ НА ДРУГОЕ ОКНО ПРОЕЦИРОВАНИЯ
  659.                 LD D,A
  660.                 JR SP_RAMD6
  661.  
  662. SP_RAMD5        LD A,H                          ;ДЛЯ ЧТЕНИЯ  
  663.                 SUB 0X40                        ;ИЗМЕНИЛИ АДРЕС КУДА КОПИРОВАТЬ НА ДРУГОЕ ОКНО ПРОЕЦИРОВАНИЯ
  664.                 LD H,A
  665. SP_RAMD6        POP AF
  666.                 LD C,A                          ;СКОЛЬКО ОСТАЛОСЬ СКОПИРОВАТЬ БАЙТ
  667.                 LD B,0
  668.                 LDIR
  669.                 LD A,(PORT_7F)
  670.                 JR SP_RAMD8_
  671.  
  672. SP_RAMD3        LD A,IXL                        ;ЧТЕНИЕ ИЛИ ЗАПИСЬ
  673.                 AND A
  674.                 JR Z,SP_RAMD7
  675.                 EX DE,HL                        ;ДЛЯ ЗАПИСИ МЕНЯЕМ НАПРАВЛЕНИЕ
  676. SP_RAMD7        LD A,(PORT_7F)
  677.                 AND A
  678.                 JR NZ,SP_RAMD8
  679.                 CALL COPYHBLOCK                 ;ДЛЯ СЕКТОРА РАЗМЕРОМ 128 БАЙТ КОПИРУЕМ ПОЛОВИНУ И ВЫХОДИМ
  680. ECOPY_BLOCK     LD A,IXL
  681.                 AND A
  682.                 JR Z,ECOPY_BLOCK1
  683.                 EX DE,HL
  684. ECOPY_BLOCK1    LD (REG_L),DE
  685.                 RET
  686.  
  687. SP_RAMD8        CALL COPY_BLOCK                 ;ДЛЯ СЕКТОРА 256 БАЙТ КОПИРУЕМ ВЕСЬ И ВЫХОДИМ
  688. SP_RAMD8_       DEC A
  689.                 JR Z,ECOPY_BLOCK
  690.                 LD (PORT_7F),A
  691.                 OUT (0X7F),A
  692.                 LD A,IXL
  693.                 AND A
  694.                 JR Z,SP_RAMD0
  695.                 EX DE,HL
  696. SP_RAMD0        LD A,0X3F
  697.                 AND H
  698.                 LD H,A
  699.                 JP SP_RAMD9
  700.  
  701. ;[ЧТЕНИЕ CMOS]
  702. ;НА ВХОДЕ: H-АДРЕС ЯЧЕЙКИ
  703. ;          L-ПРОЧИТАННОЕ ЗНАЧЕНИЕ
  704. READCMOS        PUSH BC
  705.                 LD BC,CMOSD_SET_ADR
  706.                 OUT (C),H
  707.                 LD B,HIGH (CMOSD_RD_WR)
  708.                 IN L,(C)
  709.                 POP BC
  710.                 LD A,L
  711.                 AND A
  712.                 RET
  713.  
  714. ;[ЗАПИСЬ CMOS]
  715. ;НА ВХОДЕ: H-АДРЕС ЯЧЕЙКИ
  716. ;          L-ЧТО ТУДА ЗАПИСАТЬ
  717. WRITECMOS       RST8D _CMOS_RW,_WRITE_CMOS
  718.                 RET
  719.  
  720. CP_TYPEDRIVE    PUSH BC
  721.                 IN A,(RW_PORT0)
  722.                 AND 3
  723.                 LD B,A
  724.                 LD A,(TRD_5CF6)
  725.                 CP B
  726.                 POP BC
  727.                 RET
  728.  
  729. ;[УСТАНОВКА ПЕРЕМЕННЫХ ТЕКУЩЕГО ПРИВОДА]
  730. SET_DRIVENAME   LD H,VIRT_REAL_DRIVE
  731.                 CALL READCMOS
  732.                 RRCA
  733.                 RRCA
  734.                 AND 3
  735.                 LD (TRD_5D19),A
  736.                 LD (TRD_5CF6),A
  737.                 OR 0X3C
  738.                 LD (TRD_5D16),A
  739.                 RET
  740.  
  741. ;[ФОРМАТИРОВАНИЕ RAM ДИСКА]
  742. FORMAT_RAM      LD A,(TRD_5CF6)
  743.                 LD B,A
  744.                 INC B
  745.                 LD A,8
  746.                 RLCA
  747.                 DJNZ $-1
  748.                 LD B,A
  749.                 IN A,(RW_PORT0)
  750.                 AND B
  751.                 JR NZ,FORMAT_RAM3               ;ЕСЛИ БИТ=1 ФОРМАТ ПРИМОНТИРОВАННОГО ОБРАЗА
  752.                 CALL CP_TYPEDRIVE
  753.                 RET NZ                          ;ВЫХОД ДЛЯ ФОРМАТА РЕЛЬНОГО ДИСКА
  754.                 CALL CREATE_TRDTABL             ;ФОРМАТ РАМДИСКА
  755.                 XOR A
  756.                 RET
  757.  
  758. FORMAT_RAM3     LD HL,TRD_5D25
  759.                 LD DE,TRD_5D26
  760.                 LD BC,0XFF
  761.                 LD (HL),B
  762.                 LDIR
  763.                 LD D,B
  764.                 LD E,B
  765.                 LD B,0X10
  766. FORMAT_RAM1     PUSH BC
  767.                 PUSH DE
  768.                 LD B,1
  769.                 LD HL,TRD_5D25
  770.                 CALL COM_06
  771.                 POP DE
  772.                 POP BC
  773.                 INC E
  774.                 DJNZ FORMAT_RAM1
  775.                 XOR A
  776.                 RET
  777.  
  778. ;[ПРОВЕРКА НАЛИЧИЯ МАРКЕРА РАМДИСКА]
  779. CMP_RAM_DISK    CALL READ_WCPU12
  780.                 LD BC,WIN_P1
  781.                 LD A,RAM_RAMDISK
  782.                 OUT (C),A
  783.                 LD HL,CPU1+0X3FFF
  784.                 LD D,(HL)
  785.                 DEC H
  786.                 LD E,(HL)                       ;ВЗЯЛИ БАЙТЫ ДЛЯ ПРОВЕРКИ МАРКЕРА
  787.                 CALL WRITE_WCPU12
  788.                 LD HL,"RD"
  789.                 AND A
  790.                 SBC HL,DE
  791.                 RET Z                           ;ЕСЛИ МАРКЕР НА МЕСТЕ, ТО РАМДИСКА НЕ СОЗДАЕМ
  792. ;[СОЗДАНИЕ ЧИСТОГО РАМДИСКА]
  793. CREATE_TRDTABL  LD BC,WIN_P1
  794.                 LD A,RAM_RAMDISK                ;НУЖНА СТРАНИЦА НАЧАЛА РАМДИСКА, ГДЕ БУДЕТ ТАБЛИЦА ОПИСАТЕЛЕЙ
  795.                 OUT (C),A
  796.                 LD HL,CPU1
  797.                 PUSH HL
  798.                 LD DE,CPU1+1
  799.                 LD BC,0X3FFF
  800.                 LD (HL),L
  801.                 LDIR                            ;ОЧИСТИЛИ СТРАНИЦУ
  802.                 POP DE                          ;АДРЕС НАЧАЛА
  803.                 LD HL,0                         ;СМЕЩЕНИЕ В БЛОКАХ И СТРАНИЦАХ
  804.                 LD A,0XA0
  805. ELT2            PUSH AF
  806.                 LD BC,0X1000                    ;СЧЕТЧИК НОМЕРОВ СЕКТОРОВ И ИХ НОМЕРА
  807.                 LD A,L
  808.                 RRCA
  809.                 RRCA
  810.                 LD (DE),A                       ;СМЕЩЕНИЕ В БЛОКАХ ДОРОЖКИ В СТРАНИЦЕ
  811.                 INC D
  812.                 LD A,H
  813.                 LD (DE),A                       ;СМЕЩЕНИЕ В СТРАНИЦАХ ДО ДОРОЖКИ
  814.                 INC D
  815. ELT1            INC C
  816.                 LD A,C
  817.                 LD (DE),A                       ;НОМЕР СЕКТОРА
  818.                 INC D
  819.                 LD A,2
  820.                 LD (DE),A                       ;РАЗМЕР СЕКТОРА
  821.                 INC D
  822.                 DJNZ ELT1                       ;ВНОСИМ В ТАБЛИЦУ ВСЕ НОМЕРА СЕКТОРОВ С РАЗМЕРАМИ
  823.                 LD D,HIGH (CPU1)                ;ВЕРНУЛИ УКАЗАТЕЛЬ В НАЧАЛО
  824.                 INC E                           ;ДЛЯ СЛЕДУЮЩЕЙ ДОРОЖКИ
  825.                 LD BC,0X40
  826.                 ADD HL,BC                       ;ПЕРЕХОД К СЛЕДУЮЩЕЙ ДОРОЖКЕ
  827.                 POP AF
  828.                 DEC A
  829.                 JR NZ,ELT2                      ;ПОВТОРЯЕМ ДЛЯ ВСЕХ ДОРОЖЕК
  830.                 LD HL,CPU1+0X3FFF
  831.                 LD (HL),"R"                     ;ВНОСИМ МАРКЕР РАМДИСКА
  832.                 DEC H
  833.                 LD (HL),"D"
  834.                 LD BC,WIN_P1
  835.                 LD A,RAM_DATARAMD
  836.                 OUT (C),A
  837.                 LD HL,CPU1
  838.                 LD DE,CPU1+1
  839.                 LD BC,0X0FFF
  840.                 LD (HL),L
  841.                 LDIR
  842.                 LD HL,DSKINFO
  843.                 LD DE,CPU1+0X8E1
  844.                 LD BC,DSK_END-DSKINFO
  845.                 LDIR
  846. ;[ВОССТАНОВЛЕНИЕ КОНФИГУРАЦИИ ОКОН ПРОЕЦИРОВАНИЯ 1,2]
  847. WRITE_WCPU12    LD BC,(BB_CPU1)
  848.                 LD A,C
  849.                 LD C,LOW (WIN_A0)
  850.                 OUT (C),A
  851.                 LD BC,(BB_CPU2)
  852.                 LD A,C
  853.                 LD C,LOW (WIN_A0)
  854.                 OUT (C),A
  855.                 RET
  856.  
  857. ;[ЧТЕНИЕ КОНФИГУРАЦИИ ОКОН ПРОЕИРОВАНИЯ 1,2]
  858. READ_WCPU12     LD BC,RD_RAMNROM
  859.                 IN L,(C)                        ;БИТЫ RAM & ROM
  860.                 INC B
  861.                 IN H,(C)                        ;БИТЫ DOS & 7FFD
  862.                 ADD HL,HL
  863.                 LD B,HIGH (RD_1WINA1)
  864.                 IN A,(C)
  865.                 CP 0XC0
  866.                 JR NC,RST30_01
  867.                 LD E,A
  868.                 LD D,HIGH (WIN_P1)
  869.                 JR RST30_02
  870.  
  871. RST30_01        RLCA
  872.                 RLCA
  873.                 SLA L
  874.                 RRA
  875.                 SLA H
  876.                 RRA
  877.                 LD E,A
  878.                 LD D,HIGH (WIN_A1)
  879. RST30_02        LD (BB_CPU1),DE
  880.                 INC B
  881.                 IN A,(C)
  882.                 CP 0XC0
  883.                 JR NC,RST30_03
  884.                 LD E,A
  885.                 LD D,HIGH (WIN_P2)
  886.                 JR RST30_04
  887.  
  888. RST30_03        RLCA
  889.                 RLCA
  890.                 SLA L
  891.                 RRA
  892.                 SLA H
  893.                 RRA
  894.                 LD E,A
  895.                 LD D,HIGH (WIN_A2)
  896. RST30_04        LD (BB_CPU2),DE
  897.                 RET
  898.  
  899. DISK_NONE       PUSH HL
  900.                 PUSH BC
  901.                 CALL READ_WCPU12
  902.                 LD BC,WIN_A1
  903.                 LD A,0X40
  904.                 OUT (C),A
  905.                 LD B,HIGH (WIN_P1)
  906.                 LD A,RAM_RAMDISK
  907.                 OUT (C),A
  908.                 LD HL,CPU1+0XFFF
  909.                 LD A,(HL)
  910.                 DEC H
  911.                 CP "R"
  912.                 SCF
  913.                 JR NZ,DISK_NONE1
  914.                 LD A,(HL)
  915.                 CP "D"
  916.                 SCF
  917.                 JR NZ,DISK_NONE1
  918.                 XOR A
  919. DISK_NONE1      PUSH AF
  920.                 CALL WRITE_WCPU12
  921.                 POP AF
  922.                 POP BC
  923.                 POP HL
  924.                 RET
  925.  
  926. SET_RWPORT0     PUSH BC
  927.                 PUSH AF
  928.                 LD BC,CMOSD_SET_ADR
  929.                 LD A,VIRT_REAL_DRIVE
  930.                 OUT (C),A
  931.                 LD B,HIGH (CMOSD_RD_WR)
  932.                 IN A,(C)
  933.                 AND 0X0F
  934.                 LD C,A
  935.                 IN A,(RW_PORT0)
  936.                 AND 0XF0
  937.                 OR C
  938.                 OUT (RW_PORT0),A
  939.                 POP AF
  940.                 POP BC
  941.                 RET
  942.