Subversion Repositories pentevo

Rev

Rev 896 | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed | ?url?

  1.  
  2. ;LAST UPDATE: 12.02.2020 savelij
  3.  
  4.                 include ../../svn/pentevo/rom/macros.a80
  5.                 include ../../svn/pentevo/rom/define.a80
  6.                 include ../../svn/pentevo/rom/global_vars.a80
  7.                 include ../../svn/pentevo/rom/evodos_vars.a80
  8.  
  9. DEPKADR         EQU 0X6000
  10.  
  11.                 ORG 0X0000
  12.                 DI
  13.                 JP INITPAGE0
  14.  
  15.                 DUPL 0X0008-$,0XFF
  16.                 NOP
  17.                 JP DOS2RST8
  18.  
  19.                 DUPL ADR_SEL_ROM-$,0XFF
  20.                 OUT (C),A
  21.                 NOP
  22.                 RET
  23.  
  24.                 DUPL 0X0038-$,0XFF
  25.                 EI
  26.                 RET
  27.  
  28.                 DUPL 0X0040-$,0XFF
  29.                 JP SET_MAPPER
  30.  
  31.                 DUPL 0X0066-$,0XFF
  32.                 NOP
  33.  
  34.                 DUPL 0X0080-$,0XFF
  35.                 include ../../svn/pentevo/rom/dec40.a80
  36.  
  37.                 DUPL 0X00FF-$,0XFF
  38.                 DW 0X0038
  39.  
  40. INITPAGE0       LD SP,DEPKADR
  41.                 LD IY,0X5C3A
  42.                 LD A,0X3F
  43.                 LD I,A
  44.                 IM 1
  45.                 XOR A
  46.                 OUT (0XFE),A
  47.                 LD HL,PAGES_CONF
  48.                 LD BC,0XBC77
  49.                 LD A,2
  50.                 OUT (C),A
  51.                 LD DE,0X103F
  52. INITPAGE2       LD BC,CONF_128
  53.                 OUT (C),D
  54.                 LD BC,LOW (WIN_A0)
  55. INITPAGE1       OUTI
  56.                 LD A,B
  57.                 SUB E
  58.                 LD B,A
  59.                 JR NZ,INITPAGE1
  60.                 LD BC,CONF_128
  61.                 LD A,D
  62.                 XOR 0X10
  63.                 LD D,A
  64.                 JR Z,INITPAGE2
  65.                 LD BC,0XFF77
  66.                 LD A,0XAB
  67.                 OUT (C),A
  68.                 LD BC,WIN_P1
  69.                 LD A,RAM_EVODOS
  70.                 OUT (C),A
  71.                 LD BC,WIN_A2
  72.                 LD A,ROM_BAS48
  73.                 OUT (C),A
  74.                 LD HL,CPU2
  75.                 LD DE,CPU1
  76.                 LD BC,0X4000
  77.                 LDIR
  78.                 LD BC,WIN_A1
  79.                 LD A,5 ! 0X7F
  80.                 OUT (C),A
  81.                 LD BC,WIN_A2
  82.                 LD A,2 ! 0X7F
  83.                 OUT (C),A
  84.                 LD HL,0
  85.                 PUSH HL
  86.                 LD HL,0X3D2F
  87.                 PUSH HL
  88.                 LD HL,0X6000
  89.                 PUSH HL
  90.                 LD (HL),0XC9
  91.                 XOR A
  92.                 OUT (0XBF),A
  93.                 LD A,0X10
  94.                 JP START_SELECT
  95.  
  96.  
  97.  
  98.  
  99.  
  100.  
  101.  
  102.  
  103.  
  104.  
  105.  
  106.  
  107.  
  108.  
  109.  
  110.  
  111.                 PEC_ON M_SHADOW_BF
  112.                 LD HL,INITPAGE3
  113.                 PUSH HL
  114.                 LD HL,0X40;INST_NMIRST
  115.                 PUSH HL
  116.                 LD BC,WIN_A0
  117.                 LD A,ROM_RST81
  118.                 JP ADR_SEL_ROM
  119.  
  120. INITPAGE3       RST8 _CMOS_RW,_INIT_CMOS
  121.                 LD HL,PAGES_CONF
  122.                 LD A,0XEF
  123.                 IN A,(0XFE)
  124.                 RRCA                            ;ПРОВЕРКА НАЖАТИЯ КНОПКИ "0" ПРИ СБРОСЕ
  125.                 CALL NC,RES_REZIDENT
  126.                 JR NC,RSTRAM                    ;СБРОС В ОСНОВНОЕ ПЗУ
  127.                 RRCA
  128.                 RRCA
  129.                 RRCA
  130.                 RRCA                            ;ПРОВЕРКА НАЖАТИЯ КНОПКИ "6" ПРИ СБРОСЕ
  131.                 JR C,INITPAGE4
  132. ;ВХОД В ОТЛАДЧИК
  133.                 EXX
  134.                 LD BC,WIN_P2
  135.                 XOR A
  136.                 OUT (C),A
  137.                 LD HL,CPU2+DEBUG_ONOFF
  138.                 SET 7,(HL)
  139.                 EXX
  140.                 IN A,(PEVO_CONF)
  141.                 OR M_NMI_BF
  142.                 OUT (PEVO_CONF),A
  143.                 AND M_NMI_BF!0XFF
  144.                 OUT (PEVO_CONF),A
  145.                 HALT
  146. INITPAGE4       LD BC,CMOSD_SET_ADR
  147.                 LD A,CMOS_BYTE_00
  148.                 OUT (C),A
  149.                 LD B,HIGH (CMOSD_RD_WR)
  150.                 IN A,(C)
  151.                 AND MKOL_MODES
  152.                 CP KOL_MODES
  153.                 JR NC,RSTRAM
  154.                 AND A
  155.                 JR Z,RSTRAM
  156.                 DEC A
  157.                 LD HL,PAGES_CONFGLUK            ;КОНФИГУРИРОВАТЬ ДЛЯ GLUK
  158.                 JR Z,RSTRAM
  159.                 DEC A
  160.                 LD HL,PAGES_PROFROM             ;КОНФИГУРИРОВАТЬ ДЛЯ PROFROM
  161.                 JR Z,RSTRAM
  162.                 LD HL,PAGES_CUSTOM              ;КОНФИГУРИРОВАТЬ ДЛЯ USER ROM
  163. RSTRAM          LD A,0XEF
  164.                 IN A,(0XFE)
  165.                 RRCA                            ;ПРОВЕРКА НЕ НАЖАТОСТИ КНОПКИ "0" ПРИ СБРОСЕ
  166.                 JR NC,RSTRAM                    ;ЕСЛИ НАЖАТА ЖДЕМ ОТПУСКАНИЯ
  167.                 LD BC,0XBC77
  168.                 LD A,2
  169.                 OUT (C),A
  170.                 LD DE,0X103F
  171. LOOP2           LD BC,CONF_128
  172.                 OUT (C),D
  173.                 LD BC,LOW (WIN_A0)
  174. LOOP1           OUTI
  175.                 LD A,B
  176.                 SUB E
  177.                 LD B,A
  178.                 JR NZ,LOOP1
  179.                 LD BC,CONF_128
  180.                 LD A,D
  181.                 XOR 0X10
  182.                 LD D,A
  183.                 JR Z,LOOP2
  184. RSTPAL          LD A,(HL)
  185.                 LD IXH,A                        ;НОМЕР СТРАНИЦЫ ЗАВЕРШЕНИЯ ИНИТА МАНАГЕРА
  186.                 LD DE,0XAB0F                    ;ZX SCREEN MODE, TURBO ON 14MHZ
  187.                 LD BC,0XFD77                    ;И ДОСТУП К ПАЛИТРЕ
  188.                 OUT (C),D
  189.                 EI                              ;палитра
  190.                 HALT
  191.                 DI
  192.                 LD HL,TRSTPAL                   ;+15
  193.                 LD BC,0XBD77
  194.                 OUT (C),D                       ;вкл.PAL
  195. RSTPAL0         LD A,E
  196.                 BIT 3,E
  197.                 OUT (0XFE),A
  198.                 JR Z,$+4
  199.                 OUT (0XF6),A
  200.                 LD A,(HL)
  201.                 INC HL
  202.                 OR %00001100
  203.                 OUT (0XFF),A
  204.                 DEC E
  205.                 JP P,RSTPAL0
  206. END_INIT        LD A,0XAB
  207.                 LD BC,0XFF77
  208.                 OUT (C),A                       ;выкл.PAL
  209.                 LD A,IXH
  210.                 LD BC,0
  211.                 AND 0X3C
  212.                 JR Z,RSTKEYS2                   ;RESET TO EVO SERVICE PAGE
  213.                 CP CONF4GLUK&0X3F
  214.                 JR Z,RSTKEYS3                   ;RESET TO GLUK SERVICE PAGE
  215.                 CP CONF4CUSTOM&0X3F
  216.                 JR Z,RSTKEYS3                   ;RESET TO CUSTOM ROM
  217.                 JP LDIR4PROFROM                 ;RESET TO PROFROM BASIC 128
  218.  
  219. RSTKEYS3        PUSH BC
  220.                 LD BC,0XBC77
  221.                 LD A,2
  222.                 OUT (C),A
  223.                 LD BC,WIN_A0
  224.                 LD A,IXH
  225.                 OUT (C),A
  226.                 PEC_OFF M_SHADOW_BF
  227.                 LD BC,0XFF77
  228.                 LD A,0XA3
  229.                 JP 0X3D2D
  230.  
  231. RSTKEYS2        LD H,CMOS_BYTE_00
  232.                 RST8 _CMOS_RW,_READ_CMOS
  233.                 AND 0XFC                        ;СБРОС ДЛЯ ОСНОВНОГО ПЗУ
  234.                 LD L,A
  235.                 RST8 _CMOS_RW,_WRITE_CMOS       ;ПРИНУДИТЕЛЬНО ВЫСТАВЛЕНИЕ В КМОС СБРОСА НА EVO SERVICE
  236.         IFDEF DOS_FE
  237.                 LD BC,WIN_A3
  238.                 LD A,ROM_RST82
  239.                 OUT (C),A
  240.                 LD B,HIGH (WIN_P2)
  241.                 LD A,RAM_EVODOS
  242.                 OUT (C),A
  243.                 LD A,(CPU2+COPY_VIRT_BITS)
  244.                 PUSH AF
  245.                 CALL UNP_DOS_FE+CPU3            ;РАСПАКОВКА DOS
  246.                 POP AF
  247.                 LD (CPU2+COPY_VIRT_BITS),A
  248.         ELSE
  249.                 LD BC,WIN_A3
  250.                 LD A,ROM_ADD_DOS
  251.                 OUT (C),A
  252.                 LD B,HIGH (WIN_P2)
  253.                 LD A,RAM_EVODOS
  254.                 OUT (C),A
  255.                 LD A,(CPU2+COPY_VIRT_BITS)
  256.                 LD HL,CPU3
  257.                 LD DE,CPU2
  258.                 LD BC,0X4000
  259.                 LDIR                            ;ПЕРЕНОС DOS
  260.                 LD (CPU2+COPY_VIRT_BITS),A
  261.         ENDIF
  262.                 LD BC,WIN_A2
  263.                 LD A,0X7D
  264.                 OUT (C),A
  265.                 LD B,HIGH (WIN_A3)
  266.                 LD A,0XFF
  267.                 OUT (C),A
  268. ;ДЛЯ РЕЗИДЕНТА HONEY COMANDER
  269.         IFDEF REZIDENT
  270.                 CALL CMP_REZIDENT               ;ПРОВЕРКА РЕЗИДЕНТА
  271.         ENDIF
  272.                 LD BC,0XFEFF
  273. RSTKEYS1        LD A,B
  274.                 IN A,(0XFE)
  275.                 REPT 5
  276.                 RRA
  277.                 JR C,$+3
  278.                 INC C
  279.                 ENDM
  280.                 RLC B
  281.                 JR C,RSTKEYS1
  282.                 DEC C
  283.                 JP P,GTSTKEY                    ;НАЖАТО БОЛЕЕ 1 КНОПКИ, ПЕРЕХОДИМ К ТЕСТУ КЛАВИАТУРЫ
  284.                 LD IXL,0                        ;ЗАПУСК НЕОСНОВНОЙ ПРОШИВКИ СЕРВИСА
  285.                 LD DE,0                         ;1 НАЖАТА, ПРОВЕРЯЕМ ЧТО ЭТО
  286.                 LD BC,CONF_128
  287.                 PUSH DE                         ;АДРЕС ПЕРЕХОДА В ПЗУ ЕСЛИ ВЫБРАНО
  288.                 LD A,0XFE
  289.                 IN A,(0XFE)                     ;ЧТЕНИЕ НАЖАТОСТИ КНОПКИ "CS"
  290.                 RRA
  291.                 LD A,0
  292.                 JP NC,START_SELECT              ;ПРИ НАЖАТОЙ "CS" ПЕРЕХОДИМ В БЕЙСИК 128
  293.                 LD A,0X7F
  294.                 IN A,(0XFE)                     ;ЧТЕНИЕ НАЖАТОСТИ КНОПКИ "SS"
  295.                 LD D,A
  296.                 RRA
  297.                 RRA
  298.                 LD A,0X30
  299.                 JP NC,START_SELECT              ;ПРИ НАЖАТОЙ "SS" ПЕРЕХОДИМ В БЕЙСИК 48
  300.                 LD A,D
  301.                 RRA                             ;ПРОВЕРКА НАЖАТОСТИ КНОПКИ "SPACE"
  302.                 JR C,CMPCFG1                    ;ПЕРЕХОДИМ ДАЛЕЕ ЕСЛИ НИЧЕГО НЕ НАЖАТО
  303.                 LD A,0X10
  304.                 LD DE,0X3D2F
  305.                 PUSH DE
  306.                 JP START_SELECT                 ;ПРИ НАЖАТОЙ "SPACE" ПЕРЕХОДИМ В TR-DOS
  307.  
  308. CMPCFG1         LD A,0XFD
  309.                 IN A,(0XFE)
  310.                 AND 4                           ;НАЖАТО "D" ЗАПУСК ДЕМКИ
  311.                 JP Z,GDEMO
  312.                 LD IXL,1                        ;ЗАПУСК ОСНОВНОЙ ПРОШИВКИ СЕРВИСА
  313.                 LD HL,DEPKADR                   ;НИЧЕГО НЕ НАЖАТО, ЗАПУСКАЕМ ОСНОВНУЮ ПРОШИВКУ
  314.                 LD SP,HL
  315.                 EX DE,HL
  316.                 LD HL,CMPCFG3
  317.                 PUSH HL
  318.                 LD HL,0X0101
  319.                 PUSH HL
  320.                 LD BC,WIN_A0
  321.                 LD A,ROM_MAINMENU
  322.                 JP ADR_SEL_ROM
  323.  
  324. CMPCFG3         XOR A
  325.                 IN A,(0XFE)
  326.                 CPL
  327.                 AND 0X1F
  328.                 LD A,0X10
  329.                 JR NZ,CMOSHELP
  330.                 LD HL,0X6000
  331.                 PUSH HL
  332.                 JR START_SELECT
  333.  
  334. GTSTKEY         SCF
  335.                 LD A,0X10
  336. CMOSHELP        LD HL,BONUADR                   ;CMOS setup & HELP
  337.                 LD DE,0X6000                    ;РАСПАКОВКА И ЗАПУСК CMOS SETUP
  338.                 PUSH DE
  339.                 PUSH AF
  340.                 CALL DEC40
  341.                 POP AF
  342.                 JR START_SELECT
  343.  
  344. GDEMO           LD HL,0X6000-szdemoini
  345.                 LD SP,HL
  346.                 EX DE,HL
  347.                 PUSH DE
  348.                 LD HL,DEMO
  349.                 LD B,3
  350.                 LDIR
  351. START_SELECT    EX AF,AF'                       ;СОХРАНЕНИЕ А И ФЛАГОВ
  352.                 LD HL,ERAM_CODE-1
  353.                 LD DE,0X5C80
  354.                 LD BC,ERAM_CODE-RAM_CODE
  355.                 LDDR
  356.                 EX DE,HL
  357.                 INC HL
  358.                 EXX
  359.                 LD A,IXL
  360.                 AND A
  361.         IF 1
  362.                 LD DE,0XAB02
  363.         ELSE
  364.                 LD D,0XA3
  365.                 JR NZ,SET_MODE3
  366.                 LD H,CMOS_BYTE_00;0XEF
  367.                 CALL READCMOS
  368.                 AND M_TURBO14;0X80
  369.                 REPT 4
  370.                 RRCA
  371.                 ENDM
  372.                 OR D;0XA3
  373.                 LD D,A                          ;УСТАНОВКА ДЛЯ 14МГЦ
  374. SET_MODE3       LD H,CMOS_BYTE_01;0X0E
  375.                 CALL READCMOS
  376.                 LD E,A                          ;УСТАНОВКА ДЛЯ 7.0/3.5МГЦ И МОДЕЛЬ ПАМЯТИ
  377.                 PEC_OFF M_SHADOW_BF
  378.         ENDIF
  379.                 EXX
  380. CMPCFG2         JP (HL)
  381.  
  382. RAM_CODE        EXX
  383.                 LD BC,PENT_CONF
  384.                 LD A,IXL
  385.                 AND A
  386.                 LD A,0X10
  387.                 JR NZ,SET_MODE2
  388.                 LD A,E
  389.                 AND 3
  390.                 LD L,0
  391.                 JR Z,SET_MODE1
  392.                 LD L,4
  393. SET_MODE1       LD A,E
  394.                 AND M_TURBO357;0X80
  395.                 REPT 3
  396.                 RRCA
  397.                 ENDM
  398.                 OR L
  399.                 BIT 3,D
  400.                 JR Z,SET_MODE2
  401.                 SET 4,A
  402. SET_MODE2       OUT (C),A
  403.                 LD BC,CONF_128
  404.                 XOR A
  405.                 OUT (C),A                       ;ВКЛЮЧИЛИ МАППЕР 0
  406.                 PEC_ON M_SHADOW_BF
  407.                 LD BC,WIN_A0
  408.                 LD A,IXH
  409.                 OUT (C),A                       ;ЗАПРОГРАММИРОВАЛИ ROM ДЛЯ МАППЕР 0
  410.                 LD BC,0XFF77
  411.                 OUT (C),D                       ;ВЫСТАВИЛИ ТУРБО В ЗАВИСИМОСТИ ОТ УСТАНОВОК
  412.                 PEC_OFF M_SHADOW_BF
  413.                 EX AF,AF'
  414.                 LD BC,CONF_128
  415.                 OUT (C),A                       ;ВКЛЮЧИЛИ МАППЕР 1
  416.                 RET
  417. ERAM_CODE
  418.  
  419. ;НА ВХОДЕ:  H-АДРЕС ЯЧЕЙКИ
  420. ;НА ВЫХОДЕ: L,A-ПРОЧИТАННОЕ ЗНАЧЕНИЕ
  421. READCMOS        PUSH BC
  422.                 LD BC,CMOSD_SET_ADR
  423.                 OUT (C),H
  424.                 LD B,HIGH (CMOSD_RD_WR)
  425.                 IN L,(C)
  426.                 LD A,L
  427.                 POP BC
  428.                 RET
  429.  
  430. ;сброс включенного резидента
  431. RES_REZIDENT    PUSH AF
  432.                 PUSH HL
  433.                 LD H,CMOS_BYTE_01
  434.                 CALL READCMOS
  435.                 RES B_REZIDENT,L
  436.                 RST8 _CMOS_RW,_WRITE_CMOS
  437.                 POP HL
  438.                 POP AF
  439.                 RET
  440.  
  441. ;ДЛЯ РЕЗИДЕНТА HONEY COMANDER
  442.         IFDEF REZIDENT
  443. CMP_REZIDENT    LD H,CMOS_BYTE_01
  444.                 CALL READCMOS
  445.                 AND M_REZIDENT
  446.                 RET Z
  447.                 LD BC,WIN_A3
  448.                 LD A,0X1F ! 0X7F
  449.                 OUT (C),A
  450.                 LD HL,CPU3
  451.                 LD A,(HL)
  452.                 CP 0XC3
  453.                 JR NZ,.NOTFOUND
  454.                 XOR A
  455. .NEXTBYTE       ADD A,(HL)
  456.                 ADC A,0
  457.                 INC HL
  458.                 BIT 7,H
  459.                 JR NZ,.NEXTBYTE
  460.                 DEC A
  461.                 JR NZ,.NOTFOUND
  462.                 LD A,0XAA
  463.                 DEC HL
  464.                 CP (HL)
  465.                 JR NZ,.NOTFOUND
  466.                 CPL
  467.                 DEC HL
  468.                 CP (HL)
  469.                 JR NZ,.NOTFOUND
  470.                 LD BC,0X4177
  471.                 LD A,6
  472.                 OUT (C),A
  473.                 PEC_OFF M_SHADOW_BF
  474.                 JP CPU3
  475.  
  476. .NOTFOUND       LD BC,WIN_A3
  477.                 LD A,0XFF
  478.                 OUT (C),A
  479.                 RET
  480.         ENDIF
  481.  
  482. BONUADR         ;binclude ../../mainmenu/cmosset_pack.rom
  483.  
  484.                 DUPL ADR_RST8END-$,0XFF
  485. EDOS2RST8       LD A,L
  486.                 OUT (PEVO_CONF),A
  487.                 POP DE
  488.                 POP HL
  489.                 POP AF
  490.                 JP PO,EDOS2RST01
  491.                 EI
  492. EDOS2RST01      POP BC
  493.                 POP AF
  494.                 EX (SP),HL
  495.                 RET
  496.  
  497. DOS2RST8        EX (SP),HL                      ;HL
  498.                 PUSH AF                         ;AF
  499.                 PUSH BC                         ;BC
  500.                 LD A,R
  501.                 JP PE,DOS2RST8_01
  502.                 LD A,R
  503. DOS2RST8_01     DI
  504.                 PUSH AF                         ;RF
  505.                 PUSH HL                         ;ADR_RET
  506.                 PUSH DE                         ;DE
  507.                 IN A,(PEVO_CONF)
  508.                 LD L,A
  509.                 OR M_SHADOW_BF
  510.                 OUT (PEVO_CONF),A
  511.                 LD BC,RD_0WINA0
  512.                 IN H,(C)
  513.                 LD B,HIGH (RD_DOS7FFD)
  514.                 IN E,(C)
  515.                 RES 4,E
  516.                 DEC B
  517.                 IN D,(C)
  518.                 LD BC,WIN_P0
  519.                 XOR A
  520.                 JP ADR_SEL_ROM
  521.  
  522.                 DUPL 0X3D2D-$,0XFF
  523.                 OUT (C),A
  524.                 NOP
  525.                 RET
  526.  
  527. DEMO            LD BC,CONF_128
  528.                 LD A,0X10
  529.                 OUT (C),A
  530.                 EI
  531. szdemoini       EQU $-DEMO
  532.  
  533.                 ;binclude ../../mainmenu/src/grass.bin
  534.  
  535. LDIR4PROFROM    LD HL,JMP2PROFROM
  536.                 LD DE,JMP2PROFROM+0X8000
  537.                 LD BC,EJMP2PROFROM-JMP2PROFROM
  538.                 LDIR
  539.                 PUSH BC
  540.                 LD BC,0XBC77
  541.                 LD A,3
  542.                 OUT (C),A
  543.                 LD A,IXH
  544.                 LD BC,WIN_A0
  545.                 OUT (C),A
  546.                 LD BC,0XFF77
  547.                 LD A,0XA3
  548.                 JP JMP2PROFROM+0X8000
  549.  
  550. JMP2PROFROM     OUT (C),A
  551.                 RET
  552. EJMP2PROFROM   
  553.  
  554. SET_MAPPER     
  555.                 RET
  556.  
  557. ;1000 0001 81 0 BASIC 128       |EVO
  558. ;1000 0011 83 0 BASIC 48        |SERVICE
  559.  
  560. ;1000 0101 85 1 BASIC 128       |ADDONS
  561. ;1000 0111 87 1 BASIC 48        |RST8 SERVICE
  562.  
  563. ;1000 1001 89 2 BASIC 128       |RESERVED
  564. ;1000 1110 8B 2 BASIC 48        |EVODOS EMUL 3D2F
  565.                                          
  566. ;1000 1101 8D 3 BASIC 128       |PROFROM 1
  567. ;1000 1111 8F 3 BASIC 48        |PROFROM 1
  568.                                          
  569. ;1001 0001 91 4 BASIC 128       |PROFROM 0
  570. ;1001 0011 93 4 BASIC 48        |PROFROM 0
  571.  
  572. ;1001 0101 95 5 BASIC 128       |GLUK
  573. ;1001 0111 97 5 BASIC 48        |GLUK
  574.  
  575. ;1001 1001 99 6 BASIC 128       |FREE
  576. ;1001 1011 9B 6 BASIC 48        |FREE
  577.  
  578. ;1001 1101 9D 7 BASIC 128       |CUSTOM
  579. ;1001 1111 9F 7 BASIC 48        |CUSTOM
  580.  
  581. ;ОСНОВНАЯ КОНФИГУРАЦИЯ ПО СБРОСУ, ИЗМЕНЯТЬ КАТЕГОРИЧЕСКИ НЕ РЕКОМЕНДУЕТСЯ
  582. PAGES_CONF      DB 0XFF,0X7D,0X7A,0X83
  583.                 DB 0XFF,0X7D,0X7A,0X00,0X81
  584.  
  585. ;КОНФИГУРАЦИЯ ДЛЯ GLUK
  586. PAGES_CONFGLUK  DB 0XFF,0X7D,0X7A,CONF4GLUK+3
  587.                 DB 0XFF,0X7D,0X7A,0X00,CONF4GLUK+1
  588.  
  589. ;КОНФИГУРАЦИЯ ДЛЯ EVO PROFROM
  590. PAGES_PROFROM   DB 0XFF,0X7D,0X7A,CONF4PROF+3
  591.                 DB 0XFF,0X7D,0X7A,0X00,CONF4PROF+1
  592.  
  593. ;КОНФИГУРАЦИЯ ДЛЯ ОТДЕЛЬНО ПРОШИВАЕМОЙ 64К ПРОШИВКИ (USER ROM)
  594. PAGES_CUSTOM    DB 0XFF,0X7D,0X7A,CONF4CUSTOM+3
  595.                 DB 0XFF,0X7D,0X7A,0X00,CONF4CUSTOM+1
  596.  
  597. ;ПАЛИТРА ДЛЯ SPECTRUM РЕЖИМА
  598. TRSTPAL
  599.                 DB (R_H | R_L | G_H | G_L | B_H | B_L)  ! 0xF3  ;00
  600.                 DB (R_H | R_L | G_H | G_L            )  ! 0xF3  ;21
  601.                 DB (            G_H | G_L | B_H | B_L)  ! 0xF3  ;42
  602.                 DB (            G_H | G_L            )  ! 0xF3  ;63
  603.                 DB (R_H | R_L |             B_H | B_L)  ! 0xF3  ;90
  604.                 DB (R_H | R_L                        )  ! 0xF3  ;B1
  605.                 DB (                        B_H | B_L)  ! 0xF3  ;D2
  606.                 DB BLACK                                ! 0xF3  ;F3
  607.                 DB (R_H |       G_H |       B_H      )  ! 0xF3  ;E0
  608.                 DB (R_H |       G_H                  )  ! 0xF3  ;E1
  609.                 DB (            G_H |       B_H      )  ! 0xF3  ;E2
  610.                 DB (            G_H                  )  ! 0xF3  ;E3
  611.                 DB (R_H |                   B_H      )  ! 0xF3  ;F0
  612.                 DB (R_H)                                ! 0xF3  ;F1
  613.                 DB (                        B_H      )  ! 0xF3  ;F2
  614.                 DB BLACK                                ! 0xF3  ;F3
  615.  
  616.                 DUPL 0X3FF8-$,0XFF
  617.                 DB "HEGLUK"
  618.                 DW DATA_VERS
  619.