Subversion Repositories pentevo

Rev

Rev 952 | Rev 1035 | Go to most recent revision | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed | ?url?

  1.  
  2. ;LAST UPDATE: 26.05.2021 savelij
  3.  
  4.                 include ../../macros.a80
  5.                 include ../../define.a80
  6.                 include ../../global_vars.a80
  7.                 include ../../evodos_vars.a80
  8.  
  9. DEPKADR         EQU 0X6000
  10.  
  11.                 ORG 0X0000
  12.                 DI
  13.                 JP INITPAGE0
  14.  
  15.                 DUPL 0X0008-$,0XFF
  16.                 NOP
  17.                 JP DOS2RST8
  18.  
  19.                 DUPL ADR_SEL_ROM-$,0XFF
  20.                 OUT (C),A
  21.                 NOP
  22.                 RET
  23.  
  24.                 DUPL 0X0038-$,0XFF
  25.                 EI
  26.                 RET
  27.  
  28.                 DUPL 0X0040-$,0XFF
  29.                 JP SET_MAPPER
  30.  
  31.                 DUPL 0X0066-$,0XFF
  32.                 NOP
  33.  
  34.                 DUPL 0X0080-$,0XFF
  35.                 include ../../dec40.a80
  36.  
  37.                 DUPL 0X00FF-$,0XFF
  38.                 DW 0X0038
  39.  
  40. INITPAGE0       LD SP,DEPKADR
  41.                 LD IY,0X5C3A
  42.                 LD A,0X3F
  43.                 LD I,A
  44.                 IM 1
  45.                 XOR A
  46.                 OUT (0XFE),A
  47.                 LD HL,PAGES_CONF
  48.                 LD BC,0XBC77
  49.                 LD A,2
  50.                 OUT (C),A
  51.                 LD DE,0X103F
  52. INITPAGE2       LD BC,CONF_128
  53.                 OUT (C),D
  54.                 LD BC,LOW (WIN_A0)
  55. INITPAGE1       OUTI
  56.                 LD A,B
  57.                 SUB E
  58.                 LD B,A
  59.                 JR NZ,INITPAGE1
  60.                 LD BC,CONF_128
  61.                 LD A,D
  62.                 XOR 0X10
  63.                 LD D,A
  64.                 JR Z,INITPAGE2
  65.                 LD BC,0XFF77
  66.                 LD A,0XAB
  67.                 OUT (C),A
  68.                 PEC_ON M_SHADOW_BF
  69.                 LD HL,INITPAGE3
  70.                 PUSH HL
  71.                 LD HL,0X40;INST_NMIRST
  72.                 PUSH HL
  73.                 LD BC,WIN_A0
  74.                 LD A,ROM_RST81
  75.                 JP ADR_SEL_ROM
  76.  
  77. INITPAGE3       RST8 _CMOS_RW,_INIT_CMOS
  78.                 LD HL,PAGES_CONF
  79.                 LD A,0XEF
  80.                 IN A,(0XFE)
  81.                 RRCA                            ;ПРОВЕРКА НАЖАТИЯ КНОПКИ "0" ПРИ СБРОСЕ
  82.                 CALL NC,RES_REZIDENT
  83.                 JR NC,RSTRAM                    ;СБРОС В ОСНОВНОЕ ПЗУ
  84.                 RRCA
  85.                 RRCA
  86.                 RRCA
  87.                 RRCA                            ;ПРОВЕРКА НАЖАТИЯ КНОПКИ "6" ПРИ СБРОСЕ
  88.                 JR C,INITPAGE4
  89. ;ВХОД В ОТЛАДЧИК
  90.                 EXX
  91.                 LD BC,WIN_P2
  92.                 XOR A
  93.                 OUT (C),A
  94.                 LD HL,CPU2+DEBUG_ONOFF
  95.                 SET 7,(HL)
  96.                 EXX
  97.                 IN A,(PEVO_CONF)
  98.                 OR M_NMI_BF
  99.                 OUT (PEVO_CONF),A
  100.                 AND M_NMI_BF!0XFF
  101.                 OUT (PEVO_CONF),A
  102.                 HALT
  103. INITPAGE4       LD BC,CMOSD_SET_ADR
  104.                 LD A,CMOS_BYTE_00
  105.                 OUT (C),A
  106.                 LD B,HIGH (CMOSD_RD_WR)
  107.                 IN A,(C)
  108.                 AND MKOL_MODES
  109.                 CP KOL_MODES
  110.                 JR NC,RSTRAM
  111.                 AND A
  112.                 JR Z,RSTRAM
  113.                 DEC A
  114.                 LD HL,PAGES_CONFGLUK            ;КОНФИГУРИРОВАТЬ ДЛЯ GLUK
  115.                 JR Z,RSTRAM
  116.                 DEC A
  117.                 LD HL,PAGES_PROFROM             ;КОНФИГУРИРОВАТЬ ДЛЯ PROFROM
  118.                 JR Z,RSTRAM
  119.                 LD HL,PAGES_CUSTOM              ;КОНФИГУРИРОВАТЬ ДЛЯ USER ROM
  120. RSTRAM          LD A,0XEF
  121.                 IN A,(0XFE)
  122.                 RRCA                            ;ПРОВЕРКА НЕ НАЖАТОСТИ КНОПКИ "0" ПРИ СБРОСЕ
  123.                 JR NC,RSTRAM                    ;ЕСЛИ НАЖАТА ЖДЕМ ОТПУСКАНИЯ
  124.                 LD BC,0XBC77
  125.                 LD A,2
  126.                 OUT (C),A
  127.                 LD DE,0X103F
  128. LOOP2           LD BC,CONF_128
  129.                 OUT (C),D
  130.                 LD BC,LOW (WIN_A0)
  131. LOOP1           OUTI
  132.                 LD A,B
  133.                 SUB E
  134.                 LD B,A
  135.                 JR NZ,LOOP1
  136.                 LD BC,CONF_128
  137.                 LD A,D
  138.                 XOR 0X10
  139.                 LD D,A
  140.                 JR Z,LOOP2
  141. RSTPAL          LD A,(HL)
  142.                 LD IXH,A                        ;НОМЕР СТРАНИЦЫ ЗАВЕРШЕНИЯ ИНИТА МАНАГЕРА
  143.                 LD DE,0XAB0F                    ;ZX SCREEN MODE, TURBO ON 14MHZ
  144.                 LD BC,0XFD77                    ;И ДОСТУП К ПАЛИТРЕ
  145.                 OUT (C),D
  146.                 EI                              ;палитра
  147.                 HALT
  148.                 DI
  149.                 LD HL,TRSTPAL                   ;+15
  150.                 LD BC,0XBD77
  151.                 OUT (C),D                       ;вкл.PAL
  152. RSTPAL0         LD A,E
  153.                 BIT 3,E
  154.                 OUT (0XFE),A
  155.                 JR Z,$+4
  156.                 OUT (0XF6),A
  157.                 LD A,(HL)
  158.                 INC HL
  159.                 OR %00001100
  160.                 OUT (0XFF),A
  161.                 DEC E
  162.                 JP P,RSTPAL0
  163. END_INIT        LD A,0XAB
  164.                 LD BC,0XFF77
  165.                 OUT (C),A                       ;выкл.PAL
  166.                 LD A,IXH
  167.                 LD BC,0
  168.                 AND 0X3C
  169.                 JR Z,RSTKEYS2                   ;RESET TO EVO SERVICE PAGE
  170.                 CP CONF4GLUK&0X3F
  171.                 JR Z,RSTKEYS3                   ;RESET TO GLUK SERVICE PAGE
  172.                 CP CONF4CUSTOM&0X3F
  173.                 JR Z,RSTKEYS3                   ;RESET TO CUSTOM ROM
  174.                 JP LDIR4PROFROM                 ;RESET TO PROFROM BASIC 128
  175.  
  176. RSTKEYS3        PUSH BC
  177.                 LD BC,0XBC77
  178.                 LD A,2
  179.                 OUT (C),A
  180.                 LD BC,WIN_A0
  181.                 LD A,IXH
  182.                 OUT (C),A
  183.                 PEC_OFF M_SHADOW_BF
  184.                 LD BC,0XFF77
  185.                 LD A,0XA3
  186.                 JP 0X3D2D
  187.  
  188. RSTKEYS2        LD H,CMOS_BYTE_00
  189.                 RST8 _CMOS_RW,_READ_CMOS
  190.                 AND 0XFC                        ;СБРОС ДЛЯ ОСНОВНОГО ПЗУ
  191.                 LD L,A
  192.                 RST8 _CMOS_RW,_WRITE_CMOS       ;ПРИНУДИТЕЛЬНО ВЫСТАВЛЕНИЕ В КМОС СБРОСА НА EVO SERVICE
  193.         IFDEF DOS_FE
  194. ;               RST8 _MOUNTER,_MOUNT_RAMDISK
  195.                 LD BC,WIN_A3
  196.                 LD A,ROM_RST82
  197.                 OUT (C),A
  198.                 LD B,HIGH (WIN_P2)
  199.                 LD A,RAM_EVODOS
  200.                 OUT (C),A
  201.                 LD A,(CPU2+COPY_VIRT_BITS)
  202.                 PUSH AF
  203.                 CALL UNP_DOS_FE+CPU3            ;РАСПАКОВКА DOS
  204.                 POP AF
  205.                 LD (CPU2+COPY_VIRT_BITS),A
  206.         ELSE
  207.                 LD BC,WIN_A3
  208.                 LD A,ROM_ADD_DOS
  209.                 OUT (C),A
  210.                 LD B,HIGH (WIN_P2)
  211.                 LD A,RAM_EVODOS
  212.                 OUT (C),A
  213.                 LD A,(CPU2+COPY_VIRT_BITS)
  214.                 LD HL,CPU3
  215.                 LD DE,CPU2
  216.                 LD BC,0X4000
  217.                 LDIR                            ;ПЕРЕНОС DOS
  218.                 LD (CPU2+COPY_VIRT_BITS),A
  219.         ENDIF
  220.                 LD BC,WIN_A2
  221.                 LD A,0X7D
  222.                 OUT (C),A
  223.                 LD B,HIGH (WIN_A3)
  224.                 LD A,0XFF
  225.                 OUT (C),A
  226. ;ДЛЯ РЕЗИДЕНТА HONEY COMANDER
  227.         IFDEF REZIDENT
  228.                 CALL CMP_REZIDENT               ;ПРОВЕРКА РЕЗИДЕНТА
  229.         ENDIF
  230.                 LD BC,0XFEFF
  231. RSTKEYS1        LD A,B
  232.                 IN A,(0XFE)
  233.                 REPT 5
  234.                 RRA
  235.                 JR C,$+3
  236.                 INC C
  237.                 ENDM
  238.                 RLC B
  239.                 JR C,RSTKEYS1
  240.                 DEC C
  241.                 JP P,GTSTKEY                    ;НАЖАТО БОЛЕЕ 1 КНОПКИ, ПЕРЕХОДИМ К ТЕСТУ КЛАВИАТУРЫ
  242.                 LD IXL,0                        ;ЗАПУСК НЕОСНОВНОЙ ПРОШИВКИ СЕРВИСА
  243.                 LD DE,0                         ;1 НАЖАТА, ПРОВЕРЯЕМ ЧТО ЭТО
  244.                 LD BC,CONF_128
  245.                 PUSH DE                         ;АДРЕС ПЕРЕХОДА В ПЗУ ЕСЛИ ВЫБРАНО
  246.                 LD A,0XFE
  247.                 IN A,(0XFE)                     ;ЧТЕНИЕ НАЖАТОСТИ КНОПКИ "CS"
  248.                 RRA
  249.                 LD A,0
  250.                 JP NC,START_SELECT              ;ПРИ НАЖАТОЙ "CS" ПЕРЕХОДИМ В БЕЙСИК 128
  251.                 LD A,0X7F
  252.                 IN A,(0XFE)                     ;ЧТЕНИЕ НАЖАТОСТИ КНОПКИ "SS"
  253.                 LD D,A
  254.                 RRA
  255.                 RRA
  256.                 LD A,0X30
  257.                 JP NC,START_SELECT              ;ПРИ НАЖАТОЙ "SS" ПЕРЕХОДИМ В БЕЙСИК 48
  258.                 LD A,D
  259.                 RRA                             ;ПРОВЕРКА НАЖАТОСТИ КНОПКИ "SPACE"
  260.                 JR C,CMPCFG1                    ;ПЕРЕХОДИМ ДАЛЕЕ ЕСЛИ НИЧЕГО НЕ НАЖАТО
  261.                 LD A,0X10
  262.                 LD DE,0X3D2F
  263.                 PUSH DE
  264.                 JP START_SELECT                 ;ПРИ НАЖАТОЙ "SPACE" ПЕРЕХОДИМ В TR-DOS
  265.  
  266. CMPCFG1         LD A,0XFD
  267.                 IN A,(0XFE)
  268.                 AND 4                           ;НАЖАТО "D" ЗАПУСК ДЕМКИ
  269.                 JP Z,GDEMO
  270.                 LD IXL,1                        ;ЗАПУСК ОСНОВНОЙ ПРОШИВКИ СЕРВИСА
  271.                 LD HL,DEPKADR                   ;НИЧЕГО НЕ НАЖАТО, ЗАПУСКАЕМ ОСНОВНУЮ ПРОШИВКУ
  272.                 LD SP,HL
  273.                 EX DE,HL
  274.                 LD HL,CMPCFG3
  275.                 PUSH HL
  276.                 LD HL,0X0101
  277.                 PUSH HL
  278.                 LD BC,WIN_A0
  279.                 LD A,ROM_MAINMENU
  280.                 JP ADR_SEL_ROM
  281.  
  282. CMPCFG3         XOR A
  283.                 IN A,(0XFE)
  284.                 CPL
  285.                 AND 0X1F
  286.                 LD A,0X10
  287.                 JR NZ,CMOSHELP
  288.                 LD HL,0X6000
  289.                 PUSH HL
  290.                 JR START_SELECT
  291.  
  292. GTSTKEY         SCF
  293.                 LD A,0X10
  294. CMOSHELP        LD HL,BONUADR                   ;CMOS setup & HELP
  295.                 LD DE,0X6000                    ;РАСПАКОВКА И ЗАПУСК CMOS SETUP
  296.                 PUSH DE
  297.                 PUSH AF
  298.                 CALL DEC40
  299.                 POP AF
  300.                 JR START_SELECT
  301.  
  302. GDEMO           LD HL,0X6000-szdemoini
  303.                 LD SP,HL
  304.                 EX DE,HL
  305.                 PUSH DE
  306.                 LD HL,DEMO
  307.                 LD B,3
  308.                 LDIR
  309. START_SELECT    EX AF,AF'                       ;СОХРАНЕНИЕ А И ФЛАГОВ
  310.                 LD HL,ERAM_CODE-1
  311.                 LD DE,0X5C80
  312.                 LD BC,ERAM_CODE-RAM_CODE
  313.                 LDDR
  314.                 EX DE,HL
  315.                 INC HL
  316.                 EXX
  317.                 LD A,IXL
  318.                 AND A
  319.                 LD D,0XA3
  320.                 JR NZ,SET_MODE3
  321.                 LD H,CMOS_BYTE_00;0XEF
  322.                 CALL READCMOS
  323.                 AND M_TURBO14;0X80
  324.                 REPT 4
  325.                 RRCA
  326.                 ENDM
  327.                 OR D;0XA3
  328.                 LD D,A                          ;УСТАНОВКА ДЛЯ 14МГЦ
  329. SET_MODE3       LD H,CMOS_BYTE_01;0X0E
  330.                 CALL READCMOS
  331.                 LD E,A                          ;УСТАНОВКА ДЛЯ 7.0/3.5МГЦ И МОДЕЛЬ ПАМЯТИ
  332.                 PEC_OFF M_SHADOW_BF
  333.                 EXX
  334. CMPCFG2         JP (HL)
  335.  
  336. RAM_CODE        EXX
  337.                 LD BC,PENT_CONF
  338.                 LD A,IXL
  339.                 AND A
  340.                 LD A,0X10
  341.                 JR NZ,SET_MODE2
  342.                 LD A,E
  343.                 AND 3
  344.                 LD L,0
  345.                 JR Z,SET_MODE1
  346.                 LD L,4
  347. SET_MODE1       LD A,E
  348.                 AND M_TURBO357;0X80
  349.                 REPT 3
  350.                 RRCA
  351.                 ENDM
  352.                 OR L
  353.                 BIT 3,D
  354.                 JR Z,SET_MODE2
  355.                 SET 4,A
  356. SET_MODE2       OUT (C),A
  357.                 LD BC,CONF_128
  358.                 XOR A
  359.                 OUT (C),A                       ;ВКЛЮЧИЛИ МАППЕР 0
  360.                 PEC_ON M_SHADOW_BF
  361.                 LD BC,WIN_A0
  362.                 LD A,IXH
  363.                 OUT (C),A                       ;ЗАПРОГРАММИРОВАЛИ ROM ДЛЯ МАППЕР 0
  364.                 LD BC,0XFF77
  365.                 OUT (C),D                       ;ВЫСТАВИЛИ ТУРБО В ЗАВИСИМОСТИ ОТ УСТАНОВОК
  366.                 PEC_OFF M_SHADOW_BF
  367.                 EX AF,AF'
  368.                 LD BC,CONF_128
  369.                 OUT (C),A                       ;ВКЛЮЧИЛИ МАППЕР 1
  370.                 RET
  371. ERAM_CODE
  372.  
  373. ;НА ВХОДЕ:  H-АДРЕС ЯЧЕЙКИ
  374. ;НА ВЫХОДЕ: L,A-ПРОЧИТАННОЕ ЗНАЧЕНИЕ
  375. READCMOS        PUSH BC
  376.                 LD BC,CMOSD_SET_ADR
  377.                 OUT (C),H
  378.                 LD B,HIGH (CMOSD_RD_WR)
  379.                 IN L,(C)
  380.                 LD A,L
  381.                 POP BC
  382.                 RET
  383.  
  384. ;сброс включенного резидента
  385. RES_REZIDENT    PUSH AF
  386.                 PUSH HL
  387.                 LD H,CMOS_BYTE_01
  388.                 CALL READCMOS
  389.                 RES B_REZIDENT,L
  390.                 RST8 _CMOS_RW,_WRITE_CMOS
  391.                 POP HL
  392.                 POP AF
  393.                 RET
  394.  
  395. ;ДЛЯ РЕЗИДЕНТА HONEY COMANDER
  396.         IFDEF REZIDENT
  397. CMP_REZIDENT    LD H,CMOS_BYTE_01
  398.                 CALL READCMOS
  399.                 AND M_REZIDENT
  400.                 RET Z
  401.                 LD BC,WIN_A3
  402.                 LD A,0X1F ! 0X7F
  403.                 OUT (C),A
  404.                 LD HL,CPU3
  405.                 LD A,(HL)
  406.                 CP 0XC3
  407.                 JR NZ,.NOTFOUND
  408.                 XOR A
  409. .NEXTBYTE       ADD A,(HL)
  410.                 ADC A,0
  411.                 INC HL
  412.                 BIT 7,H
  413.                 JR NZ,.NEXTBYTE
  414.                 DEC A
  415.                 JR NZ,.NOTFOUND
  416.                 LD A,0XAA
  417.                 DEC HL
  418.                 CP (HL)
  419.                 JR NZ,.NOTFOUND
  420.                 CPL
  421.                 DEC HL
  422.                 CP (HL)
  423.                 JR NZ,.NOTFOUND
  424.                 LD BC,0X4177
  425.                 LD A,6
  426.                 OUT (C),A
  427.                 PEC_OFF M_SHADOW_BF
  428.                 JP CPU3
  429.  
  430. .NOTFOUND       LD BC,WIN_A3
  431.                 LD A,0XFF
  432.                 OUT (C),A
  433.                 RET
  434.         ENDIF
  435.  
  436. BONUADR         binclude ../../mainmenu/cmosset_pack.rom
  437.  
  438.                 DUPL ADR_RST8END-$,0XFF
  439. EDOS2RST8       LD A,L
  440.                 OUT (PEVO_CONF),A
  441.                 POP DE
  442.                 POP HL
  443.                 POP AF
  444.                 JP PO,EDOS2RST01
  445.                 EI
  446. EDOS2RST01      POP BC
  447.                 POP AF
  448.                 EX (SP),HL
  449.                 RET
  450.  
  451. DOS2RST8        EX (SP),HL                      ;HL
  452.                 PUSH AF                         ;AF
  453.                 PUSH BC                         ;BC
  454.                 LD A,R
  455.                 JP PE,DOS2RST8_01
  456.                 LD A,R
  457. DOS2RST8_01     DI
  458.                 PUSH AF                         ;RF
  459.                 PUSH HL                         ;ADR_RET
  460.                 PUSH DE                         ;DE
  461.                 IN A,(PEVO_CONF)
  462.                 LD L,A
  463.                 OR M_SHADOW_BF
  464.                 OUT (PEVO_CONF),A
  465.                 LD BC,RD_0WINA0
  466.                 IN H,(C)
  467.                 LD B,HIGH (RD_DOS7FFD)
  468.                 IN E,(C)
  469.                 RES 4,E
  470.                 DEC B
  471.                 IN D,(C)
  472.                 LD BC,WIN_P0
  473.                 XOR A
  474.                 JP ADR_SEL_ROM
  475.  
  476.                 DUPL 0X3D2D-$,0XFF
  477.                 OUT (C),A
  478.                 NOP
  479.                 RET
  480.  
  481. DEMO            LD BC,CONF_128
  482.                 LD A,0X10
  483.                 OUT (C),A
  484.                 EI
  485. szdemoini       EQU $-DEMO
  486.  
  487.                 binclude ../../mainmenu/src/grass.bin
  488.  
  489. LDIR4PROFROM    LD HL,JMP2PROFROM
  490.                 LD DE,JMP2PROFROM+0X8000
  491.                 LD BC,EJMP2PROFROM-JMP2PROFROM
  492.                 LDIR
  493.                 PUSH BC
  494.                 LD BC,0XBC77
  495.                 LD A,3
  496.                 OUT (C),A
  497.                 LD A,IXH
  498.                 LD BC,WIN_A0
  499.                 OUT (C),A
  500.                 LD BC,0XFF77
  501.                 LD A,0XA3
  502.                 JP JMP2PROFROM+0X8000
  503.  
  504. JMP2PROFROM     OUT (C),A
  505.                 RET
  506. EJMP2PROFROM   
  507.  
  508. SET_MAPPER     
  509.                 RET
  510.  
  511. ;1000 0001 81 0 BASIC 128       |EVO
  512. ;1000 0011 83 0 BASIC 48        |SERVICE
  513.  
  514. ;1000 0101 85 1 BASIC 128       |ADDONS
  515. ;1000 0111 87 1 BASIC 48        |RST8 SERVICE
  516.  
  517. ;1000 1001 89 2 BASIC 128       |RESERVED
  518. ;1000 1110 8B 2 BASIC 48        |EVODOS EMUL 3D2F
  519.                                          
  520. ;1000 1101 8D 3 BASIC 128       |PROFROM 1
  521. ;1000 1111 8F 3 BASIC 48        |PROFROM 1
  522.                                          
  523. ;1001 0001 91 4 BASIC 128       |PROFROM 0
  524. ;1001 0011 93 4 BASIC 48        |PROFROM 0
  525.  
  526. ;1001 0101 95 5 BASIC 128       |GLUK
  527. ;1001 0111 97 5 BASIC 48        |GLUK
  528.  
  529. ;1001 1001 99 6 BASIC 128       |FREE
  530. ;1001 1011 9B 6 BASIC 48        |FREE
  531.  
  532. ;1001 1101 9D 7 BASIC 128       |CUSTOM
  533. ;1001 1111 9F 7 BASIC 48        |CUSTOM
  534.  
  535. ;ОСНОВНАЯ КОНФИГУРАЦИЯ ПО СБРОСУ, ИЗМЕНЯТЬ КАТЕГОРИЧЕСКИ НЕ РЕКОМЕНДУЕТСЯ
  536. PAGES_CONF      DB 0XFF,0X7D,0X7A,0X83
  537.                 DB 0XFF,0X7D,0X7A,0X00,0X81
  538.  
  539. ;КОНФИГУРАЦИЯ ДЛЯ GLUK
  540. PAGES_CONFGLUK  DB 0XFF,0X7D,0X7A,CONF4GLUK+3
  541.                 DB 0XFF,0X7D,0X7A,0X00,CONF4GLUK+1
  542.  
  543. ;КОНФИГУРАЦИЯ ДЛЯ EVO PROFROM
  544. PAGES_PROFROM   DB 0XFF,0X7D,0X7A,CONF4PROF+3
  545.                 DB 0XFF,0X7D,0X7A,0X00,CONF4PROF+1
  546.  
  547. ;КОНФИГУРАЦИЯ ДЛЯ ОТДЕЛЬНО ПРОШИВАЕМОЙ 64К ПРОШИВКИ (USER ROM)
  548. PAGES_CUSTOM    DB 0XFF,0X7D,0X7A,CONF4CUSTOM+3
  549.                 DB 0XFF,0X7D,0X7A,0X00,CONF4CUSTOM+1
  550.  
  551. ;ПАЛИТРА ДЛЯ SPECTRUM РЕЖИМА
  552. TRSTPAL
  553.                 DB (R_H | R_L | G_H | G_L | B_H | B_L)  ! 0xF3  ;00
  554.                 DB (R_H | R_L | G_H | G_L            )  ! 0xF3  ;21
  555.                 DB (            G_H | G_L | B_H | B_L)  ! 0xF3  ;42
  556.                 DB (            G_H | G_L            )  ! 0xF3  ;63
  557.                 DB (R_H | R_L |             B_H | B_L)  ! 0xF3  ;90
  558.                 DB (R_H | R_L                        )  ! 0xF3  ;B1
  559.                 DB (                        B_H | B_L)  ! 0xF3  ;D2
  560.                 DB BLACK                                ! 0xF3  ;F3
  561.                 DB (R_H |       G_H |       B_H      )  ! 0xF3  ;E0
  562.                 DB (R_H |       G_H                  )  ! 0xF3  ;E1
  563.                 DB (            G_H |       B_H      )  ! 0xF3  ;E2
  564.                 DB (            G_H                  )  ! 0xF3  ;E3
  565.                 DB (R_H |                   B_H      )  ! 0xF3  ;F0
  566.                 DB (R_H)                                ! 0xF3  ;F1
  567.                 DB (                        B_H      )  ! 0xF3  ;F2
  568.                 DB BLACK                                ! 0xF3  ;F3
  569.  
  570.                 DUPL 0X3FF8-$,0XFF
  571.                 DB "HEGLUK"
  572.                 DW DATA_VERS
  573.