Subversion Repositories pentevo

Rev

Rev 1046 | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed

  1.  
  2. ; LAST UPDATE: 01.11.2023 savelij
  3.  
  4. ;================ЗАГРУЗЧИК С ZC SD КАРТОЧКИ===================
  5. READ_ZSD        PUSH AF
  6.                 LD A,1
  7.                 OUT (P_CONF),A
  8.                 POP AF
  9.                 EX AF,AF'
  10.                 LD A,CMD_18
  11.                 CALL SECM200
  12.                 EX AF,AF'
  13. RDMULT1         EX AF,AF'
  14. RDMULT2         CALL IN_OOUT
  15.                 CP 0xFE
  16.                 JR NZ,RDMULT2
  17.                 PUSH BC
  18.                 LD BC,P_DATA
  19.                 INIR
  20.                 NOP
  21.                 INIR
  22.                 NOP
  23.                 IN A,(C)
  24.                 NOP
  25.                 IN A,(C)
  26.                 POP BC
  27.                 EX AF,AF'
  28.                 DEC A
  29.                 JR NZ,RDMULT1
  30.                 LD A,CMD_12
  31.                 CALL OUT_COM
  32. RDMULT3         CALL IN_OOUT
  33.                 INC A
  34.                 JR NZ,RDMULT3
  35.                 PUSH AF
  36.                 LD A,3
  37.                 OUT (P_CONF),A
  38.                 XOR A
  39.                 OUT (P_DATA),A
  40.                 POP AF
  41.                 RET
  42.  
  43. SECM200         PUSH HL
  44.                 PUSH DE
  45.                 PUSH BC
  46.                 PUSH AF
  47.                 PUSH BC
  48.                 LD A,CMD_58
  49.                 LD BC,P_DATA
  50.                 CALL OUT_COM
  51.                 CALL IN_OOUT
  52.                 IN A,(C)
  53.                 NOP
  54.                 IN H,(C)
  55.                 NOP
  56.                 IN H,(C)
  57.                 NOP
  58.                 IN H,(C)
  59.                 BIT 6,A
  60.                 POP HL
  61.                 JR NZ,SECN200
  62.                 EX DE,HL
  63.                 ADD HL,HL
  64.                 EX DE,HL
  65.                 ADC HL,HL
  66.                 LD H,L
  67.                 LD L,D
  68.                 LD D,E
  69.                 LD E,0
  70. SECN200         POP AF
  71.                 in (c) ;in f,(c)
  72.                 in (c) ;in f,(c)
  73.                 LD BC,P_DATA
  74.                 OUT (C),A
  75.                 NOP
  76.                 OUT (C),H
  77.                 NOP
  78.                 OUT (C),L
  79.                 NOP
  80.                 OUT (C),D
  81.                 NOP
  82.                 OUT (C),E
  83.                 LD A,0xFF
  84.                 OUT (C),A
  85.                 POP BC
  86.                 POP DE
  87.                 POP HL
  88.                 RET
  89.  
  90. OUT_COM         PUSH BC
  91.                 LD BC,P_DATA
  92.                 in (c) ;in f,(c)
  93.                 in (c) ;in f,(c)
  94.                 OUT (C),A
  95.                 XOR A
  96.                 OUT (C),A
  97.                 NOP
  98.                 OUT (C),A
  99.                 NOP
  100.                 OUT (C),A
  101.                 NOP
  102.                 OUT (C),A
  103.                 DEC A
  104.                 OUT (C),A
  105.                 POP BC
  106.                 RET
  107.  
  108. IN_OOUT         PUSH DE
  109.                 LD DE,0x20FF
  110. IN_WAIT         IN A,(P_DATA)
  111.                 CP E
  112.                 JR NZ,IN_EXIT
  113. IN_NEXT         DEC D
  114.                 JR NZ,IN_WAIT
  115. IN_EXIT         POP DE
  116.                 RET
  117. ;================ЗАГРУЗЧИК С ZC SD КАРТОЧКИ===================
  118.