Subversion Repositories pentevo

Rev

Go to most recent revision | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed | ?url?

  1.  
  2. ;LAST UPDATE: 01.12.2014 savelij
  3.  
  4. ;================ЗАГРУЗЧИК С ZC SD КАРТОЧКИ===================
  5. READ_SD         PUSH AF
  6.                 LD A,1
  7.                 OUT (P_CONF),A
  8.                 POP AF
  9.                 EX AF,AF'
  10.                 LD A,CMD_18
  11.                 CALL SECM200
  12.                 EX AF,AF'
  13. RDMULT1         EX AF,AF'
  14. RDMULT2         CALL IN_OOUT
  15.                 CP 0XFE
  16.                 JR NZ,RDMULT2
  17.                 PUSH BC
  18.                 LD BC,P_DATA
  19.                 INIR
  20.                 NOP
  21.                 INIR
  22.                 NOP
  23.                 IN A,(C)
  24.                 NOP
  25.                 IN A,(C)
  26.                 POP BC
  27.                 EX AF,AF'
  28.                 DEC A
  29.                 JR NZ,RDMULT1
  30.                 LD A,CMD_12
  31.                 CALL OUT_COM
  32. RDMULT3         CALL IN_OOUT
  33.                 INC A
  34.                 JR NZ,RDMULT3
  35.                 PUSH AF
  36.                 LD A,3
  37.                 OUT (P_CONF),A
  38.                 XOR A
  39.                 OUT (P_DATA),A
  40.                 POP AF
  41.                 RET
  42.  
  43. SECM200         PUSH HL
  44.                 PUSH DE
  45.                 PUSH BC
  46.                 PUSH AF
  47.                 PUSH BC
  48.                 LD A,CMD_58
  49.                 LD BC,P_DATA
  50.                 CALL OUT_COM
  51.                 CALL IN_OOUT
  52.                 IN A,(C)
  53.                 NOP
  54.                 IN H,(C)
  55.                 NOP
  56.                 IN H,(C)
  57.                 NOP
  58.                 IN H,(C)
  59.                 BIT 6,A
  60.                 POP HL
  61.                 JR NZ,SECN200
  62.                 EX DE,HL
  63.                 ADD HL,HL
  64.                 EX DE,HL
  65.                 ADC HL,HL
  66.                 LD H,L
  67.                 LD L,D
  68.                 LD D,E
  69.                 LD E,0
  70. SECN200         POP AF
  71.                 LD BC,P_DATA
  72.                 OUT (C),A
  73.                 NOP
  74.                 OUT (C),H
  75.                 NOP
  76.                 OUT (C),L
  77.                 NOP
  78.                 OUT (C),D
  79.                 NOP
  80.                 OUT (C),E
  81.                 LD A,0XFF
  82.                 OUT (C),A
  83.                 POP BC
  84.                 POP DE
  85.                 POP HL
  86.                 RET
  87.  
  88. OUT_COM         PUSH BC
  89.                 LD BC,P_DATA
  90.                 OUT (C),A
  91.                 XOR A
  92.                 OUT (C),A
  93.                 NOP
  94.                 OUT (C),A
  95.                 NOP
  96.                 OUT (C),A
  97.                 NOP
  98.                 OUT (C),A
  99.                 DEC A
  100.                 OUT (C),A
  101.                 POP BC
  102.                 RET
  103.  
  104. IN_OOUT         PUSH DE
  105.                 LD DE,0X20FF
  106. IN_WAIT         IN A,(P_DATA)
  107.                 CP E
  108.                 JR NZ,IN_EXIT
  109. IN_NEXT         DEC D
  110.                 JR NZ,IN_WAIT
  111. IN_EXIT         POP DE
  112.                 RET
  113. ;================ЗАГРУЗЧИК С ZC SD КАРТОЧКИ===================
  114.